1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
|
// RUN: mlir-opt %s -one-shot-bufferize="test-analysis-only" \
// RUN: -allow-unregistered-dialect -split-input-file | FileCheck %s
// RUN: mlir-opt %s -one-shot-bufferize="test-analysis-only dump-alias-sets" \
// RUN: -allow-unregistered-dialect -split-input-file | \
// RUN: FileCheck %s --check-prefix=CHECK-ALIAS-SETS
// CHECK-LABEL: func @unknown_op_aliasing(
// CHECK-ALIAS-SETS-LABEL: func @unknown_op_aliasing(
func.func @unknown_op_aliasing(%f: f32, %f2: f32, %pos: index) -> f32 {
// CHECK-ALIAS-SETS: %[[empty:.*]] = tensor.empty
%0 = tensor.empty() : tensor<10xf32>
// CHECK: linalg.fill {__inplace_operands_attr__ = ["none", "true"]}
// CHECK-ALIAS-SETS: %[[fill1:.*]] = linalg.fill
%1 = linalg.fill ins(%f : f32) outs(%0 : tensor<10xf32>) -> tensor<10xf32>
// Something must bufferize out-of-place because the op may return an alias
// of %1.
// CHECK: "dummy.dummy_op"(%{{.*}}) {__inplace_operands_attr__ = ["false"]}
%alias = "dummy.dummy_op"(%1) : (tensor<10xf32>) -> (tensor<10xf32>)
// CHECK: linalg.fill {__inplace_operands_attr__ = ["none", "true"]}
// CHECK-ALIAS-SETS: %[[fill2:.*]] = linalg.fill
// CHECK-ALIAS-SETS-SAME: __opresult_alias_set_attr__ = [{{\[}}"%[[fill2]]", "%[[fill1]]", "%[[empty]]"]]
%2 = linalg.fill ins(%f2 : f32) outs(%1 : tensor<10xf32>) -> tensor<10xf32>
%3 = tensor.extract %alias[%pos] : tensor<10xf32>
return %3 : f32
}
// -----
// CHECK-LABEL: func @unknown_op_bbarg_aliasing(
// CHECK-ALIAS-SETS-LABEL: func @unknown_op_bbarg_aliasing(
func.func @unknown_op_bbarg_aliasing() {
%0 = tensor.empty() : tensor<7xf32>
// %arg0 is not aliasing with %0 because it bufferizes out-of-place.
// CHECK-ALIAS-SETS: "dummy.dummy_op"
// CHECK-ALIAS-SETS-NEXT: ^{{.*}}(%[[arg:.*]]: tensor<7xf32>):
// CHECK-ALIAS-SETS-NEXT: }) {__bbarg_alias_set_attr__ = [{{\[}}[{{\[}}"%[[arg]]"]]]], __inplace_operands_attr__ = ["false"]} : (tensor<7xf32>) -> ()
"dummy.dummy_op"(%0) ({
^bb0(%arg1: tensor<7xf32>):
}) : (tensor<7xf32>) -> ()
return
}
// -----
// CHECK-LABEL: func @unknown_op_writing(
func.func @unknown_op_writing(%f: f32, %f2: f32, %pos: index) -> f32 {
%0 = tensor.empty() : tensor<10xf32>
// CHECK: linalg.fill {__inplace_operands_attr__ = ["none", "true"]}
%1 = linalg.fill ins(%f : f32) outs(%0 : tensor<10xf32>) -> tensor<10xf32>
// The op may bufferize to a memory write, so it must bufferize out-of-place.
// CHECK: "dummy.dummy_op"(%{{.*}}) {__inplace_operands_attr__ = ["false"]}
"dummy.dummy_op"(%1) : (tensor<10xf32>) -> ()
%3 = tensor.extract %1[%pos] : tensor<10xf32>
return %3 : f32
}
// -----
// CHECK-LABEL: func @read_of_undef_is_not_a_conflict(
func.func @read_of_undef_is_not_a_conflict(%f: f32, %idx: index) -> f32 {
%0 = tensor.empty() : tensor<10xf32>
// This can be in-place because the read below does reads undefined data.
// CHECK: tensor.insert {{.*}} {__inplace_operands_attr__ = ["none", "true", "none"]}
%1 = tensor.insert %f into %0[%idx] : tensor<10xf32>
%2 = tensor.extract %0[%idx] : tensor<10xf32>
return %2 : f32
}
// -----
// CHECK-LABEL: func @read_of_alloc_tensor_is_not_a_conflict(
func.func @read_of_alloc_tensor_is_not_a_conflict(%f: f32, %idx: index) -> f32 {
%0 = bufferization.alloc_tensor() : tensor<10xf32>
// This can be in-place because the read below does reads undefined data.
// CHECK: tensor.insert {{.*}} {__inplace_operands_attr__ = ["none", "true", "none"]}
%1 = tensor.insert %f into %0[%idx] : tensor<10xf32>
%2 = tensor.extract %0[%idx] : tensor<10xf32>
return %2 : f32
}
// -----
// CHECK-LABEL: func @to_memref_not_read_only(
func.func @to_memref_not_read_only(%idx : index, %f: f32) -> f32 {
%t = tensor.generate {
^bb0(%i : index):
tensor.yield %f : f32
} : tensor<5xf32>
// Some op may write into the result of to_memref later.
// CHECK: bufferization.to_memref
// CHECK-SAME: {__inplace_operands_attr__ = ["false"]}
%m = bufferization.to_memref %t : memref<5xf32>
%2 = tensor.extract %t[%idx] : tensor<5xf32>
return %2 : f32
}
// -----
// CHECK-LABEL: func @to_memref_read_only(
func.func @to_memref_read_only(%idx : index, %f: f32) -> f32 {
%t = tensor.generate {
^bb0(%i : index):
tensor.yield %f : f32
} : tensor<5xf32>
// Some op may write into the result of to_memref later.
// CHECK: bufferization.to_memref
// CHECK-SAME: {__inplace_operands_attr__ = ["true"]}
%m = bufferization.to_memref %t {read_only} : memref<5xf32>
%2 = tensor.extract %t[%idx] : tensor<5xf32>
return %2 : f32
}
// -----
// CHECK-LABEL: func @bbarg_of_unknown_op(
func.func @bbarg_of_unknown_op(%f: f32) {
%0 = tensor.empty() : tensor<10xf32>
// CHECK: linalg.fill {__inplace_operands_attr__ = ["none", "true"]}
%1 = linalg.fill ins(%f : f32) outs(%0 : tensor<10xf32>) -> tensor<10xf32>
// The op is not bufferizable because %1 is assumed to alias with %arg1.
// BlockArguments are considered "not writable" by default. So %1 is also
// considered "not writable".
// CHECK: "dummy.dummy_op"
// CHECK: {__inplace_operands_attr__ = ["false"]} : (tensor<10xf32>) -> ()
"dummy.dummy_op"(%1) ({
^bb0(%arg1: tensor<10xf32>):
}) : (tensor<10xf32>) -> ()
return
}
// -----
// CHECK-LABEL: func @bbarg_of_unknown_op_2(
func.func @bbarg_of_unknown_op_2(%f: f32) {
%0 = tensor.empty() : tensor<10xf32>
// CHECK: linalg.fill {__inplace_operands_attr__ = ["none", "true"]}
%1 = linalg.fill ins(%f : f32) outs(%0 : tensor<10xf32>) -> tensor<10xf32>
// The op is not bufferizable because %1 is assumed to alias with %arg1.
// BlockArguments are considered "not writable" by default. So %1 is also
// considered "not writable".
// CHECK: "dummy.dummy_op"
"dummy.dummy_op"(%1) ({
^bb0(%arg1: tensor<10xf32>):
// CHECK: "dummy.another_op"(%{{.*}}) {__inplace_operands_attr__ = ["false"]}
"dummy.another_op"(%arg1) : (tensor<10xf32>) -> ()
}) : (tensor<10xf32>) -> ()
// CHECK: {__inplace_operands_attr__ = ["false"]} : (tensor<10xf32>) -> ()
return
}
// -----
// CHECK: func @materialize_in_destination_aliasing(
func.func @materialize_in_destination_aliasing(%t: tensor<?xf32>, %p1: index, %p2: index, %sz: index) -> tensor<5xf32> {
%buffer = tensor.empty(%sz) : tensor<?xf32>
// CHECK: tensor.extract_slice
// CHECK-SAME: {__inplace_operands_attr__ = ["true", "none"]}
%src = tensor.extract_slice %t[%p1][5][1] : tensor<?xf32> to tensor<5xf32>
// CHECK: tensor.extract_slice
// CHECK-SAME: {__inplace_operands_attr__ = ["false", "none"]}
%dest = tensor.extract_slice %t[%p2][5][1] : tensor<?xf32> to tensor<5xf32>
// CHECK: bufferization.materialize_in_destination
// CHECK-SAME: {__inplace_operands_attr__ = ["true", "true"]}
%r = bufferization.materialize_in_destination %src in %dest : (tensor<5xf32>, tensor<5xf32>) -> tensor<5xf32>
return %r : tensor<5xf32>
}
// -----
// CHECK: func @materialize_in_destination(
func.func @materialize_in_destination(%t: tensor<?xf32>, %sz: index) -> tensor<?xf32> {
%buffer = tensor.empty(%sz) : tensor<?xf32>
// CHECK: bufferization.materialize_in_destination
// CHECK-SAME: {__inplace_operands_attr__ = ["true", "true"]}
%r = bufferization.materialize_in_destination %buffer in %buffer : (tensor<?xf32>, tensor<?xf32>) -> tensor<?xf32>
return %r : tensor<?xf32>
}
|
