1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
|
/*
* Copyright (c) 2010-2015 Balabit
* Copyright (c) 2010-2014 Gergely Nagy <algernon@balabit.hu>
*
* This program is free software; you can redistribute it and/or modify it
* under the terms of the GNU General Public License version 2 as published
* by the Free Software Foundation, or (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program; if not, write to the Free Software
* Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
*
* As an additional exemption you are allowed to compile & link against the
* OpenSSL libraries as published by the OpenSSL project. See the file
* COPYING for details.
*
*/
%code requires {
#include "afmongodb-parser.h"
}
%code {
#include "cfg-grammar-internal.h"
#include "plugin.h"
#include "value-pairs/value-pairs.h"
}
%define api.prefix {afmongodb_}
%lex-param {CfgLexer *lexer}
%parse-param {CfgLexer *lexer}
%parse-param {LogDriver **instance}
%parse-param {gpointer arg}
/* INCLUDE_DECLS */
%token KW_MONGODB
%token KW_URI
%token KW_COLLECTION
%token KW_BULK
%token KW_BULK_UNORDERED
%token KW_BULK_BYPASS_VALIDATION
%token KW_WRITE_CONCERN
%token KW_W_UNACKNOWLEDGED
%token KW_W_DEFAULT
%token KW_W_MAJORITY
%type <num> write_concern_strict
%type <num> write_concern
%%
start
: LL_CONTEXT_DESTINATION KW_MONGODB
{
last_driver = *instance = afmongodb_dd_new(configuration);
}
'(' _inner_dest_context_push afmongodb_options _inner_dest_context_pop ')' { YYACCEPT; }
;
write_concern_strict
: KW_W_UNACKNOWLEDGED { $$ = 0; } /* MONGOC_WRITE_CONCERN_W_UNACKNOWLEDGED */
| KW_W_DEFAULT { $$ = -2; } /* MONGOC_WRITE_CONCERN_W_DEFAULT */
| KW_W_MAJORITY { $$ = -3; } /* MONGOC_WRITE_CONCERN_W_MAJORITY */
;
write_concern
: write_concern_strict
| positive_integer { $$ = $1; }
;
afmongodb_options
: afmongodb_option afmongodb_options
|
;
afmongodb_option
: KW_URI '(' string ')' { afmongodb_dd_set_uri(last_driver, $3); free($3); }
| KW_BULK '(' yesno ')' { afmongodb_dd_set_bulk(last_driver, $3); }
| KW_BULK_UNORDERED '(' yesno ')' { afmongodb_dd_set_bulk_unordered(last_driver, $3); }
| KW_BULK_BYPASS_VALIDATION '(' yesno ')' { afmongodb_dd_set_bulk_bypass_validation(last_driver, $3); }
| KW_WRITE_CONCERN '(' write_concern ')' { afmongodb_dd_set_write_concern(last_driver, $3); }
| KW_COLLECTION '(' template_content ')' { afmongodb_dd_set_collection(last_driver, $3); }
| value_pair_option { afmongodb_dd_set_value_pairs(last_driver, $1); }
| threaded_dest_driver_general_option
| threaded_dest_driver_workers_option
| threaded_dest_driver_batch_option
| { last_template_options = afmongodb_dd_get_template_options(last_driver); } template_option
;
/* INCLUDE_RULES */
%%
|
