1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
|
// RUN: %target-sil-opt -enable-sil-verify-all %s -lower-hop-to-actor | %FileCheck %s
// REQUIRES: concurrency
sil_stage canonical
import Builtin
import Swift
import _Concurrency
actor MyActor {
@_hasStorage private var p: Int { get set }
}
actor CustomActor {
nonisolated var unownedExecutor: UnownedSerialExecutor { get }
}
// CHECK-LABEL: sil [ossa] @simple :
sil [ossa] @simple : $@async (@guaranteed MyActor) -> () {
bb0(%0 : @guaranteed $MyActor):
// CHECK: bb0(%0 : @guaranteed $MyActor):
// CHECK-NEXT: [[EXECUTOR:%.*]] = builtin "buildDefaultActorExecutorRef"<MyActor>(%0 : $MyActor) : $Builtin.Executor
// CHECK-NEXT: [[SOME:%.*]] = enum $Optional<Builtin.Executor>, #Optional.some!enumelt, [[EXECUTOR]] : $Builtin.Executor
// CHECK-NEXT: [[DEPEND:%.*]] = mark_dependence [[SOME]] : $Optional<Builtin.Executor> on %0 : $MyActor
// CHECK-NEXT: hop_to_executor [[DEPEND]] : $Optional<Builtin.Executor>
// CHECK-NEXT: [[RET:%.*]] = tuple ()
// CHECK-NEXT: return [[RET]] : $()
hop_to_executor %0 : $MyActor
%r = tuple ()
return %r : $()
}
// CHECK-LABEL: sil [ossa] @pair :
sil [ossa] @pair : $@async (@guaranteed MyActor, @guaranteed MyActor) -> () {
bb0(%0 : @guaranteed $MyActor, %1 : @guaranteed $MyActor):
// CHECK: bb0(%0 : @guaranteed $MyActor, %1 : @guaranteed $MyActor):
// CHECK-NEXT: [[EXECUTOR:%.*]] = builtin "buildDefaultActorExecutorRef"<MyActor>(%0 : $MyActor) : $Builtin.Executor
// CHECK-NEXT: [[SOME:%.*]] = enum $Optional<Builtin.Executor>, #Optional.some!enumelt, [[EXECUTOR]] : $Builtin.Executor
// CHECK-NEXT: [[DEPEND:%.*]] = mark_dependence [[SOME]] : $Optional<Builtin.Executor> on %0 : $MyActor
// CHECK-NEXT: hop_to_executor [[DEPEND]] : $Optional<Builtin.Executor>
// CHECK-NEXT: [[EXECUTOR:%.*]] = builtin "buildDefaultActorExecutorRef"<MyActor>(%1 : $MyActor) : $Builtin.Executor
// CHECK-NEXT: [[SOME:%.*]] = enum $Optional<Builtin.Executor>, #Optional.some!enumelt, [[EXECUTOR]] : $Builtin.Executor
// CHECK-NEXT: [[DEPEND:%.*]] = mark_dependence [[SOME]] : $Optional<Builtin.Executor> on %1 : $MyActor
// CHECK-NEXT: hop_to_executor [[DEPEND]] : $Optional<Builtin.Executor>
// CHECK-NEXT: [[RET:%.*]] = tuple ()
// CHECK-NEXT: return [[RET]] : $()
hop_to_executor %0 : $MyActor
hop_to_executor %1 : $MyActor
%r = tuple ()
return %r : $()
}
// CHECK-LABEL: sil [ossa] @immediate_dominance :
sil [ossa] @immediate_dominance : $@async (@guaranteed MyActor) -> () {
bb0(%0 : @guaranteed $MyActor):
// CHECK: bb0(%0 : @guaranteed $MyActor):
// CHECK-NEXT: [[EXECUTOR:%.*]] = builtin "buildDefaultActorExecutorRef"<MyActor>(%0 : $MyActor) : $Builtin.Executor
// CHECK-NEXT: [[SOME:%.*]] = enum $Optional<Builtin.Executor>, #Optional.some!enumelt, [[EXECUTOR]] : $Builtin.Executor
// CHECK-NEXT: [[DEPEND:%.*]] = mark_dependence [[SOME]] : $Optional<Builtin.Executor> on %0 : $MyActor
// CHECK-NEXT: hop_to_executor [[DEPEND]] : $Optional<Builtin.Executor>
// CHECK-NEXT: hop_to_executor [[DEPEND]] : $Optional<Builtin.Executor>
// CHECK-NEXT: [[RET:%.*]] = tuple ()
// CHECK-NEXT: return [[RET]] : $()
hop_to_executor %0 : $MyActor
hop_to_executor %0 : $MyActor
%r = tuple ()
return %r : $()
}
// CHECK-LABEL: sil [ossa] @multi_block :
sil [ossa] @multi_block : $@async (@guaranteed MyActor, Builtin.Int1) -> () {
bb0(%0 : @guaranteed $MyActor, %1 : $Builtin.Int1):
// CHECK: bb0(%0 : @guaranteed $MyActor, %1 : $Builtin.Int1):
// CHECK-NEXT: cond_br %1, bb1, bb2
// CHECK: bb1:
// CHECK-NEXT: [[EXECUTOR:%.*]] = builtin "buildDefaultActorExecutorRef"<MyActor>(%0 : $MyActor) : $Builtin.Executor
// CHECK-NEXT: [[SOME:%.*]] = enum $Optional<Builtin.Executor>, #Optional.some!enumelt, [[EXECUTOR]] : $Builtin.Executor
// CHECK-NEXT: [[DEPEND:%.*]] = mark_dependence [[SOME]] : $Optional<Builtin.Executor> on %0 : $MyActor
// CHECK-NEXT: hop_to_executor [[DEPEND]] : $Optional<Builtin.Executor>
// CHECK-NEXT: br bb3
// CHECK: bb2:
// CHECK-NEXT: [[EXECUTOR:%.*]] = builtin "buildDefaultActorExecutorRef"<MyActor>(%0 : $MyActor) : $Builtin.Executor
// CHECK-NEXT: [[SOME:%.*]] = enum $Optional<Builtin.Executor>, #Optional.some!enumelt, [[EXECUTOR]] : $Builtin.Executor
// CHECK-NEXT: [[DEPEND:%.*]] = mark_dependence [[SOME]] : $Optional<Builtin.Executor> on %0 : $MyActor
// CHECK-NEXT: hop_to_executor [[DEPEND]] : $Optional<Builtin.Executor>
// CHECK-NEXT: br bb3
// CHECK: bb3:
// CHECK-NEXT: [[RET:%.*]] = tuple ()
// CHECK-NEXT: return [[RET]] : $()
cond_br %1, bb1, bb2
bb1:
hop_to_executor %0 : $MyActor
br bb3
bb2:
hop_to_executor %0 : $MyActor
br bb3
bb3:
%r = tuple ()
return %r : $()
}
// Test that we apply the dominance-based optimization correctly even
// opposite to program order.
// CHECK-LABEL: sil [ossa] @reverse :
sil [ossa] @reverse : $@async (@guaranteed MyActor, Builtin.Int1) -> () {
bb0(%0 : @guaranteed $MyActor, %1 : $Builtin.Int1):
// CHECK: bb0(%0 : @guaranteed $MyActor, %1 : $Builtin.Int1):
// CHECK-NEXT: br bb5
// CHECK: bb1:
// CHECK-NEXT: hop_to_executor [[DEPEND:%.*]] : $Optional<Builtin.Executor>
// CHECK-NEXT: br bb6
// CHECK: bb2:
// CHECK-NEXT: [[EXECUTOR:%.*]] = builtin "buildDefaultActorExecutorRef"<MyActor>(%0 : $MyActor) : $Builtin.Executor
// CHECK-NEXT: [[SOME:%.*]] = enum $Optional<Builtin.Executor>, #Optional.some!enumelt, [[EXECUTOR]] : $Builtin.Executor
// CHECK-NEXT: [[DEPEND]] = mark_dependence [[SOME]] : $Optional<Builtin.Executor> on %0 : $MyActor
// CHECK-NEXT: hop_to_executor [[DEPEND]] : $Optional<Builtin.Executor>
// CHECK-NEXT: br bb1
// CHECK: bb3:
// CHECK-NEXT: hop_to_executor [[DEPEND:%.*]] : $Optional<Builtin.Executor>
// CHECK-NEXT: br bb6
// CHECK: bb4:
// CHECK-NEXT: [[EXECUTOR:%.*]] = builtin "buildDefaultActorExecutorRef"<MyActor>(%0 : $MyActor) : $Builtin.Executor
// CHECK-NEXT: [[SOME:%.*]] = enum $Optional<Builtin.Executor>, #Optional.some!enumelt, [[EXECUTOR]] : $Builtin.Executor
// CHECK-NEXT: [[DEPEND]] = mark_dependence [[SOME]] : $Optional<Builtin.Executor> on %0 : $MyActor
// CHECK-NEXT: hop_to_executor [[DEPEND]] : $Optional<Builtin.Executor>
// CHECK-NEXT: br bb3
// CHECK: bb5:
// CHECK-NEXT: cond_br %1, bb2, bb4
// CHECK: bb6:
// CHECK-NEXT: [[RET:%.*]] = tuple ()
// CHECK-NEXT: return [[RET]] : $()
br bb5
bb1:
hop_to_executor %0 : $MyActor
br bb6
bb2:
hop_to_executor %0 : $MyActor
br bb1
bb3:
hop_to_executor %0 : $MyActor
br bb6
bb4:
hop_to_executor %0 : $MyActor
br bb3
bb5:
cond_br %1, bb2, bb4
bb6:
%r = tuple ()
return %r : $()
}
// Test that we merge blocks appropriately in dominance optimizations.
// CHECK-LABEL: sil [ossa] @reverse_merge :
sil [ossa] @reverse_merge : $@async (@guaranteed MyActor, Builtin.Int1) -> () {
bb0(%0 : @guaranteed $MyActor, %1 : $Builtin.Int1):
// CHECK: bb0(%0 : @guaranteed $MyActor, %1 : $Builtin.Int1):
// CHECK-NEXT: br bb5
// CHECK: bb1:
// CHECK-NEXT: hop_to_executor [[DEPEND:%.*]] : $Optional<Builtin.Executor>
// CHECK-NEXT: br bb6
// CHECK: bb2:
// CHECK-NEXT: hop_to_executor [[DEPEND]] : $Optional<Builtin.Executor>
// CHECK-NEXT: br bb1
// CHECK: bb3:
// CHECK-NEXT: hop_to_executor [[DEPEND]] : $Optional<Builtin.Executor>
// CHECK-NEXT: br bb6
// CHECK: bb4:
// CHECK-NEXT: hop_to_executor [[DEPEND]] : $Optional<Builtin.Executor>
// CHECK-NEXT: br bb3
// CHECK: bb5:
// CHECK-NEXT: [[EXECUTOR:%.*]] = builtin "buildDefaultActorExecutorRef"<MyActor>(%0 : $MyActor) : $Builtin.Executor
// CHECK-NEXT: [[SOME:%.*]] = enum $Optional<Builtin.Executor>, #Optional.some!enumelt, [[EXECUTOR]] : $Builtin.Executor
// CHECK-NEXT: [[DEPEND]] = mark_dependence [[SOME]] : $Optional<Builtin.Executor> on %0 : $MyActor
// CHECK-NEXT: hop_to_executor [[DEPEND]] : $Optional<Builtin.Executor>
// CHECK-NEXT: cond_br %1, bb2, bb4
// CHECK: bb6:
// CHECK-NEXT: [[RET:%.*]] = tuple ()
// CHECK-NEXT: return [[RET]] : $()
br bb5
bb1:
hop_to_executor %0 : $MyActor
br bb6
bb2:
hop_to_executor %0 : $MyActor
br bb1
bb3:
hop_to_executor %0 : $MyActor
br bb6
bb4:
hop_to_executor %0 : $MyActor
br bb3
bb5:
hop_to_executor %0 : $MyActor
cond_br %1, bb2, bb4
bb6:
%r = tuple ()
return %r : $()
}
// CHECK-LABEL: sil [ossa] @simple_custom :
sil [ossa] @simple_custom : $@async (@guaranteed CustomActor) -> () {
bb0(%0 : @guaranteed $CustomActor):
// CHECK: bb0(%0 : @guaranteed $CustomActor):
// CHECK-NEXT: [[WITNESS_METHOD:%.*]] = witness_method $CustomActor, #Actor.unownedExecutor!getter
// CHECK-NEXT: [[WRAPPED_EXECUTOR:%.*]] = apply [[WITNESS_METHOD]]<CustomActor>(%0)
// CHECK-NEXT: [[EXECUTOR:%.*]] = struct_extract [[WRAPPED_EXECUTOR]] : $UnownedSerialExecutor, #UnownedSerialExecutor.executor
// CHECK-NEXT: [[SOME:%.*]] = enum $Optional<Builtin.Executor>, #Optional.some!enumelt, [[EXECUTOR]] : $Builtin.Executor
// CHECK-NEXT: [[DEPEND:%.*]] = mark_dependence [[SOME]] : $Optional<Builtin.Executor> on %0 : $CustomActor
// CHECK-NEXT: hop_to_executor [[DEPEND]] : $Optional<Builtin.Executor>
// CHECK-NEXT: [[RET:%.*]] = tuple ()
// CHECK-NEXT: return [[RET]] : $()
hop_to_executor %0 : $CustomActor
%r = tuple ()
return %r : $()
}
sil @get_raw_executor : $@convention(thin) () -> Builtin.Executor
// CHECK-LABEL: sil [ossa] @non_optional_executor :
sil [ossa] @non_optional_executor : $@async () -> () {
bb0:
// CHECK: bb0:
// CHECK: [[GET_RAW_EXECUTOR:%.*]] = function_ref @get_raw_executor
// CHECK-NEXT: [[EXECUTOR:%.*]] = apply [[GET_RAW_EXECUTOR]]()
// CHECK-NEXT: [[SOME:%.*]] = enum $Optional<Builtin.Executor>, #Optional.some!enumelt, [[EXECUTOR]] : $Builtin.Executor
// CHECK-NEXT: hop_to_executor [[SOME]] : $Optional<Builtin.Executor>
// CHECK-NEXT: [[RET:%.*]] = tuple ()
// CHECK-NEXT: return [[RET]] : $()
%0 = function_ref @get_raw_executor : $@convention(thin) () -> Builtin.Executor
%1 = apply %0() : $@convention(thin) () -> Builtin.Executor
hop_to_executor %1 : $Builtin.Executor
%r = tuple ()
return %r : $()
}
// CHECK-LABEL: sil [ossa] @simple_optional_actor :
sil [ossa] @simple_optional_actor : $@async (@guaranteed Optional<MyActor>) -> () {
bb0(%0 : @guaranteed $Optional<MyActor>):
// CHECK: bb0(%0 : @guaranteed $Optional<MyActor>):
// CHECK-NEXT: switch_enum %0 : $Optional<MyActor>, case #Optional.some!enumelt: bb1, default bb2
// CHECK: bb1([[ACTOR:%.*]] : @guaranteed $MyActor):
// CHECK-NEXT: [[EXECUTOR:%.*]] = builtin "buildDefaultActorExecutorRef"<MyActor>([[ACTOR]] : $MyActor) : $Builtin.Executor
// CHECK-NEXT: [[SOME:%.*]] = enum $Optional<Builtin.Executor>, #Optional.some!enumelt, [[EXECUTOR]] : $Builtin.Executor
// CHECK-NEXT: br bb3([[SOME]] : $Optional<Builtin.Executor>)
// CHECK: bb2:
// CHECK-NEXT: [[NONE:%.*]] = enum $Optional<Builtin.Executor>, #Optional.none!enumelt
// CHECK-NEXT: br bb3([[NONE]] : $Optional<Builtin.Executor>)
// CHECK: bb3([[OPT_EXEC:%.*]] : $Optional<Builtin.Executor>):
// CHECK-NEXT: [[DEPEND:%.*]] = mark_dependence [[OPT_EXEC]] : $Optional<Builtin.Executor> on %0 : $Optional<MyActor>
// CHECK-NEXT: hop_to_executor [[DEPEND]] : $Optional<Builtin.Executor>
// CHECK-NEXT: hop_to_executor [[DEPEND]] : $Optional<Builtin.Executor>
// CHECK-NEXT: [[RET:%.*]] = tuple ()
// CHECK-NEXT: return [[RET]] : $()
hop_to_executor %0 : $Optional<MyActor>
hop_to_executor %0 : $Optional<MyActor>
%r = tuple ()
return %r : $()
}
// CHECK-LABEL: sil [ossa] @optional_existential_actor :
sil [ossa] @optional_existential_actor : $@async (@guaranteed Optional<any Actor>) -> () {
bb0(%0 : @guaranteed $Optional<any Actor>):
// CHECK: bb0(%0 : @guaranteed $Optional<any Actor>):
// CHECK-NEXT: switch_enum %0 : $Optional<any Actor>, case #Optional.some!enumelt: bb1, default bb2
// CHECK: bb1([[ACTOR:%.*]] : @guaranteed $any Actor):
// CHECK-NEXT: [[OPENED:%.*]] = open_existential_ref [[ACTOR]] : $any Actor to $@opened("[[ID:.*]]", any Actor) Self
// CHECK-NEXT: [[WITNESS:%.*]] = witness_method $@opened("[[ID]]", any Actor) Self, #Actor.unownedExecutor!getter : <Self where Self : Actor> (Self) -> () -> UnownedSerialExecutor
// CHECK-NEXT: [[SERIAL_EXEC:%.*]] = apply [[WITNESS]]<@opened("[[ID]]", any Actor) Self>([[OPENED]])
// CHECK-NEXT: [[EXECUTOR:%.*]] = struct_extract [[SERIAL_EXEC]] : $UnownedSerialExecutor, #UnownedSerialExecutor.executor
// CHECK-NEXT: [[SOME:%.*]] = enum $Optional<Builtin.Executor>, #Optional.some!enumelt, [[EXECUTOR]] : $Builtin.Executor
// CHECK-NEXT: br bb3([[SOME]] : $Optional<Builtin.Executor>)
// CHECK: bb2:
// CHECK-NEXT: [[NONE:%.*]] = enum $Optional<Builtin.Executor>, #Optional.none!enumelt
// CHECK-NEXT: br bb3([[NONE]] : $Optional<Builtin.Executor>)
// CHECK: bb3([[OPT_EXEC:%.*]] : $Optional<Builtin.Executor>):
// CHECK-NEXT: [[DEPEND:%.*]] = mark_dependence [[OPT_EXEC]] : $Optional<Builtin.Executor> on %0 : $Optional<any Actor>
// CHECK-NEXT: hop_to_executor [[DEPEND]] : $Optional<Builtin.Executor>
// CHECK-NEXT: hop_to_executor [[DEPEND]] : $Optional<Builtin.Executor>
// CHECK-NEXT: [[RET:%.*]] = tuple ()
// CHECK-NEXT: return [[RET]] : $()
hop_to_executor %0 : $Optional<any Actor>
hop_to_executor %0 : $Optional<any Actor>
%r = tuple ()
return %r : $()
}
|
