1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
|
# text.tcl --
#
# The HTML export plugin. Generation of HTML markup.
#
# Copyright (c) 2009 Andreas Kupries <andreas_kupries@sourceforge.net>
#
# See the file "license.terms" for information on usage and redistribution
# of this file, and for a DISCLAIMER OF ALL WARRANTIES.
#
# RCS: @(#) $Id: export_html.tcl,v 1.3 2009/11/15 05:50:03 andreas_kupries Exp $
# This package is a plugin for the doctools::toc v2 system. It takes
# the list serialization of a table of contents and produces text in
# HTML format.
# ### ### ### ######### ######### #########
## Requisites
# @mdgen NODEP: doctools::toc::export::plugin
package require Tcl 8.4
package require doctools::toc::export::plugin ; # Presence of this
# pseudo package
# indicates execution
# inside of a properly
# initialized plugin
# interpreter.
package require doctools::toc::structure ; # Verification that the
# input is proper.
package require doctools::html
package require doctools::html::cssdefaults
doctools::html::import ;# -> ::html::*
# ### ### ### ######### ######### #########
## API.
proc export {serial configuration} {
# Phase I. Check that we got a canonical toc serialization. That
# makes the unpacking easier, as we can mix it with the
# generation of the output, knowing that everything is
# already sorted as it should be.
::doctools::toc::structure verify-as-canonical $serial
# ### ### ### ######### ######### #########
# Configuration ...
# * Standard entries
# - user = person running the application doing the formatting
# - format = name of this format
# - file = name of the file the toc came from. Optional.
# - map = maps symbolic references to actual file path. Optional.
# * HTML specific entries
# - newlines = boolean. tags separated by eol markers
# - indented = boolean. tags indented per their nesting structure.
# //layout = string in { list, table }.
#
# - meta = HTML fragment for use within the document <meta> section.
# - header = HTML fragment used immediately after <body>
# - footer = HTML fragment used immediately before </body>
#
# - rid = dictionary mapping element labels to link anchor names.
# <=> Reference IDentifier
#
# Notes
# * indented => newlines
# Import the configuration and initialize the internal state
#// layout list
array set config {
newlines 0
indented 0
meta {}
header {}
footer {}
rid {}
map {}
sepline ------------------------------------------------------------
class.main doctools
class.header toc-header
class.title toc-title
class.navsep toc-navsep
class.contents toc-contents
class.ref toc-ref
class.div toc-div
class.footer toc-footer
}
array set config $configuration
array set map $config(map)
array set rid $config(rid)
# Force the implications mentioned in the notes above.
if {$config(indented)} {
set config(newlines) 1
}
# Allow structuring comments iff structure is present.
set config(comments) [expr {$config(indented) || $config(newlines)}]
# ### ### ### ######### ######### #########
# Phase II. Generate the output, taking the configuration into
# account.
# Unpack the serialization.
array set toc $serial
array set toc $toc(doctools::toc)
unset toc(doctools::toc)
html::begin
# Configure the layouting
if {!$config(indented)} { html::indenting 0 }
if {!$config(newlines)} { html::newlines 0 }
html::tag* html {
html::newline ; html::indented 4 {
Header
Provenance
Body
}
}
return [html::done]
}
# ### ### ### ######### ######### #########
proc Header {} {
upvar 1 config config toc toc
html::tag* head {
html::newline ; html::indented 4 {
html::tag= title [Title] ; html::newline
if {![Extend meta]} {
html::tag* style {
DefaultStyle
} ; html::newline
}
}
} ; html::newline
return
}
proc Provenance {} {
upvar 1 config config
if {!$config(comments)} return
html::comment [html::collect {
html::indented 4 {
html::+ "Generated @ [clock format [clock seconds]]" ; html::newline
html::+ "By $config(user)" ; html::newline
if {[info exists config(file)] && ($config(file) ne {})} {
html::+ "From file $config(file)" ; html::newline
}
}
}] ; html::newline
return
}
proc Body {} {
upvar 1 config config rid rid toc toc
html::tag* body {
html::newline ; html::indented 4 {
html::tag* div class $config(class.main) {
html::newline ; html::indented 4 {
html::tag* div class $config(class.header) {
html::newline ; html::indented 4 {
BodyTitle
UserHeader
html::tag1 hr class $config(class.navsep) ; html::newline
}
} ; html::newline
Division $toc(items) {} {Table Of Contents}
html::tag* div class $config(class.footer) {
html::newline ; html::indented 4 {
html::tag1 hr class $config(class.navsep) ; html::newline
UserFooter
}
} ; html::newline
}
} ; html::newline
}
} ; html::newline
return
}
# ### ### ### ######### ######### #########
proc BodyTitle {} {
upvar 1 toc toc config config
html::tag= h1 class $config(class.title) [Title] ; html::newline
return
}
proc UserHeader {} {
upvar 1 config config
Extend header
html::newline
return
}
proc UserFooter {} {
upvar 1 config config
Extend footer
html::newline
return
}
# ### ### ### ######### ######### #########
proc Title {} {
upvar 1 toc(label) label toc(title) title
if {($label ne {}) && ($title ne {})} {
return "$label -- $title"
} elseif {$label ne {}} {
return $label
} elseif {$title ne {}} {
return $title
}
return -code error {Reached the unreachable}
}
proc DefaultStyle {} {
html::comment \n[doctools::html::cssdefaults::contents]
return
}
# ### ### ### ######### ######### #########
proc Division {items path seplabel} {
upvar 1 config config rid rid map map
# No content for an empty division
if {![llength $items]} return
# Process the elements in a division.
Separator "Start $seplabel"
html::tag* dl class $config(class.contents) {
html::newline ; html::indented 4 {
foreach element $items {
foreach {etype edata} $element break
array set e $edata
switch -exact -- $etype {
reference {
html::tag* dt class $config(class.ref) {
RMap $e(label)
html::tag= a href [Map $e(id)] $e(label)
}
html::newline
html::tag= dd class $config(class.ref) $e(desc)
html::newline
}
division {
html::tag* dt class $config(class.div) {
RMap $e(label)
if {[info exists e(id)]} {
html::tag= a href [Map $e(id)] $e(label)
} else {
html::+ $e(label)
}
}
html::newline
html::tag* dd class $config(class.div) {
html::newline ; html::indented 4 {
Division $e(items) [linsert $path end $e(label)] "Division ($e(label))"
}
} ; html::newline
}
}
unset e
}
}
} ; html::newline
Separator "Stop $seplabel"
}
# ### ### ### ######### ######### #########
proc Separator {{text {}}} {
upvar config config
if {!$config(comments)} return
set str $config(sepline)
if {$text ne {}} {
set new " $text "
set str [string replace $str 1 [string length $new] $new]
}
html::comment $str
html::newline
return
}
proc Map {id} {
upvar 1 map map
if {![info exists map($id)]} { return $id }
return $map($id)
}
proc RMap {label} {
upvar 1 rid rid path path
set k [linsert $path end $label]
if {![info exists rid($k)]} return
html::tag/ a name $rid($k)
}
proc Extend {varname} {
upvar 1 config config
if {$config($varname) eq {}} {
if {$config(comments)} {
html::comment "Customization Point: $varname"
}
return 0
}
html::+++ $config($varname)
return 1
}
# ### ### ### ######### ######### #########
## Ready
package provide doctools::toc::export::html 0.1
return
|
