1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
|
// RUN: %target-sil-opt -dont-abort-on-memory-lifetime-errors -verify-continue-on-failure -enable-sil-verify-all=0 %s -o /dev/null 2>&1 | %FileCheck %s
// Memory lifetime verifier also raises errors in some of these cases, add dont-abort-on-memory-lifetime-errors so that we don't check it's output.
// Memory lifetime verifier cannot subsume this because the verification is disabled on unreachable paths.
import Builtin
class Klass {}
struct NonTrivialStruct {
var val: Klass
}
sil @use_owned : $@convention(thin) (@owned Klass) -> ()
sil @use_guaranteed : $@convention(thin) (@guaranteed Klass) -> ()
sil @get_owned : $@convention(thin) () -> @owned Klass
// CHECK: Begin Error in function test_missing_end_borrow_single
// CHECK: SIL verification failed: return with operations still active: state.ActiveOps.empty()
// CHECK: Verifying instruction:
// CHECK: %4 = tuple () // user: %5
// CHECK: -> return %4 : $() // id: %5
// CHECK: End Error in function test_missing_end_borrow_single
sil [ossa] @test_missing_end_borrow_single : $@convention(thin) (@guaranteed Klass) -> () {
bb0(%0 : @guaranteed $Klass):
%stk = alloc_stack $Klass
%ra = store_borrow %0 to %stk : $*Klass
dealloc_stack %stk : $*Klass
%1 = tuple ()
return %1 : $()
}
// CHECK: Begin Error in function test_missing_end_borrow
// CHECK: SIL verification failed: return with operations still active: state.ActiveOps.empty()
// CHECK: Verifying instruction:
// CHECK: %8 = tuple () // user: %9
// CHECK: -> return %8 : $() // id: %9
// CHECK: End Error in function test_missing_end_borrow
sil [ossa] @test_missing_end_borrow : $@convention(thin) (@guaranteed Klass) -> () {
bb0(%0 : @guaranteed $Klass):
%stk = alloc_stack $Klass
%ra = store_borrow %0 to %stk : $*Klass
cond_br undef, bb1, bb2
bb1:
end_borrow %ra : $*Klass
br bb3
bb2:
br bb3
bb3:
dealloc_stack %stk : $*Klass
%1 = tuple ()
return %1 : $()
}
// CHECK: Begin Error in function test_missing_end_borrow
// CHECK: SIL verification failed: inconsistent active-operations sets entering basic block: state.ActiveOps == foundState.ActiveOps || isUnreachable()
// CHECK: Verifying instruction:
// CHECK: -> br bb3 // id: %5
// CHECK: End Error in function test_missing_end_borrow
sil [ossa] @test_missing_end_borrow_dead : $@convention(thin) (@guaranteed Klass) -> () {
bb0(%0 : @guaranteed $Klass):
%stk = alloc_stack $Klass
%ra = store_borrow %0 to %stk : $*Klass
cond_br undef, bb1, bb2
bb1:
end_borrow %ra : $*Klass
br bb3
bb2:
unreachable
bb3:
dealloc_stack %stk : $*Klass
%1 = tuple ()
return %1 : $()
}
// CHECK: Begin Error in function test_load_borrow_from_stk
// CHECK: SIL verification failed: A store_borrow destination can be used only via its return address: user == SI || isa<StoreBorrowInst>(user) || isa<DeallocStackInst>(user)
// CHECK: Verifying instruction:
// CHECK: %2 = alloc_stack $Klass // users: %10, %7, %4
// CHECK: %3 = begin_borrow %1 : $Klass // users: %6, %4
// CHECK: -> %4 = store_borrow %3 to %2 : $*Klass // user: %5
// CHECK: end_borrow %4 : $*Klass // id: %5
// CHECK: End Error in function test_load_borrow_from_stk
sil [ossa] @test_load_borrow_from_stk : $@convention(thin) (@guaranteed Klass) -> () {
bb0(%0 : @guaranteed $Klass):
%copy = copy_value %0 : $Klass
%stk = alloc_stack $Klass
%borrow = begin_borrow %copy : $Klass
%ra = store_borrow %borrow to %stk : $*Klass
end_borrow %ra : $*Klass
end_borrow %borrow : $Klass
%ld = load_borrow %stk : $*Klass
end_borrow %ld : $Klass
destroy_value %copy : $Klass
dealloc_stack %stk : $*Klass
%1 = tuple ()
return %1 : $()
}
// CHECK: User found outside scope: end_borrow %3 : $Klass // id: %5
// CHECK: Begin Error in function test_load_borrow_outside_scope
// CHECK: SIL verification failed: Ill formed store_borrow scope
// CHECK: Verifying instruction:
// CHECK: %0 = argument of bb0 : $Klass // user: %2
// CHECK: %1 = alloc_stack $Klass // users: %6, %2
// CHECK: -> %2 = store_borrow %0 to %1 : $*Klass // users: %4, %3
// CHECK: %3 = load_borrow %2 : $*Klass // user: %5
// CHECK: end_borrow %2 : $*Klass // id: %4
// CHECK: End Error in function test_load_borrow_outside_scope
sil [ossa] @test_load_borrow_outside_scope : $@convention(thin) (@guaranteed Klass) -> () {
bb0(%0 : @guaranteed $Klass):
%stk = alloc_stack $Klass
%ra = store_borrow %0 to %stk : $*Klass
%ld = load_borrow %ra : $*Klass
end_borrow %ra : $*Klass
end_borrow %ld : $Klass
dealloc_stack %stk : $*Klass
%1 = tuple ()
return %1 : $()
}
// FIXME: SILVerifier checkStoreBorrowInst needs to be fixed to
// successfully compute liveness of a load_borrow that contains a
// store_borrow.
//
// HECK: Begin Error in function test_load_borrow_store_borrow_nested
// HECK: SIL verification failed: A store_borrow cannot be nested within another store_borrow to its destination
// HECK: Verifying instruction:
// HECK: %0 = argument of bb0 : $Klass // user: %2
// HECK: %1 = alloc_stack $Klass // users: %8, %4, %2
// HECK: -> %2 = store_borrow %0 to %1 : $*Klass // users: %7, %3
// HECK: %3 = load_borrow %2 : $*Klass // users: %6, %4
// HECK: end_borrow %2 : $*Klass // id: %7
// HECK: End Error in function test_load_borrow_store_borrow_nested
sil [ossa] @test_load_borrow_store_borrow_nested : $@convention(thin) (@guaranteed Klass) -> () {
bb0(%0 : @guaranteed $Klass):
%stk = alloc_stack $Klass
%ra1 = store_borrow %0 to %stk : $*Klass
%ld = load_borrow %ra1 : $*Klass
%ra2 = store_borrow %ld to %stk : $*Klass
end_borrow %ra2 : $*Klass
end_borrow %ld : $Klass
end_borrow %ra1 : $*Klass
dealloc_stack %stk : $*Klass
%1 = tuple ()
return %1 : $()
}
// CHECK: Begin Error in function test_store_borrow_single_block
// CHECK: SIL verification failed: A store_borrow destination can be used only via its return address: user == SI || isa<StoreBorrowInst>(user) || isa<DeallocStackInst>(user)
// CHECK: Verifying instruction:
// CHECK: %0 = argument of bb0 : $Klass // users: %6, %2
// CHECK: %1 = alloc_stack $Klass // users: %8, %6, %4, %3
// CHECK: -> %6 = store_borrow %0 to %1 : $*Klass // user: %7
// CHECK: end_borrow %6 : $*Klass // id: %7
// CHECK: End Error in function test_store_borrow_single_block
sil [ossa] @test_store_borrow_single_block : $@convention(thin) (@guaranteed Klass) -> () {
bb0(%0 : @guaranteed $Klass):
%stk = alloc_stack $Klass
%copy = copy_value %0 : $Klass
store %copy to [init] %stk : $*Klass
%ld = load [take] %stk : $*Klass
destroy_value %ld : $Klass
%sb = store_borrow %0 to %stk : $*Klass
end_borrow %sb : $*Klass
dealloc_stack %stk : $*Klass
%8 = tuple ()
return %8 : $()
}
// CHECK: Begin Error in function test_store_borrow_multi_block
// CHECK: SIL verification failed: A store_borrow destination can be used only via its return address: user == SI || isa<StoreBorrowInst>(user) || isa<DeallocStackInst>(user)
// CHECK: Verifying instruction:
// CHECK: %0 = argument of bb0 : $Klass // users: %7, %2
// CHECK: %1 = alloc_stack $Klass // users: %9, %7, %4, %3
// CHECK: -> %7 = store_borrow %0 to %1 : $*Klass // user: %8
// CHECK: end_borrow %7 : $*Klass // id: %8
// CHECK: End Error in function test_store_borrow_multi_block
sil [ossa] @test_store_borrow_multi_block : $@convention(thin) (@guaranteed Klass) -> () {
bb0(%0 : @guaranteed $Klass):
%stk = alloc_stack $Klass
%copy = copy_value %0 : $Klass
store %copy to [init] %stk : $*Klass
%ld = load [take] %stk : $*Klass
destroy_value %ld : $Klass
br bb1
bb1:
%sb = store_borrow %0 to %stk : $*Klass
end_borrow %sb : $*Klass
dealloc_stack %stk : $*Klass
%8 = tuple ()
return %8 : $()
}
// CHECK: Begin Error in function test_store_borrow_dest
// CHECK: SIL verification failed: store_borrow destination can only be an alloc_stack: isLegal(SI->getDest())
// CHECK: Verifying instruction:
// CHECK: %0 = argument of bb0 : $Klass // user: %3
// CHECK: %2 = struct_element_addr %1 : $*NonTrivialStruct, #NonTrivialStruct.val // user: %3
// CHECK: -> %3 = store_borrow %0 to %2 : $*Klass // user: %4
// CHECK: end_borrow %3 : $*Klass // id: %4
// CHECK: End Error in function test_store_borrow_dest
sil [ossa] @test_store_borrow_dest : $@convention(thin) (@guaranteed Klass) -> () {
bb0(%0 : @guaranteed $Klass):
%stk = alloc_stack $NonTrivialStruct
%addr = struct_element_addr %stk : $*NonTrivialStruct, #NonTrivialStruct.val
%ra = store_borrow %0 to %addr : $*Klass
end_borrow %ra : $*Klass
dealloc_stack %stk : $*NonTrivialStruct
%1 = tuple ()
return %1 : $()
}
// CHECK: Begin Error in function test_store_borrow_within_store_borrow1
// CHECK: SIL verification failed: A store_borrow cannot be nested within another store_borrow to its destination
// CHECK: Verifying instruction:
// CHECK: %0 = argument of bb0 : $Klass // users: %3, %2
// CHECK: %1 = alloc_stack $Klass // users: %6, %3, %2
// CHECK: -> %2 = store_borrow %0 to %1 : $*Klass // user: %5
// CHECK: end_borrow %2 : $*Klass // id: %5
// CHECK: End Error in function test_store_borrow_within_store_borrow1
sil [ossa] @test_store_borrow_within_store_borrow1 : $@convention(thin) (@guaranteed Klass) -> () {
bb0(%0 : @guaranteed $Klass):
%stk = alloc_stack $Klass
%ra1 = store_borrow %0 to %stk : $*Klass
%ra2 = store_borrow %0 to %stk : $*Klass
end_borrow %ra2 : $*Klass
end_borrow %ra1 : $*Klass
dealloc_stack %stk : $*Klass
%1 = tuple ()
return %1 : $()
}
// CHECK: Begin Error in function test_store_borrow_within_store_borrow2
// CHECK: SIL verification failed: A store_borrow cannot be nested within another store_borrow to its destination
// CHECK: Verifying instruction:
// CHECK: %0 = argument of bb0 : $Klass // users: %3, %2
// CHECK: %1 = alloc_stack $Klass // users: %9, %3, %2
// CHECK: -> %2 = store_borrow %0 to %1 : $*Klass // user: %6
// CHECK: end_borrow %2 : $*Klass // id: %6
// CHECK: End Error in function test_store_borrow_within_store_borrow2
sil [ossa] @test_store_borrow_within_store_borrow2 : $@convention(thin) (@guaranteed Klass) -> () {
bb0(%0 : @guaranteed $Klass):
%stk = alloc_stack $Klass
%ra1 = store_borrow %0 to %stk : $*Klass
%ra2 = store_borrow %0 to %stk : $*Klass
cond_br undef, bb1, bb2
bb1:
end_borrow %ra2 : $*Klass
end_borrow %ra1 : $*Klass
br bb3
bb2:
unreachable
bb3:
dealloc_stack %stk : $*Klass
%1 = tuple ()
return %1 : $()
}
|
