1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
|
// RUN: %target-sil-opt -enable-sil-verify-all %s -cse | %FileCheck %s
sil_stage canonical
import Builtin
class SuperKlass {}
class Klass : SuperKlass {}
struct NonTrivialStruct {
var val : Klass
}
// CHECK-LABEL: sil [ossa] @cse_copy_upcast1 :
// CHECK: upcast
// CHECK-NOT: upcast
// CHECK-LABEL: } // end sil function 'cse_copy_upcast1'
sil [ossa] @cse_copy_upcast1 : $@convention(thin) (@owned Klass) -> @owned (SuperKlass, SuperKlass) {
bb0(%0 : @owned $Klass):
%copy0 = copy_value %0 : $Klass
%1 = upcast %0 : $Klass to $SuperKlass
%2 = upcast %copy0 : $Klass to $SuperKlass
%res = tuple (%1: $SuperKlass, %2: $SuperKlass)
return %res : $(SuperKlass, SuperKlass)
}
// CHECK-LABEL: sil [ossa] @cse_copy_upcast2 :
// CHECK: upcast
// CHECK-NOT: upcast
// CHECK-LABEL: } // end sil function 'cse_copy_upcast2'
sil [ossa] @cse_copy_upcast2 : $@convention(thin) (@owned Klass) -> @owned (SuperKlass, SuperKlass) {
bb0(%0 : @owned $Klass):
%copy0 = copy_value %0 : $Klass
%1 = upcast %copy0 : $Klass to $SuperKlass
%2 = upcast %0 : $Klass to $SuperKlass
%res = tuple (%1: $SuperKlass, %2: $SuperKlass)
return %res : $(SuperKlass, SuperKlass)
}
// CHECK-LABEL: sil [ossa] @cse_copy_upcast3 :
// CHECK: upcast
// CHECK-NOT: upcast
// CHECK-LABEL: } // end sil function 'cse_copy_upcast3'
sil [ossa] @cse_copy_upcast3 : $@convention(thin) (@owned Klass) -> @owned (SuperKlass, SuperKlass) {
bb0(%0 : @owned $Klass):
%copy0 = copy_value %0 : $Klass
%copy1 = copy_value %0 : $Klass
%1 = upcast %copy0 : $Klass to $SuperKlass
%2 = upcast %copy1 : $Klass to $SuperKlass
destroy_value %0 : $Klass
%res = tuple (%1: $SuperKlass, %2: $SuperKlass)
return %res : $(SuperKlass, SuperKlass)
}
// CHECK-LABEL: sil [ossa] @cse_copy_upcast4 :
// CHECK: upcast
// CHECK-NOT: upcast
// CHECK-LABEL: } // end sil function 'cse_copy_upcast4'
sil [ossa] @cse_copy_upcast4 : $@convention(thin) (@guaranteed Klass) -> @owned SuperKlass {
bb0(%0 : @guaranteed $Klass):
%copy0 = copy_value %0 : $Klass
%1 = upcast %0 : $Klass to $SuperKlass
%2 = upcast %copy0 : $Klass to $SuperKlass
destroy_value %2 : $SuperKlass
%copy1 = copy_value %1 : $SuperKlass
return %copy1 : $SuperKlass
}
// CHECK-LABEL: sil [ossa] @cse_copy_upcast5 :
// CHECK: upcast
// CHECK-NOT: upcast
// CHECK-LABEL: } // end sil function 'cse_copy_upcast5'
sil [ossa] @cse_copy_upcast5 : $@convention(thin) (@guaranteed Klass) -> @owned SuperKlass {
bb0(%0 : @guaranteed $Klass):
%copy0 = copy_value %0 : $Klass
%1 = upcast %copy0 : $Klass to $SuperKlass
%2 = upcast %0 : $Klass to $SuperKlass
destroy_value %1 : $SuperKlass
%copy2 = copy_value %2 : $SuperKlass
return %copy2 : $SuperKlass
}
sil [ossa] @useSuperKlass1 : $@convention(thin) (@guaranteed SuperKlass) -> ()
sil [ossa] @useSuperKlass2 : $@convention(thin) (@owned SuperKlass) -> ()
// CHECK-LABEL: sil [ossa] @cse_copy_upcast6 :
// CHECK: upcast
// CHECK-NOT: upcast
// CHECK-LABEL: } // end sil function 'cse_copy_upcast6'
sil [ossa] @cse_copy_upcast6 : $@convention(thin) (@guaranteed Klass) -> @owned SuperKlass {
bb0(%0 : @guaranteed $Klass):
%1 = upcast %0 : $Klass to $SuperKlass
%func = function_ref @useSuperKlass1 : $@convention(thin) (@guaranteed SuperKlass) -> ()
apply %func(%1) : $@convention(thin) (@guaranteed SuperKlass) -> ()
%2 = upcast %0 : $Klass to $SuperKlass
%copy2 = copy_value %2 : $SuperKlass
return %copy2 : $SuperKlass
}
// CHECK-LABEL: sil [ossa] @cse_copy_upcast7 :
// CHECK: upcast
// CHECK-NOT: upcast
// CHECK-LABEL: } // end sil function 'cse_copy_upcast7'
sil [ossa] @cse_copy_upcast7 : $@convention(thin) (@guaranteed Klass) -> () {
bb0(%0 : @guaranteed $Klass):
%copy0 = copy_value %0 : $Klass
%1 = upcast %copy0 : $Klass to $SuperKlass
%2 = upcast %0 : $Klass to $SuperKlass
cond_br undef, bb1, bb2
bb1:
br bb3
bb2:
%copy2 = copy_value %2 : $SuperKlass
%func = function_ref @useSuperKlass2 : $@convention(thin) (@owned SuperKlass) -> ()
apply %func(%copy2) : $@convention(thin) (@owned SuperKlass) -> ()
br bb3
bb3:
destroy_value %1 : $SuperKlass
%res = tuple()
return %res : $()
}
// CHECK-LABEL: sil [ossa] @cse_copy_upcast8 :
// CHECK: upcast
// CHECK-NOT: upcast
// CHECK-LABEL: } // end sil function 'cse_copy_upcast8'
sil [ossa] @cse_copy_upcast8 : $@convention(thin) (@guaranteed Klass) -> @owned SuperKlass {
bb0(%0 : @guaranteed $Klass):
%copy0 = copy_value %0 : $Klass
%borrow0 = begin_borrow %copy0 : $Klass
%1 = upcast %borrow0 : $Klass to $SuperKlass
end_borrow %borrow0 : $Klass
destroy_value %copy0 : $Klass
%2 = upcast %0 : $Klass to $SuperKlass
%copy2 = copy_value %2 : $SuperKlass
return %copy2 : $SuperKlass
}
// CHECK-LABEL: sil [ossa] @cse_copy_unchecked_ref_cast :
// CHECK: unchecked_ref_cast
// CHECK-NOT: unchecked_ref_cast
// CHECK-LABEL: } // end sil function 'cse_copy_unchecked_ref_cast'
sil [ossa] @cse_copy_unchecked_ref_cast : $@convention(thin) (@owned Klass) -> @owned (SuperKlass, SuperKlass) {
bb0(%0 : @owned $Klass):
%copy0 = copy_value %0 : $Klass
%1 = unchecked_ref_cast %0 : $Klass to $SuperKlass
%2 = unchecked_ref_cast %copy0 : $Klass to $SuperKlass
%res = tuple (%1: $SuperKlass, %2: $SuperKlass)
return %res : $(SuperKlass, SuperKlass)
}
// CHECK-LABEL: sil [ossa] @cse_copy_upcast_destroy_before_common_expr :
// CHECK: upcast
// CHECK-NOT: upcast
// CHECK-LABEL: } // end sil function 'cse_copy_upcast_destroy_before_common_expr'
sil [ossa] @cse_copy_upcast_destroy_before_common_expr : $@convention(thin) (@owned Klass) -> @owned SuperKlass {
bb0(%0 : @owned $Klass):
%copy0 = copy_value %0 : $Klass
%1 = upcast %0 : $Klass to $SuperKlass
destroy_value %1 : $SuperKlass
%2 = upcast %copy0 : $Klass to $SuperKlass
return %2 : $SuperKlass
}
// CHECK-LABEL: sil [ossa] @cse_copy_upcast_need_destroys :
// CHECK-NOT: upcast
// CHECK-LABEL: } // end sil function 'cse_copy_upcast_need_destroys'
sil [ossa] @cse_copy_upcast_need_destroys : $@convention(thin) (@owned Klass) -> () {
bb0(%0 : @owned $Klass):
%copy0 = copy_value %0 : $Klass
%1 = upcast %0 : $Klass to $SuperKlass
destroy_value %1 : $SuperKlass
cond_br undef, bb1, bb2
bb1:
%2 = upcast %copy0 : $Klass to $SuperKlass
destroy_value %2 : $SuperKlass
br bb3
bb2:
destroy_value %copy0 : $Klass
br bb3
bb3:
%res = tuple ()
return %res : $()
}
// CHECK-LABEL: sil [ossa] @cse_copy_upcast_multiple_identity :
// CHECK: upcast
// CHECK-NOT: upcast
// CHECK-LABEL: } // end sil function 'cse_copy_upcast_multiple_identity'
sil [ossa] @cse_copy_upcast_multiple_identity : $@convention(thin) (@owned Klass) -> @owned SuperKlass {
bb0(%0 : @owned $Klass):
%copy0 = copy_value %0 : $Klass
%copy00 = copy_value %copy0 : $Klass
%1 = upcast %0 : $Klass to $SuperKlass
destroy_value %1 : $SuperKlass
%2 = upcast %copy00 : $Klass to $SuperKlass
destroy_value %copy0 : $Klass
return %2 : $SuperKlass
}
// CHECK-LABEL: sil [ossa] @cse_borrow_upcast :
// CHECK: upcast
// CHECK-NOT: upcast
// CHECK-LABEL: } // end sil function 'cse_borrow_upcast'
sil [ossa] @cse_borrow_upcast : $@convention(thin) (@owned Klass) -> @owned (SuperKlass, SuperKlass) {
bb0(%0 : @owned $Klass):
%borrow = begin_borrow %0 : $Klass
%copy0_1 = copy_value %borrow : $Klass
%copy0_2 = copy_value %borrow : $Klass
%1 = upcast %copy0_1 : $Klass to $SuperKlass
%2 = upcast %copy0_2 : $Klass to $SuperKlass
end_borrow %borrow : $Klass
destroy_value %0 : $Klass
%res = tuple (%1: $SuperKlass, %2: $SuperKlass)
return %res : $(SuperKlass, SuperKlass)
}
|
