1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
// RUN: %target-sil-opt -enable-sil-verify-all %s -sil-deadfuncelim | %FileCheck --check-prefix=KEEP %s
// RUN: %target-sil-opt -enable-sil-verify-all %s -sil-deadfuncelim | %FileCheck %s
sil_stage canonical
import Builtin
import Swift
// CHECK-LABEL: sil_global private @privateGlobal
sil_global private @privateGlobal : $Int64
// This function needs to be removed.
// KEEP-NOT: @remove_me
sil private @remove_me : $@convention(thin) (Builtin.Int64) -> Builtin.Int64 {
bb0(%0 : $Builtin.Int64):
%2 = integer_literal $Builtin.Int1, 0
%3 = builtin "umul_with_overflow_Int64"(%0 : $Builtin.Int64, %0 : $Builtin.Int64, %2 : $Builtin.Int1) : $(Builtin.Int64, Builtin.Int1)
%4 = tuple_extract %3 : $(Builtin.Int64, Builtin.Int1), 0
return %4: $Builtin.Int64
}
sil_global @globalFunctionPointer : $@callee_guaranteed () -> () = {
%0 = function_ref @alivePrivateFunc : $@convention(thin) () -> ()
%initval = thin_to_thick_function %0 : $@convention(thin) () -> () to $@callee_guaranteed () -> ()
}
// CHECK-LABEL: sil_global private @self_referencing_private_global
sil_global private @self_referencing_private_global : $Builtin.RawPointer = {
%0 = global_addr @self_referencing_private_global : $*Builtin.RawPointer
%initval = address_to_pointer %0 : $*Builtin.RawPointer to $Builtin.RawPointer
}
// CHECK-LABEL: sil_global private @referencing_other_private_global
sil_global private @referencing_other_private_global : $Builtin.RawPointer = {
%0 = global_addr @self_referencing_private_global : $*Builtin.RawPointer
%initval = address_to_pointer %0 : $*Builtin.RawPointer to $Builtin.RawPointer
}
// CHECK-LABEL: sil_global @referencing_private_globals
sil_global @referencing_private_globals : $Builtin.RawPointer = {
%0 = global_addr @referencing_other_private_global : $*Builtin.RawPointer
%initval = address_to_pointer %0 : $*Builtin.RawPointer to $Builtin.RawPointer
}
// KEEP-NOT: @dead_self_referencing_private_global
sil_global private @dead_self_referencing_private_global : $Builtin.RawPointer = {
%0 = global_addr @dead_self_referencing_private_global : $*Builtin.RawPointer
%initval = address_to_pointer %0 : $*Builtin.RawPointer to $Builtin.RawPointer
}
// CHECK-LABEL: sil private @alivePrivateFunc
sil private @alivePrivateFunc : $@convention(thin) () -> () {
bb0:
alloc_global @privateGlobal
%0 = tuple ()
return %0 : $()
}
// KEEP-NOT: @privateFunctionPointer
sil_global private @privateFunctionPointer : $@callee_guaranteed () -> () = {
%0 = function_ref @deadPrivateFunc : $@convention(thin) () -> ()
%initval = thin_to_thick_function %0 : $@convention(thin) () -> () to $@callee_guaranteed () -> ()
}
// KEEP-NOT: @deadPrivateFunc
sil private @deadPrivateFunc : $@convention(thin) () -> () {
bb0:
%0 = global_addr @privateFunctionPointer : $*@callee_guaranteed () -> ()
%1 = load %0 : $*@callee_guaranteed () -> ()
%2 = apply %1() : $@callee_guaranteed () -> ()
%3 = tuple ()
return %3 : $()
}
|
