1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
// RUN: %empty-directory(%t)
// RUN: %build-irgen-test-overlays
// RUN: %target-swift-frontend(mock-sdk: -sdk %S/Inputs -I %t) -primary-file %s -emit-ir | %FileCheck --check-prefix=CHECK --check-prefix=CHECK-%target-ptrsize %s
// REQUIRES: objc_interop
import Swift
import Foundation
class SwiftClass {}
sil_vtable SwiftClass {}
protocol ClassProto : class {}
// CHECK-LABEL: define hidden swiftcc ptr @checkedClassBoundCast(ptr %0, ptr %1, ptr %T) #0 {
// CHECK: call ptr @llvm.objc.retain(ptr %1)
// CHECK: [[OPAQUE_RESULT:%.+]] = call ptr @swift_dynamicCastUnknownClassUnconditional(ptr %1, ptr %T, {{.*}})
// CHECK: ret ptr [[OPAQUE_RESULT]]
// CHECK: {{^}$}}
sil hidden @checkedClassBoundCast : $@convention(thin) <T where T : NSObject> (@thick T.Type, @owned NSObject) -> @owned T {
bb0(%unused : $@thick T.Type, %obj : $NSObject):
strong_retain %obj : $NSObject
%result = unconditional_checked_cast %obj : $NSObject to T
strong_release %obj : $NSObject
return %result : $T
}
// rdar://24924966
// CHECK-LABEL: define hidden swiftcc void @metatype_to_objc_class(ptr %0, ptr %T)
// CHECK: [[T0:%.*]] = call ptr @swift_dynamicCastMetatypeToObjectUnconditional(ptr %0, {{.*}})
// TODO: is this really necessary? also, this really shouldn't use a direct reference
// CHECK-NEXT: [[T2a:%.*]] = load ptr, ptr @"OBJC_CLASS_REF_$_Foo"
// CHECK-NEXT: [[T2:%.*]] = call ptr @{{.*}}(ptr [[T2a]])
// CHECK-NEXT: call ptr @swift_dynamicCastObjCClassUnconditional(ptr [[T0]], ptr [[T2]], {{.*}})
sil hidden @metatype_to_objc_class : $@convention(thin) <T> (@thick T.Type) -> () {
bb0(%metatype : $@thick T.Type):
%result = unconditional_checked_cast %metatype : $@thick T.Type to Foo
%tuple = tuple ()
return %tuple : $()
}
// CHECK-LABEL: define hidden swiftcc void @opt_metatype_to_objc_class({{(i32|i64)}} %0, ptr %T)
// CHECK: [[ARG:%.*]] = inttoptr {{.*}} %0 to ptr
// CHECK: [[T0:%.*]] = call ptr @swift_dynamicCastMetatypeToObjectUnconditional(ptr [[ARG]], {{.*}})
// TODO: is this really necessary? also, this really shouldn't use a direct reference
// CHECK-NEXT: [[T2a:%.*]] = load ptr, ptr @"OBJC_CLASS_REF_$_Foo"
// CHECK-NEXT: [[T2:%.*]] = call ptr @{{.*}}(ptr [[T2a]])
// CHECK-NEXT: call ptr @swift_dynamicCastObjCClassUnconditional(ptr [[T0]], ptr [[T2]], {{.*}})
sil hidden @opt_metatype_to_objc_class : $@convention(thin) <T> (Optional<@thick T.Type>) -> () {
bb0(%metatype : $Optional<@thick T.Type>):
%result = unconditional_checked_cast %metatype : $Optional<@thick T.Type> to Foo
%tuple = tuple ()
return %tuple : $()
}
// CHECK-LABEL: define hidden swiftcc { ptr, ptr } @swift_class_bounded_to_cp
// CHECK-SAME: (ptr %0, ptr %T)
// CHECK: [[TYPE:%.*]] = load ptr, ptr %0,
// CHECK-NEXT: call { ptr, ptr } @dynamic_cast_existential_1_unconditional(ptr %0, ptr [[TYPE]], {{.*}} @"$s10objc_casts10ClassProtoMp"
sil hidden @swift_class_bounded_to_cp : $@convention(thin) <T: SwiftClass> (@owned T) -> @owned ClassProto {
entry(%a : $T):
%0 = unconditional_checked_cast %a : $T to ClassProto
return %0 : $ClassProto
}
// CHECK-LABEL: define hidden swiftcc { ptr, ptr } @objc_class_bounded_to_cp
// CHECK-SAME: (ptr %0, ptr %T)
// CHECK: [[TYPE:%.*]] = call ptr @swift_getObjectType(ptr %0)
// CHECK-NEXT: call { ptr, ptr } @dynamic_cast_existential_1_unconditional(ptr %0, ptr [[TYPE]], {{.*}} @"$s10objc_casts10ClassProtoMp"
sil hidden @objc_class_bounded_to_cp : $@convention(thin) <T: NSObject> (@owned T) -> @owned ClassProto {
entry(%a : $T):
%0 = unconditional_checked_cast %a : $T to ClassProto
return %0 : $ClassProto
}
|
