1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
|
// RUN: %target-sil-opt -copy-propagation -enable-sil-verify-all %s | %FileCheck %s --check-prefixes=CHECK,CHECK-OPT
class X {}
enum FakeOptional<T> {
case some(T)
case none
}
sil [ossa] @getX : $@convention(thin) () -> (@owned X)
sil [ossa] @holdX : $@convention(thin) (@guaranteed X) -> ()
// CHECK-LABEL: sil [ossa] @nohoist_destroy_over_reborrow_endborrow : {{.*}} {
// CHECK: {{bb[0-9]+}}([[REBORROW:%[^,]+]] : @reborrow @guaranteed $X, [[VALUE:%[^,]+]] : @owned $X):
// CHECK: end_borrow [[REBORROW]]
// CHECK: destroy_value [[VALUE]]
// CHECK-LABEL: } // end sil function 'nohoist_destroy_over_reborrow_endborrow'
sil [ossa] @nohoist_destroy_over_reborrow_endborrow : $@convention(thin) () -> () {
entry:
%get = function_ref @getX : $@convention(thin) () -> @owned X
%value_1 = apply %get() : $@convention(thin) () -> @owned X
%lifetime = begin_borrow %value_1 : $X
br body(%lifetime : $X, %value_1 : $X)
body(%reborrow : @guaranteed $X, %value_2 : @owned $X):
end_borrow %reborrow : $X
destroy_value %value_2 : $X
br exit
exit:
%retval = tuple ()
return %retval : $()
}
// CHECK-LABEL: sil [ossa] @hoist_destroy_over_unrelated_endborrow : {{.*}} {
// CHECK: {{bb[0-9]+}}([[UNRELATED:%[^,]+]] : @reborrow @guaranteed $X, [[VALUE:%[^,]+]] : @owned $X):
// CHECK: destroy_value [[VALUE]]
// CHECK: end_borrow [[UNRELATED]]
// CHECK-LABEL: } // end sil function 'hoist_destroy_over_unrelated_endborrow'
sil [ossa] @hoist_destroy_over_unrelated_endborrow : $@convention(thin) (@guaranteed X) -> () {
entry(%unrelated : @guaranteed $X):
%get = function_ref @getX : $@convention(thin) () -> @owned X
%value_1 = apply %get() : $@convention(thin) () -> @owned X
%borrow_1 = begin_borrow %unrelated : $X
br body(%borrow_1 : $X, %value_1 : $X)
body(%borrow_2 : @guaranteed $X, %value_2 : @owned $X):
%hold = function_ref @holdX : $@convention(thin) (@guaranteed X) -> ()
apply %hold(%borrow_2) : $@convention(thin) (@guaranteed X) -> ()
end_borrow %borrow_2 : $X
destroy_value %value_2 : $X
br exit
exit:
%retval = tuple ()
return %retval : $()
}
// CHECK-LABEL: sil [ossa] @nohoist_destroy_over_reborrow_reborrow_endborrow : {{.*}} {
// CHECK: {{bb[0-9]+}}({{%[^,]+}} : @reborrow @guaranteed $X, {{%[^,]+}} : @owned $X):
// CHECK: {{bb[0-9]+}}([[REBORROW:%[^,]+]] : @reborrow @guaranteed $X, [[VALUE:%[^,]+]] : @owned $X):
// CHECK: end_borrow [[REBORROW]]
// CHECK: destroy_value [[VALUE]]
// CHECK-LABEL: } // end sil function 'nohoist_destroy_over_reborrow_reborrow_endborrow'
sil [ossa] @nohoist_destroy_over_reborrow_reborrow_endborrow : $@convention(thin) () -> () {
entry:
%get = function_ref @getX : $@convention(thin) () -> @owned X
%value_1 = apply %get() : $@convention(thin) () -> @owned X
%lifetime = begin_borrow %value_1 : $X
br body1(%lifetime : $X, %value_1 : $X)
body1(%lifetime_2 : @guaranteed $X, %value_2 : @owned $X):
br body2(%lifetime_2 : $X, %value_2 : $X)
body2(%lifetime_3 : @guaranteed $X, %value_3 : @owned $X):
end_borrow %lifetime_3 : $X
destroy_value %value_3 : $X
br exit
exit:
%14 = tuple ()
return %14 : $()
}
// CHECK-LABEL: sil [ossa] @hoist_destroy_over_unrelated_reborrow_reborrow_endborrow : {{.*}} {
// CHECK: {{bb[0-9]+}}({{%[^,]+}} : @reborrow @guaranteed $X, {{%[^,]+}} : @owned $X):
// CHECK: {{bb[0-9]+}}([[REBORROW:%[^,]+]] : @reborrow @guaranteed $X, [[VALUE:%[^,]+]] : @owned $X):
// CHECK: destroy_value [[VALUE]]
// CHECK: end_borrow [[REBORROW]]
// CHECK-LABEL: } // end sil function 'hoist_destroy_over_unrelated_reborrow_reborrow_endborrow'
sil [ossa] @hoist_destroy_over_unrelated_reborrow_reborrow_endborrow : $@convention(thin) (@guaranteed X) -> () {
entry(%unrelated : @guaranteed $X):
%get = function_ref @getX : $@convention(thin) () -> @owned X
%value_1 = apply %get() : $@convention(thin) () -> @owned X
%borrow_1 = begin_borrow %unrelated : $X
br body1(%borrow_1 : $X, %value_1 : $X)
body1(%borrow_2 : @guaranteed $X, %value_2 : @owned $X):
br body2(%borrow_2 : $X, %value_2 : $X)
body2(%borrow_3 : @guaranteed $X, %value_3 : @owned $X):
%hold = function_ref @holdX : $@convention(thin) (@guaranteed X) -> ()
apply %hold(%borrow_3) : $@convention(thin) (@guaranteed X) -> ()
end_borrow %borrow_3 : $X
destroy_value %value_3 : $X
br exit
exit:
%14 = tuple ()
return %14 : $()
}
// CHECK-LABEL: sil [ossa] @nohoist_destroy_over_forward_reborrow_endborrow : {{.*}} {
// CHECK: {{bb[0-9]+}}([[REBORROW:%[^,]+]] : @reborrow @guaranteed $X, [[VALUE:%[^,]+]] : @owned $X):
// CHECK: end_borrow [[REBORROW]]
// CHECK: destroy_value [[VALUE]]
// CHECK-LABEL: } // end sil function 'nohoist_destroy_over_forward_reborrow_endborrow'
sil [ossa] @nohoist_destroy_over_forward_reborrow_endborrow : $@convention(thin) () -> () {
entry:
%get = function_ref @getX : $@convention(thin) () -> @owned X
%value_1 = apply %get() : $@convention(thin) () -> @owned X
br body1(%value_1 : $X)
body1(%value_2 : @owned $X):
%lifetime_2 = begin_borrow %value_2 : $X
br body2(%lifetime_2 : $X, %value_2 : $X)
body2(%lifetime_3 : @guaranteed $X, %value_3 : @owned $X):
end_borrow %lifetime_3 : $X
destroy_value %value_3 : $X
br exit
exit:
%retval = tuple ()
return %retval : $()
}
// CHECK-LABEL: sil [ossa] @nohoist_destroy_over_reborrow_loop : {{.*}} {
// CHECK: {{bb[0-9]+}}([[REBORROW:%[^,]+]] : @reborrow @guaranteed $FakeOptional<X>, [[VALUE:%[^,]+]] : @owned $FakeOptional<X>):
// CHECK: cond_br undef, [[LOOP:bb[0-9]+]], [[BODY:bb[0-9]+]]
// CHECK: [[LOOP]]:
// CHECK: end_borrow [[REBORROW]] : $FakeOptional<X>
// CHECK: destroy_value [[VALUE]] : $FakeOptional<X>
// CHECK: [[BODY]]:
// CHECK: end_borrow [[REBORROW]] : $FakeOptional<X>
// CHECK: destroy_value [[VALUE]] : $FakeOptional<X>
// CHECK-LABEL: } // end sil function 'nohoist_destroy_over_reborrow_loop'
sil [ossa] @nohoist_destroy_over_reborrow_loop : $@convention(thin) () -> () {
entry:
%none1 = enum $FakeOptional<X>, #FakeOptional.none!enumelt
%none2 = enum $FakeOptional<X>, #FakeOptional.none!enumelt
%none_borrow_2 = begin_borrow %none2 : $FakeOptional<X>
br head(%none_borrow_2 : $FakeOptional<X>, %none1 : $FakeOptional<X>)
head(%reborrow : @guaranteed $FakeOptional<X>, %value : @owned $FakeOptional<X>):
cond_br undef, body, exit
body:
%get = function_ref @getX : $@convention(thin) () -> (@owned X)
%value_0 = apply %get() : $@convention(thin) () -> (@owned X)
end_borrow %reborrow : $FakeOptional<X>
destroy_value %value : $FakeOptional<X>
%some_value_0 = enum $FakeOptional<X>, #FakeOptional.some!enumelt, %value_0 : $X
%some_borrow_0 = begin_borrow %some_value_0 : $FakeOptional<X>
br head(%some_borrow_0 : $FakeOptional<X>, %some_value_0 : $FakeOptional<X>)
exit:
%retval = tuple ()
end_borrow %reborrow : $FakeOptional<X>
destroy_value %value : $FakeOptional<X>
return %retval : $()
}
// Ensure that an adjacent reborrow phi being reborrowed doesn't get counted as
// a non-lifetime ending use and extend liveness beyond the instruction where
// the reborrow occurs.
// CHECK-LABEL: sil [ossa] @reborrow_adjacent_to_consume_doesnt_extend_lifetime : {{.*}} {
// CHECK: bb1([[REBORROW:%[^,]+]] : @reborrow @guaranteed $X, [[VALUE:%[^,]+]] :
// CHECK: {{bb[0-9]+}}:
// CHECK: end_borrow [[REBORROW]]
// CHECK: destroy_value [[VALUE]]
// CHECK-LABEL: } // end sil function 'reborrow_adjacent_to_consume_doesnt_extend_lifetime'
sil [ossa] @reborrow_adjacent_to_consume_doesnt_extend_lifetime : $@convention(thin) (@owned X) -> () {
bb0(%0 : @owned $X):
%1 = begin_borrow %0 : $X
br bb1(%1 : $X, %0 : $X)
bb1(%3 : @guaranteed $X, %4 : @owned $X):
cond_br undef, bb2, bb10
bb2:
br bb3
bb3:
br bb4(%3 : $X, %4 : $X)
bb4(%8 : @guaranteed $X, %9 : @owned $X):
cond_br undef, bb5, bb8
bb5:
br bb6
bb6:
br bb7
bb7:
%13 = function_ref @getX : $@convention(thin) () -> @owned X
%14 = apply %13() : $@convention(thin) () -> @owned X
end_borrow %8 : $X
destroy_value %9 : $X
%17 = begin_borrow %14 : $X
br bb4(%17 : $X, %14 : $X)
bb8:
br bb9
bb9:
br bb1(%8 : $X, %9 : $X)
bb10:
%23 = tuple ()
end_borrow %3 : $X
destroy_value %4 : $X
return %23 : $()
}
// CHECK-LABEL: sil [ossa] @nohoist_destroy_over_endborrow_nonadjacent_reborrow : {{.*}} {
// CHECK: end_borrow {{%[^,]+}}
// CHECK: destroy_value {{%[^,]+}}
// CHECK-LABEL: } // end sil function 'nohoist_destroy_over_endborrow_nonadjacent_reborrow'
sil [ossa] @nohoist_destroy_over_endborrow_nonadjacent_reborrow : $@convention(thin) (@owned X) -> () {
entry(%value_1 : @owned $X):
%lifetime_1 = begin_borrow %value_1 : $X
br consume_and_reborrow(%lifetime_1 : $X, %value_1 : $X)
consume_and_reborrow(%lifetime_2 : @guaranteed $X, %value_2 : @owned $X):
br reborrow_only(%lifetime_2 : $X)
reborrow_only(%lifetime_3 : @guaranteed $X):
br exit
exit:
%retval = tuple ()
end_borrow %lifetime_3 : $X
destroy_value %value_2 : $X
return %retval : $()
}
// CHECK-LABEL: sil [ossa] @nohoist_destroy_over_endborrow_nonadjacent_reborrow_2 : {{.*}} {
// CHECK: end_borrow {{%[^,]+}}
// CHECK: destroy_value {{%[^,]+}}
// CHECK-LABEL: } // end sil function 'nohoist_destroy_over_endborrow_nonadjacent_reborrow_2'
sil [ossa] @nohoist_destroy_over_endborrow_nonadjacent_reborrow_2 : $@convention(thin) (@owned X) -> () {
entry(%value_1 : @owned $X):
%lifetime_1 = begin_borrow %value_1 : $X
br consume_and_reborrow(%lifetime_1 : $X, %value_1 : $X)
consume_and_reborrow(%lifetime_2 : @guaranteed $X, %value_2 : @owned $X):
br reborrow_only_1(%lifetime_2 : $X)
reborrow_only_1(%lifetime_3 : @guaranteed $X):
br reborrow_only_2(%lifetime_3 : $X)
reborrow_only_2(%lifetime_4 : @guaranteed $X):
br exit
exit:
%retval = tuple ()
end_borrow %lifetime_4 : $X
destroy_value %value_2 : $X
return %retval : $()
}
// The owned phi %5 has an inner adjacent phi %4, so its end_borrow is
// considered a use of the owned lifetime. The end_borrow/destroy
// maintain their position.
//
// CHECK-LABEL: sil [ossa] @reborrow_adjacent_to_ownedphi : $@convention(thin) (@owned X) -> () {
// CHECK: end_borrow
// CHECK: destroy_value
sil [ossa] @reborrow_adjacent_to_ownedphi : $@convention(thin) (@owned X) -> () {
bb0(%0 : @owned $X):
%1 = begin_borrow %0 : $X
br bb1(%1 : $X, %0 : $X)
bb1(%4 : @guaranteed $X, %5 : @owned $X):
end_borrow %4 : $X
destroy_value %5 : $X
%23 = tuple ()
return %23 : $()
}
// The owned phi %5 has an inner adjacent phi %4, so its reborrow use,
// %6 is considered a use of the owned value. Since %5 is also
// consumed by an owned phi in bb2, the owned lifetime extends no further.
//
// Lifetime analysis is successful; the copy/destroy in bb1 are removed. The
// end_borrow/destroy maintain their position.
//
// CHECK-LABEL: sil [ossa] @reborrow_adjacent_to_consume : $@convention(thin) () -> () {
// CHECK: bb1(%{{.*}} : @reborrow @guaranteed $X, %{{.*}} : @owned $X):
// CHECK-NEXT: br bb2
// CHECK: bb2(%{{.*}} : @reborrow @guaranteed $X, %{{.*}} : @owned $X):
// CHECK-NEXT: end_borrow
// CHECK-NEXT: destroy_value
sil [ossa] @reborrow_adjacent_to_consume : $@convention(thin) () -> () {
bb0:
%0 = apply undef() : $@convention(thin) () -> (@owned X)
%1 = begin_borrow %0 : $X
br bb1(%1 : $X, %0 : $X)
bb1(%4 : @guaranteed $X, %5 : @owned $X):
%copy = copy_value %5 : $X
destroy_value %copy : $X
br bb2(%4 : $X, %5 : $X)
bb2(%6 : @guaranteed $X, %7 : @owned $X):
end_borrow %6 : $X
destroy_value %7 : $X
%23 = tuple ()
return %23 : $()
}
// The owned phi %5 has an inner adjacent phi %4, so its reborrow use,
// %6 is considered a use of the owned value. Since %5 is not consumed
// by an owned phi in bb2, the owned lifetime extends to the uses of
// the second reborrow, %6. The copy/destroy in bb2 are removed. The
// end_borrow/destroy maintain their position.
//
// Lifetime analysis is successful; the copy/destroy in bb2 are removed.
//
// CHECK-LABEL: sil [ossa] @reborrow_no_adjacent_consume : $@convention(thin) () -> () {
// CHECK: bb1(%{{.*}} : @reborrow @guaranteed $X, %{{.*}} : @owned $X):
// CHECK-NEXT: br bb2
// CHECK: bb2(%{{.*}} : @reborrow @guaranteed $X):
// CHECK-NEXT: end_borrow
// CHECK-NEXT: destroy_value
sil [ossa] @reborrow_no_adjacent_consume : $@convention(thin) () -> () {
bb0:
%0 = apply undef() : $@convention(thin) () -> (@owned X)
%1 = begin_borrow %0 : $X
br bb1(%1 : $X, %0 : $X)
bb1(%4 : @guaranteed $X, %5 : @owned $X):
br bb2(%4 : $X)
bb2(%6 : @guaranteed $X):
%copy = copy_value %5 : $X
destroy_value %copy : $X
end_borrow %6 : $X
destroy_value %5 : $X
%23 = tuple ()
return %23 : $()
}
|
