1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
// RUN: %target-sil-opt \
// RUN: -test-runner \
// RUN: -module-name Swift \
// RUN: %s \
// RUN: -o /dev/null \
// RUN: 2>&1 | %FileCheck %s
import Builtin
@_marker protocol Copyable {}
class C {}
struct NC : ~Copyable {
var c: C
}
// CHECK-LABEL: begin running test {{.*}} on consume_move_only
// CHECK-LABEL: sil [ossa] @consume_move_only : {{.*}} {
// CHECK: bb0([[C:%[^,]+]] :
// Necessary copy.
// CHECK: [[COPY:%[^,]+]] = copy_value [[C]]
// CHECK: [[NC:%[^,]+]] = struct $NC ([[COPY]]
// CHECK: apply undef([[NC]])
// CHECK-LABEL: } // end sil function 'consume_move_only'
// CHECK-LABEL: end running test {{.*}} on consume_move_only
sil [ossa] @consume_move_only : $@convention(thin) (@guaranteed C) -> () {
bb0(%c : @guaranteed $C):
specify_test "canonicalize_function_argument @argument"
%copy = copy_value %c : $C
%nc = struct $NC (%copy : $C)
apply undef(%nc) : $@convention(thin) (@owned NC) -> ()
%retval = tuple ()
return %retval : $()
}
// CHECK-LABEL: begin running test {{.*}} on borrow_move_only
// CHECK-LABEL: sil [ossa] @borrow_move_only : {{.*}} {
// CHECK: bb0([[C:%[^,]+]] :
// No copy!
// CHECK: [[NC:%[^,]+]] = struct $NC ([[C]]
// CHECK: apply undef([[NC]])
// CHECK-LABEL: } // end sil function 'borrow_move_only'
// CHECK-LABEL: end running test {{.*}} on borrow_move_only
sil [ossa] @borrow_move_only : $@convention(thin) (@guaranteed C) -> () {
bb0(%c : @guaranteed $C):
specify_test "canonicalize_function_argument @argument"
%copy = copy_value %c : $C
%nc = struct $NC (%copy : $C)
apply undef(%nc) : $@convention(thin) (@guaranteed NC) -> ()
destroy_value %nc : $NC
%retval = tuple ()
return %retval : $()
}
// CHECK-LABEL: begin running test {{.*}} on consume_and_borrow_move_only
// CHECK-LABEL: sil [ossa] @consume_and_borrow_move_only : {{.*}} {
// CHECK: bb0([[C:%[^,]+]] :
// No copy!
// CHECK: [[NC1:%[^,]+]] = struct $NC ([[C]]
// CHECK: apply undef([[NC1]])
// Necessary copy.
// CHECK: [[COPY2:%[^,]+]] = copy_value [[C]]
// CHECK: [[NC2:%[^,]+]] = struct $NC ([[COPY2]]
// CHECK: apply undef([[NC2]])
// CHECK-LABEL: } // end sil function 'consume_and_borrow_move_only'
// CHECK-LABEL: end running test {{.*}} on consume_and_borrow_move_only
sil [ossa] @consume_and_borrow_move_only : $@convention(thin) (@guaranteed C) -> () {
bb0(%c : @guaranteed $C):
specify_test "canonicalize_function_argument @argument"
%copy1 = copy_value %c : $C
%nc1 = struct $NC (%copy1 : $C)
apply undef(%nc1) : $@convention(thin) (@guaranteed NC) -> ()
destroy_value %nc1 : $NC
%copy2 = copy_value %c : $C
%nc2 = struct $NC (%copy2 : $C)
apply undef(%nc2) : $@convention(thin) (@owned NC) -> ()
%retval = tuple ()
return %retval : $()
}
|
