1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
|
// RUN: %target-sil-opt -module-name moveonly_addresschecker -emit-verbose-sil -sil-move-only-checker -enable-sil-verify-all %s | %FileCheck %s
sil_stage raw
public class CopyableKlass {}
@_moveOnly
public struct NonTrivialStruct {
var k: CopyableKlass
}
sil @get_nontrivial_struct : $@convention(thin) () -> @owned NonTrivialStruct
sil @use_nontrivial_struct : $@convention(thin) (@guaranteed NonTrivialStruct) -> ()
sil @consume_nontrivial_struct : $@convention(thin) (@owned NonTrivialStruct) -> ()
sil @consume_nontrivial_struct_addr : $@convention(thin) (@in NonTrivialStruct) -> ()
// CHECK-LABEL: sil [ossa] @non_lifetime_ending_use_test_inst : $@convention(thin) () -> () {
// CHECK: [[STACK:%.*]] = alloc_stack $NonTrivialStruct, let, name "v" // {{.*}}; line:[[DEBUG_LOC:.*]]
// CHECK: store {{%.*}} to [init] [[STACK]]
// CHECK: [[BORROW:%.*]] = load_borrow [[STACK]]
// CHECK: apply {{%.*}}([[BORROW]])
// CHECK-NEXT: end_borrow [[BORROW]]
// CHECK-NEXT: debug_value undef : $*NonTrivialStruct, let, name "v" // {{.*}}; line:[[DEBUG_LOC]]
// CHECK: } // end sil function 'non_lifetime_ending_use_test_inst'
sil [ossa] @non_lifetime_ending_use_test_inst : $@convention(thin) () -> () {
%f = function_ref @get_nontrivial_struct : $@convention(thin) () -> @owned NonTrivialStruct
%0 = apply %f() : $@convention(thin) () -> @owned NonTrivialStruct
%1 = alloc_stack $NonTrivialStruct, let, name "v"
%2 = mark_unresolved_non_copyable_value [consumable_and_assignable] %1 : $*NonTrivialStruct
store %0 to [init] %2 : $*NonTrivialStruct
br bb1
bb1:
%3 = load [copy] %2 : $*NonTrivialStruct
%f2 = function_ref @use_nontrivial_struct : $@convention(thin) (@guaranteed NonTrivialStruct) -> ()
apply %f2(%3) : $@convention(thin) (@guaranteed NonTrivialStruct) -> ()
destroy_value %3 : $NonTrivialStruct
destroy_addr %2 : $*NonTrivialStruct
dealloc_stack %1 : $*NonTrivialStruct
%9999 = tuple ()
return %9999 : $()
}
// CHECK-LABEL: sil [ossa] @non_lifetime_ending_use_test_boundary_edge : $@convention(thin) () -> () {
// CHECK: [[STACK:%.*]] = alloc_stack $NonTrivialStruct, let, name "v" // {{.*}}; line:[[DEBUG_LOC:.*]]
// CHECK: store {{%.*}} to [init] [[STACK]]
// CHECK: cond_br undef, bb1, bb2
// CHECK: bb1:
// CHECK: [[BORROW:%.*]] = load_borrow [[STACK]]
// CHECK: apply {{%.*}}([[BORROW]])
// CHECK-NEXT: end_borrow [[BORROW]]
// CHECK: br bb3
//
// CHECK: bb2:
// CHECK-NEXT: br bb3
// CHECK: bb3:
// CHECK-NEXT: debug_value undef : $*NonTrivialStruct, let, name "v" // {{.*}}; line:[[DEBUG_LOC]]
// CHECK-NEXT: destroy_addr [[STACK]]
// CHECK: } // end sil function 'non_lifetime_ending_use_test_boundary_edge'
sil [ossa] @non_lifetime_ending_use_test_boundary_edge : $@convention(thin) () -> () {
%f = function_ref @get_nontrivial_struct : $@convention(thin) () -> @owned NonTrivialStruct
%0 = apply %f() : $@convention(thin) () -> @owned NonTrivialStruct
%1 = alloc_stack $NonTrivialStruct, let, name "v"
%2 = mark_unresolved_non_copyable_value [consumable_and_assignable] %1 : $*NonTrivialStruct
store %0 to [init] %2 : $*NonTrivialStruct
cond_br undef, bb1, bb2
bb1:
%3 = load [copy] %2 : $*NonTrivialStruct
%f2 = function_ref @use_nontrivial_struct : $@convention(thin) (@guaranteed NonTrivialStruct) -> ()
apply %f2(%3) : $@convention(thin) (@guaranteed NonTrivialStruct) -> ()
destroy_value %3 : $NonTrivialStruct
br bb3
bb2:
br bb3
bb3:
destroy_addr %2 : $*NonTrivialStruct
dealloc_stack %1 : $*NonTrivialStruct
%9999 = tuple ()
return %9999 : $()
}
// CHECK-LABEL: sil [ossa] @lifetime_ending_use : $@convention(thin) () -> () {
// CHECK: [[STACK:%.*]] = alloc_stack $NonTrivialStruct, let, name "v" // {{.*}}; line:[[DEBUG_LOC:.*]]
// CHECK: store {{%.*}} to [init] [[STACK]]
// CHECK: cond_br undef, bb1, bb2
// CHECK: bb1:
//
// TODO: We should be smarter here and redefine the debug_value to be on the
// take value and then when that value is destroyed, insert the actual
// debug_value undef.
//
// CHECK: [[TAKE:%.*]] = load [take] [[STACK]]
// CHECK-NEXT: debug_value undef : $*NonTrivialStruct, let, name "v" // {{.*}}; line:[[DEBUG_LOC]]
// CHECK-NEXT: // function_ref
// CHECK-NEXT: function_ref
// CHECK-NEXT: apply {{%.*}}([[TAKE]])
// CHECK: br bb3
//
// CHECK: bb2:
// CHECK-NEXT: destroy_addr [[STACK]]
// CHECK-NEXT: debug_value undef : $*NonTrivialStruct, let, name "v" // {{.*}}; line:[[DEBUG_LOC]]
// CHECK: } // end sil function 'lifetime_ending_use'
sil [ossa] @lifetime_ending_use : $@convention(thin) () -> () {
%f = function_ref @get_nontrivial_struct : $@convention(thin) () -> @owned NonTrivialStruct
%0 = apply %f() : $@convention(thin) () -> @owned NonTrivialStruct
%1 = alloc_stack $NonTrivialStruct, let, name "v"
%2 = mark_unresolved_non_copyable_value [consumable_and_assignable] %1 : $*NonTrivialStruct
store %0 to [init] %2 : $*NonTrivialStruct
cond_br undef, bb1, bb2
bb1:
%3 = load [copy] %2 : $*NonTrivialStruct
%f2 = function_ref @consume_nontrivial_struct : $@convention(thin) (@owned NonTrivialStruct) -> ()
apply %f2(%3) : $@convention(thin) (@owned NonTrivialStruct) -> ()
br bb3
bb2:
br bb3
bb3:
destroy_addr %2 : $*NonTrivialStruct
dealloc_stack %1 : $*NonTrivialStruct
%9999 = tuple ()
return %9999 : $()
}
// CHECK-LABEL: sil [ossa] @lifetime_ending_use_addr : $@convention(thin) () -> () {
// CHECK: [[STACK:%.*]] = alloc_stack $NonTrivialStruct, let, name "v" // {{.*}}; line:[[DEBUG_LOC:.*]]
// CHECK: store {{%.*}} to [init] [[STACK]]
// CHECK: cond_br undef, bb1, bb2
// CHECK: bb1:
// CHECK: apply {{%.*}}([[STACK]])
// CHECK-NEXT: debug_value undef : $*NonTrivialStruct, let, name "v" // {{.*}}; line:[[DEBUG_LOC]]
// CHECK: br bb3
//
// CHECK: bb2:
// CHECK-NEXT: destroy_addr [[STACK]]
// CHECK-NEXT: debug_value undef : $*NonTrivialStruct, let, name "v" // {{.*}}; line:[[DEBUG_LOC]]
// CHECK: } // end sil function 'lifetime_ending_use_addr'
sil [ossa] @lifetime_ending_use_addr : $@convention(thin) () -> () {
%f = function_ref @get_nontrivial_struct : $@convention(thin) () -> @owned NonTrivialStruct
%0 = apply %f() : $@convention(thin) () -> @owned NonTrivialStruct
%1 = alloc_stack $NonTrivialStruct, let, name "v"
%2 = mark_unresolved_non_copyable_value [consumable_and_assignable] %1 : $*NonTrivialStruct
store %0 to [init] %2 : $*NonTrivialStruct
cond_br undef, bb1, bb2
bb1:
%f2 = function_ref @consume_nontrivial_struct_addr : $@convention(thin) (@in NonTrivialStruct) -> ()
apply %f2(%2) : $@convention(thin) (@in NonTrivialStruct) -> ()
br bb3
bb2:
br bb3
bb3:
destroy_addr %2 : $*NonTrivialStruct
dealloc_stack %1 : $*NonTrivialStruct
%9999 = tuple ()
return %9999 : $()
}
// CHECK-LABEL: sil [ossa] @dead_def_test_inst : $@convention(thin) () -> () {
// CHECK: [[STACK:%.*]] = alloc_stack $NonTrivialStruct, let, name "v" // {{.*}}; line:[[DEBUG_LOC:.*]]
// CHECK: store {{%.*}} to [init] [[STACK]]
// CHECK: cond_br undef, bb1, bb3
//
// CHECK: bb1:
// CHECK: apply {{%.*}}([[STACK]])
// CHECK-NEXT: debug_value undef : $*NonTrivialStruct, let, name "v" // {{.*}}; line:[[DEBUG_LOC]]
// CHECK-NEXT: br bb2
//
// CHECK: bb2:
// CHECK: [[NEW_VAL:%.*]] = apply {{%.*}}() :
// CHECK-NEXT: store [[NEW_VAL]] to [init] [[STACK]]
// CHECK-NEXT: destroy_addr [[STACK]]
// CHECK-NEXT: debug_value undef : $*NonTrivialStruct, let, name "v" // {{.*}}; line:[[DEBUG_LOC]]
// CHECK-NEXT: br bb4
//
// CHECK: bb3:
// CHECK-NEXT: destroy_addr [[STACK]]
// CHECK-NEXT: debug_value undef : $*NonTrivialStruct, let, name "v" // {{.*}}; line:[[DEBUG_LOC]]
// CHECK: br bb4
// CHECK: } // end sil function 'dead_def_test_inst'
sil [ossa] @dead_def_test_inst : $@convention(thin) () -> () {
%f = function_ref @get_nontrivial_struct : $@convention(thin) () -> @owned NonTrivialStruct
%0 = apply %f() : $@convention(thin) () -> @owned NonTrivialStruct
%1 = alloc_stack $NonTrivialStruct, let, name "v"
%2 = mark_unresolved_non_copyable_value [consumable_and_assignable] %1 : $*NonTrivialStruct
store %0 to [init] %2 : $*NonTrivialStruct
cond_br undef, bb1, bb2
bb1:
// TODO: Fix bug where we do not propagate this use to bb0 and thus think that
// store %0 is a dead def.
%f2 = function_ref @consume_nontrivial_struct_addr : $@convention(thin) (@in NonTrivialStruct) -> ()
apply %f2(%2) : $@convention(thin) (@in NonTrivialStruct) -> ()
br bb1a
bb1a:
%0a = apply %f() : $@convention(thin) () -> @owned NonTrivialStruct
store %0a to [init] %2 : $*NonTrivialStruct
br bb3
bb2:
br bb3
bb3:
destroy_addr %2 : $*NonTrivialStruct
dealloc_stack %1 : $*NonTrivialStruct
%9999 = tuple ()
return %9999 : $()
}
|
