1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
|
// RUN: %target-sil-opt -sil-verify-all -sil-move-only-temp-allocation-from-let-tester %s | %FileCheck %s
sil_stage raw
import Swift
public class Klass {}
public struct Empty : ~Copyable {}
public struct SingleFieldLoadable : ~Copyable {
var e: Empty
var k: Klass
}
public enum LoadableEnum : ~Copyable {
case first(Empty)
case second(Klass)
}
public struct LoadableType : ~Copyable {
var e: Empty
var l: SingleFieldLoadable
var k: Klass
var lEnum: LoadableEnum
}
public protocol P {}
public struct SingleFieldAddressOnly : ~Copyable {
var e: Empty
var k: P
var en: AddressOnlyEnum
}
public struct SingleFieldAddressOnly2 : ~Copyable {
var e: Empty
var k: P
var en: AddressOnlyEnum
var s2: SingleFieldAddressOnly
}
public enum AddressOnlyEnum : ~Copyable {
case first(Empty)
case second(P)
}
public struct AddressOnlyType : ~Copyable {
var e: Empty
var l: SingleFieldAddressOnly2
var l2: SingleFieldAddressOnly
var k: P
var lEnum: AddressOnlyEnum
}
sil @get_addressonly_type : $@convention(method) (@thin AddressOnlyType.Type) -> @out AddressOnlyType
sil @sideeffect : $@convention(thin) () -> ()
/////////////////
// MARK: Tests //
/////////////////
// CHECK-LABEL: sil hidden [ossa] @accessGrandLoadableField : $@convention(thin) () -> () {
// CHECK: [[ALLOC:%.*]] = alloc_stack
// CHECK: [[MARK:%.*]] = mark_unresolved_non_copyable_value [consumable_and_assignable] [[ALLOC]]
// CHECK: apply {{%.*}}([[MARK]], {{%.*}})
// CHECK: [[GEP1:%.*]] = struct_element_addr [[MARK]]
// CHECK: [[GEP2:%.*]] = struct_element_addr [[GEP1]]
// CHECK: [[GEP3:%.*]] = struct_element_addr [[GEP2]]
// CHECK: [[LOAD:%.*]] = load [copy] [[GEP3]]
// CHECK: move_value [[LOAD]]
// CHECK: } // end sil function 'accessGrandLoadableField'
sil hidden [ossa] @accessGrandLoadableField : $@convention(thin) () -> () {
bb0:
%0 = alloc_stack [lexical] $AddressOnlyType, let, name "x"
%1 = mark_unresolved_non_copyable_value [consumable_and_assignable] %0 : $*AddressOnlyType
%2 = metatype $@thin AddressOnlyType.Type
%3 = function_ref @get_addressonly_type : $@convention(method) (@thin AddressOnlyType.Type) -> @out AddressOnlyType
%4 = apply %3(%1, %2) : $@convention(method) (@thin AddressOnlyType.Type) -> @out AddressOnlyType
%5 = struct_element_addr %1 : $*AddressOnlyType, #AddressOnlyType.l
%6 = alloc_stack $SingleFieldAddressOnly2
copy_addr %5 to [init] %6 : $*SingleFieldAddressOnly2
%8 = struct_element_addr %6 : $*SingleFieldAddressOnly2, #SingleFieldAddressOnly2.s2
%9 = alloc_stack $SingleFieldAddressOnly
copy_addr %8 to [init] %9 : $*SingleFieldAddressOnly
destroy_addr %6 : $*SingleFieldAddressOnly2
%12 = struct_element_addr %9 : $*SingleFieldAddressOnly, #SingleFieldAddressOnly.e
%13 = load [copy] %12 : $*Empty
destroy_addr %9 : $*SingleFieldAddressOnly
%15 = move_value %13 : $Empty
destroy_value %15 : $Empty
dealloc_stack %9 : $*SingleFieldAddressOnly
dealloc_stack %6 : $*SingleFieldAddressOnly2
destroy_addr %1 : $*AddressOnlyType
dealloc_stack %0 : $*AddressOnlyType
%21 = tuple ()
return %21 : $()
}
// CHECK-LABEL: sil hidden [ossa] @accessChildLoadableField : $@convention(thin) () -> () {
// CHECK: [[ALLOC:%.*]] = alloc_stack
// CHECK: [[MARK:%.*]] = mark_unresolved_non_copyable_value [consumable_and_assignable] [[ALLOC]]
// CHECK: apply {{%.*}}([[MARK]], {{%.*}})
// CHECK: [[GEP1:%.*]] = struct_element_addr [[MARK]]
// CHECK: [[GEP2:%.*]] = struct_element_addr [[GEP1]]
// CHECK: [[LOAD:%.*]] = load [copy] [[GEP2]]
// CHECK: move_value [[LOAD]]
// CHECK: } // end sil function 'accessChildLoadableField'
sil hidden [ossa] @accessChildLoadableField : $@convention(thin) () -> () {
bb0:
%0 = alloc_stack [lexical] $AddressOnlyType, let, name "x"
%1 = mark_unresolved_non_copyable_value [consumable_and_assignable] %0 : $*AddressOnlyType
%2 = metatype $@thin AddressOnlyType.Type
%3 = function_ref @get_addressonly_type : $@convention(method) (@thin AddressOnlyType.Type) -> @out AddressOnlyType
%4 = apply %3(%1, %2) : $@convention(method) (@thin AddressOnlyType.Type) -> @out AddressOnlyType
%5 = struct_element_addr %1 : $*AddressOnlyType, #AddressOnlyType.l
%6 = alloc_stack $SingleFieldAddressOnly2
copy_addr %5 to [init] %6 : $*SingleFieldAddressOnly2
%8 = struct_element_addr %6 : $*SingleFieldAddressOnly2, #SingleFieldAddressOnly2.e
%9 = load [copy] %8 : $*Empty
destroy_addr %6 : $*SingleFieldAddressOnly2
%11 = move_value %9 : $Empty
destroy_value %11 : $Empty
dealloc_stack %6 : $*SingleFieldAddressOnly2
destroy_addr %1 : $*AddressOnlyType
dealloc_stack %0 : $*AddressOnlyType
%16 = tuple ()
return %16 : $()
}
// CHECK-LABEL: sil hidden [ossa] @accessChildLoadableFieldWithBlockingSideEffect : $@convention(thin) () -> () {
// CHECK: [[MARK:%.*]] = mark_unresolved_non_copyable_value [consumable_and_assignable] [[ALLOC]]
// CHECK: apply {{%.*}}([[MARK]], {{%.*}})
// CHECK: [[GEP1:%.*]] = struct_element_addr [[MARK]]
// CHECK: [[TEMP:%.*]] = alloc_stack $SingleFieldAddressOnly2
// CHECK: copy_addr [[GEP1]] to [init] [[TEMP]]
// CHECK: apply {{%.*}}() :
// CHECK: [[GEP2:%.*]] = struct_element_addr [[TEMP]]
// CHECK: [[LOAD:%.*]] = load [copy] [[GEP2]]
// CHECK: move_value [[LOAD]]
// CHECK: } // end sil function 'accessChildLoadableFieldWithBlockingSideEffect'
sil hidden [ossa] @accessChildLoadableFieldWithBlockingSideEffect : $@convention(thin) () -> () {
bb0:
%0 = alloc_stack [lexical] $AddressOnlyType, let, name "x"
%1 = mark_unresolved_non_copyable_value [consumable_and_assignable] %0 : $*AddressOnlyType
%2 = metatype $@thin AddressOnlyType.Type
%3 = function_ref @get_addressonly_type : $@convention(method) (@thin AddressOnlyType.Type) -> @out AddressOnlyType
%4 = apply %3(%1, %2) : $@convention(method) (@thin AddressOnlyType.Type) -> @out AddressOnlyType
%5 = struct_element_addr %1 : $*AddressOnlyType, #AddressOnlyType.l
%6 = alloc_stack $SingleFieldAddressOnly2
// This is our original copy_addr. If there is a side effect in between it
// and %9 (our final use), then we conservatively bail.
copy_addr %5 to [init] %6 : $*SingleFieldAddressOnly2
%f = function_ref @sideeffect : $@convention(thin) () -> ()
apply %f() : $@convention(thin) () -> ()
%8 = struct_element_addr %6 : $*SingleFieldAddressOnly2, #SingleFieldAddressOnly2.e
%9 = load [copy] %8 : $*Empty
destroy_addr %6 : $*SingleFieldAddressOnly2
%11 = move_value %9 : $Empty
destroy_value %11 : $Empty
dealloc_stack %6 : $*SingleFieldAddressOnly2
destroy_addr %1 : $*AddressOnlyType
dealloc_stack %0 : $*AddressOnlyType
%16 = tuple ()
return %16 : $()
}
// CHECK-LABEL: sil hidden [ossa] @copyableAddressOnlyTest : $@convention(thin) () -> () {
// CHECK: [[ALLOC:%.*]] = alloc_stack
// CHECK: [[MARK:%.*]] = mark_unresolved_non_copyable_value [consumable_and_assignable] [[ALLOC]]
// CHECK: apply {{%.*}}([[MARK]], {{%.*}})
// CHECK: [[GEP1:%.*]] = struct_element_addr [[MARK]]
// CHECK: [[GEP2:%.*]] = struct_element_addr [[GEP1]]
// CHECK: [[RESULT:%.*]] = alloc_stack $any P
// CHECK: copy_addr [[GEP2]] to [init] [[RESULT]]
// CHECK: } // end sil function 'copyableAddressOnlyTest'
sil hidden [ossa] @copyableAddressOnlyTest : $@convention(thin) () -> () {
bb0:
%0 = alloc_stack [lexical] $AddressOnlyType, let, name "x"
%1 = mark_unresolved_non_copyable_value [consumable_and_assignable] %0 : $*AddressOnlyType
%2 = metatype $@thin AddressOnlyType.Type
%3 = function_ref @get_addressonly_type : $@convention(method) (@thin AddressOnlyType.Type) -> @out AddressOnlyType
%4 = apply %3(%1, %2) : $@convention(method) (@thin AddressOnlyType.Type) -> @out AddressOnlyType
%5 = struct_element_addr %1 : $*AddressOnlyType, #AddressOnlyType.l
%6 = alloc_stack $SingleFieldAddressOnly2
copy_addr %5 to [init] %6 : $*SingleFieldAddressOnly2
%8 = struct_element_addr %6 : $*SingleFieldAddressOnly2, #SingleFieldAddressOnly2.k
%9 = alloc_stack $any P
copy_addr %8 to [init] %9 : $*any P
destroy_addr %6 : $*SingleFieldAddressOnly2
destroy_addr %9 : $*any P
dealloc_stack %9 : $*any P
dealloc_stack %6 : $*SingleFieldAddressOnly2
destroy_addr %1 : $*AddressOnlyType
dealloc_stack %0 : $*AddressOnlyType
%17 = tuple ()
return %17 : $()
}
|
