1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
|
// RUN: %target-sil-opt -test-runner %s | %FileCheck %s
import Builtin
class Klass {}
class AnyKlass {}
enum FakeOptional<T> {
case some(T)
case none
}
struct NonTrivialStruct {
var val: Klass
}
sil @use_klass : $@convention(thin) (@guaranteed Klass) -> ()
// CHECK-LABEL: sil [ossa] @test_simplify_args1 :
// CHECK: bb2:
// CHECK-LABEL: } // end sil function 'test_simplify_args1'
sil [ossa] @test_simplify_args1 : $@convention(thin) (@owned Klass) -> () {
bb0(%0 : @owned $Klass):
specify_test "simplify-cfg-simplify-block-args"
%1 = begin_borrow %0 : $Klass
br bb1(%1 : $Klass)
bb1(%3 : @guaranteed $Klass):
br bb2(%3 : $Klass)
bb2(%5 : @guaranteed $Klass):
end_borrow %5 : $Klass
destroy_value %0 : $Klass
%t = tuple ()
return %t : $()
}
// CHECK-LABEL: sil [ossa] @test_simplify_args2 :
// CHECK: bb3({{.*}}):
// CHECK-LABEL: } // end sil function 'test_simplify_args2'
sil [ossa] @test_simplify_args2 : $@convention(thin) (@owned Klass, @owned Klass) -> () {
bb0(%0 : @owned $Klass, %1 : @owned $Klass):
specify_test "simplify-cfg-simplify-block-args"
cond_br undef, bb1, bb2
bb1:
%2 = begin_borrow %0 : $Klass
br bb3(%2 : $Klass)
bb2:
%3 = begin_borrow %1 : $Klass
br bb3(%3 : $Klass)
bb3(%4 : @guaranteed $Klass):
end_borrow %4 : $Klass
destroy_value %0 : $Klass
destroy_value %1 : $Klass
%t = tuple ()
return %t : $()
}
// CHECK-LABEL: sil [ossa] @test_simplify_args3 :
// CHECK: bb3({{.*}}):
// CHECK-LABEL: } // end sil function 'test_simplify_args3'
sil [ossa] @test_simplify_args3 : $@convention(thin) (@owned Klass, @owned Klass) -> () {
bb0(%0 : @owned $Klass, %1 : @owned $Klass):
specify_test "simplify-cfg-simplify-block-args"
cond_br undef, bb1, bb2
bb1:
destroy_value %0 : $Klass
br bb3(%1 : $Klass)
bb2:
destroy_value %1 : $Klass
br bb3(%0 : $Klass)
bb3(%4 : @owned $Klass):
destroy_value %4 : $Klass
%t = tuple ()
return %t : $()
}
// CHECK-LABEL: sil [ossa] @test_simplify_args4 :
// CHECK: bb3:
// CHECK-LABEL: } // end sil function 'test_simplify_args4'
sil [ossa] @test_simplify_args4 : $@convention(thin) (@owned Klass, @owned Klass) -> () {
bb0(%0 : @owned $Klass, %1 : @owned $Klass):
specify_test "simplify-cfg-simplify-block-args"
cond_br undef, bb1, bb2
bb1:
destroy_value %0 : $Klass
br bb3(%1 : $Klass)
bb2:
destroy_value %0 : $Klass
br bb3(%1 : $Klass)
bb3(%4 : @owned $Klass):
destroy_value %4 : $Klass
%t = tuple ()
return %t : $()
}
// CHECK-LABEL: sil [ossa] @test_simplify_args5 :
// CHECK: bb3:
// CHECK-LABEL: } // end sil function 'test_simplify_args5'
sil [ossa] @test_simplify_args5 : $@convention(thin) (@owned Klass, @owned Klass) -> () {
bb0(%0 : @owned $Klass, %1 : @owned $Klass):
specify_test "simplify-cfg-simplify-block-args"
%2 = begin_borrow %0 : $Klass
cond_br undef, bb1, bb2
bb1:
br bb3(%2 : $Klass)
bb2:
br bb3(%2 : $Klass)
bb3(%4 : @guaranteed $Klass):
end_borrow %4 : $Klass
destroy_value %0 : $Klass
destroy_value %1 : $Klass
%t = tuple ()
return %t : $()
}
// CHECK-LABEL: sil [ossa] @test_simplify_args6 :
// CHECK: bb1:
// CHECK-LABEL: } // end sil function 'test_simplify_args6'
sil [ossa] @test_simplify_args6 : $@convention(thin) (@owned Klass) -> () {
bb0(%0 : @owned $Klass):
specify_test "simplify-cfg-simplify-block-args"
%1 = enum $FakeOptional<Klass>, #FakeOptional.some!enumelt, %0 : $Klass
br bb1(%1 : $FakeOptional<Klass>)
bb1(%3 : @owned $FakeOptional<Klass>):
switch_enum %3 : $FakeOptional<Klass>, case #FakeOptional.some!enumelt: bb3, case #FakeOptional.none!enumelt: bb2
bb2:
br bb4
bb3(%6 : @owned $Klass):
destroy_value %6 : $Klass
br bb4
bb4:
%t = tuple ()
return %t : $()
}
// CHECK-LABEL: sil [ossa] @test_simplify_args7 :
// CHECK: bb1:
// CHECK-LABEL: } // end sil function 'test_simplify_args7'
sil [ossa] @test_simplify_args7 : $@convention(thin) (@owned Klass) -> () {
bb0(%0 : @owned $Klass):
specify_test "simplify-cfg-simplify-block-args"
%1 = enum $FakeOptional<Klass>, #FakeOptional.some!enumelt, %0 : $Klass
br bb1(%1 : $FakeOptional<Klass>)
bb1(%3 : @owned $FakeOptional<Klass>):
switch_enum %3 : $FakeOptional<Klass>, case #FakeOptional.some!enumelt: bb3, case #FakeOptional.none!enumelt: bb2
bb2:
br bb4
bb3(%6 : @owned $Klass):
destroy_value %6 : $Klass
br bb4
bb4:
%t = tuple ()
return %t : $()
}
// CHECK-LABEL: sil [ossa] @test_simplify_args8 :
// CHECK-NOT: unchecked_enum_data
// CHECK-LABEL: } // end sil function 'test_simplify_args8'
sil [ossa] @test_simplify_args8 : $@convention(thin) (@guaranteed Klass) -> () {
bb0(%0 : @guaranteed $Klass):
specify_test "simplify-cfg-simplify-argument @block[1] 0"
%1 = enum $FakeOptional<Klass>, #FakeOptional.some!enumelt, %0 : $Klass
br bb1(%1 : $FakeOptional<Klass>)
bb1(%3 : @guaranteed $FakeOptional<Klass>):
%4 = unchecked_enum_data %3 : $FakeOptional<Klass>, #FakeOptional.some!enumelt
%f = function_ref @use_klass : $@convention(thin) (@guaranteed Klass) -> ()
%c = apply %f(%4) : $@convention(thin) (@guaranteed Klass) -> ()
br bb3
bb3:
%7 = tuple ()
return %7 : $()
}
// CHECK-LABEL: sil [ossa] @test_simplify_args9 :
// CHECK-NOT: unchecked_enum_date
// CHECK-LABEL: } // end sil function 'test_simplify_args9'
sil [ossa] @test_simplify_args9 : $@convention(thin) (@owned Klass) -> () {
bb0(%0 : @owned $Klass):
specify_test "simplify-cfg-simplify-argument @block[1] 0"
%1 = enum $FakeOptional<Klass>, #FakeOptional.some!enumelt, %0 : $Klass
br bb1(%1 : $FakeOptional<Klass>)
bb1(%3 : @owned $FakeOptional<Klass>):
%4 = unchecked_enum_data %3 : $FakeOptional<Klass>, #FakeOptional.some!enumelt
%f = function_ref @use_klass : $@convention(thin) (@guaranteed Klass) -> ()
%c = apply %f(%4) : $@convention(thin) (@guaranteed Klass) -> ()
destroy_value %4 : $Klass
br bb3
bb3:
%7 = tuple ()
return %7 : $()
}
// CHECK-LABEL: test_dont_remove_mandatory_dead_args :
// CHECK: checked_cast_br AnyKlass in {{%.*}} : $AnyKlass to Klass, bb1
// CHECK: bb1([[VAR:%[0-9]+]] : @guaranteed $Klass)
// CHECK-NOT: [[VAR]]
// CHECK: return
sil [ossa] @test_dont_remove_mandatory_dead_args : $@convention(thin) (@guaranteed AnyKlass) -> () {
bb0(%0 : @guaranteed $AnyKlass):
specify_test "simplify-cfg-simplify-argument @block[1] 0"
checked_cast_br AnyKlass in %0 : $AnyKlass to Klass, bb1, bb2
bb1(%1 : @guaranteed $Klass):
%2 = integer_literal $Builtin.Int32, 1
br bb3(%2 : $Builtin.Int32)
bb2(%default : @guaranteed $AnyKlass):
%3 = integer_literal $Builtin.Int32, 0
br bb3(%3 : $Builtin.Int32)
bb3(%4 : $Builtin.Int32):
%5 = tuple ()
return %5 : $()
}
// CHECK-LABEL: sil [ossa] @test_simplify_enum_arg_owned :
// CHECK: bb1([[ARG:%.*]] : @owned $FakeOptional<Klass>)
// CHECK-LABEL: } // end sil function 'test_simplify_enum_arg_owned'
sil [ossa] @test_simplify_enum_arg_owned : $@convention(thin) (@owned Klass) -> () {
bb0(%0 : @owned $Klass):
specify_test "simplify-cfg-simplify-argument @block[1] 0"
%1 = enum $FakeOptional<Klass>, #FakeOptional.some!enumelt, %0 : $Klass
%c = copy_value %1 : $FakeOptional<Klass>
br bb1(%1 : $FakeOptional<Klass>)
bb1(%3 : @owned $FakeOptional<Klass>):
%4 = unchecked_enum_data %3 : $FakeOptional<Klass>, #FakeOptional.some!enumelt
%f = function_ref @use_klass : $@convention(thin) (@guaranteed Klass) -> ()
apply %f(%4) : $@convention(thin) (@guaranteed Klass) -> ()
br bb2
bb2:
destroy_value %4 : $Klass
br bb3
bb3:
destroy_value %c : $FakeOptional<Klass>
%t = tuple ()
return %t : $()
}
// CHECK-LABEL: sil [ossa] @test_simplify_enum_arg_guaranteed1 :
// CHECK: bb1([[ARG:%.*]] : @guaranteed $FakeOptional<Klass>)
// CHECK-LABEL: } // end sil function 'test_simplify_enum_arg_guaranteed1'
sil [ossa] @test_simplify_enum_arg_guaranteed1 : $@convention(thin) (@owned Klass) -> () {
bb0(%0 : @owned $Klass):
specify_test "simplify-cfg-simplify-argument @block[1] 0"
%b = begin_borrow %0 : $Klass
%1 = enum $FakeOptional<Klass>, #FakeOptional.some!enumelt, %b : $Klass
%c = copy_value %1 : $FakeOptional<Klass>
br bb1(%1 : $FakeOptional<Klass>)
bb1(%3 : @guaranteed $FakeOptional<Klass>):
%4 = unchecked_enum_data %3 : $FakeOptional<Klass>, #FakeOptional.some!enumelt
%f = function_ref @use_klass : $@convention(thin) (@guaranteed Klass) -> ()
apply %f(%4) : $@convention(thin) (@guaranteed Klass) -> ()
br bb2
bb2:
destroy_value %c : $FakeOptional<Klass>
end_borrow %b : $Klass
destroy_value %0 : $Klass
%t = tuple ()
return %t : $()
}
// CHECK: bb1([[ARG:%.*]] : @guaranteed $NonTrivialStruct)
sil [ossa] @test_simplify_enum_arg_guaranteed2 : $@convention(thin) (@owned Klass) -> () {
bb0(%0 : @owned $Klass):
specify_test "simplify-cfg-simplify-argument @block[1] 0"
%b = begin_borrow %0 : $Klass
%1 = struct $NonTrivialStruct(%b : $Klass)
%c = copy_value %1 : $NonTrivialStruct
br bb1(%1 : $NonTrivialStruct)
bb1(%3 : @guaranteed $NonTrivialStruct):
%4 = struct_extract %3 : $NonTrivialStruct, #NonTrivialStruct.val
%f = function_ref @use_klass : $@convention(thin) (@guaranteed Klass) -> ()
apply %f(%4) : $@convention(thin) (@guaranteed Klass) -> ()
br bb2
bb2:
destroy_value %c : $NonTrivialStruct
end_borrow %b : $Klass
destroy_value %0 : $Klass
%t = tuple ()
return %t : $()
}
|
