1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
|
###
# Class to deliver Static content
# When utilized, this class is fed a local filename
# by the dispatcher
###
::clay::define ::httpd::content.file {
method FileName {} {
# Some dispatchers will inject a fully qualified name during discovery
if {[my clay exists FILENAME] && [file exists [my clay get FILENAME]]} {
my request set PREFIX_URI [file dirname [my clay get FILENAME]]
return [my clay get FILENAME]
}
set uri [string trimleft [my request get REQUEST_PATH] /]
set path [my clay get path]
set prefix [my clay get prefix]
set fname [string range $uri [string length $prefix] end]
if {$fname in "{} index.html index.md index index.tml index.tcl"} {
return $path
}
if {[file exists [file join $path $fname]]} {
return [file join $path $fname]
}
if {[file exists [file join $path $fname.md]]} {
return [file join $path $fname.md]
}
if {[file exists [file join $path $fname.html]]} {
return [file join $path $fname.html]
}
if {[file exists [file join $path $fname.tml]]} {
return [file join $path $fname.tml]
}
if {[file exists [file join $path $fname.tcl]]} {
return [file join $path $fname.tcl]
}
return {}
}
method DirectoryListing {local_file} {
set uri [string trimleft [my request get REQUEST_PATH] /]
set path [my clay get path]
set prefix [my clay get prefix]
set fname [string range $uri [string length $prefix] end]
my puts [my html_header "Listing of /$fname/"]
my puts "Listing contents of /$fname/"
my puts "<TABLE>"
if {$prefix ni {/ {}}} {
set updir [file dirname $prefix]
if {$updir ne {}} {
my puts "<TR><TD><a href=\"/$updir\">..</a></TD><TD></TD></TR>"
}
}
foreach file [glob -nocomplain [file join $local_file *]] {
if {[file isdirectory $file]} {
my puts "<TR><TD><a href=\"[file join / $uri [file tail $file]]\">[file tail $file]/</a></TD><TD></TD></TR>"
} else {
my puts "<TR><TD><a href=\"[file join / $uri [file tail $file]]\">[file tail $file]</a></TD><TD>[file size $file]</TD></TR>"
}
}
my puts "</TABLE>"
my puts [my html_footer]
}
method content {} {
my variable reply_file
set local_file [my FileName]
if {$local_file eq {} || ![file exist $local_file]} {
my log httpNotFound [my request get REQUEST_PATH]
my error 404 {File Not Found}
tailcall my DoOutput
}
if {[file isdirectory $local_file] || [file tail $local_file] in {index index.html index.tml index.md}} {
my request set PREFIX_URI [my request get REQUEST_PATH]
my request set LOCAL_DIR $local_file
###
# Produce an index page
###
set idxfound 0
foreach name {
index.tcl
index.html
index.tml
index.md
index.info
index.clay
content.htm
} {
if {[file exists [file join $local_file $name]]} {
set idxfound 1
set local_file [file join $local_file $name]
break
}
}
if {!$idxfound} {
tailcall my DirectoryListing $local_file
}
} else {
my request set PREFIX_URI [file dirname [my request get REQUEST_PATH]]
my request set LOCAL_DIR [file dirname $local_file]
}
my request set LOCAL_FILE $local_file
switch [file extension $local_file] {
.apng {
my reply set Content-Type {image/apng}
set reply_file $local_file
}
.bmp {
my reply set Content-Type {image/bmp}
set reply_file $local_file
}
.css {
my reply set Content-Type {text/css}
set reply_file $local_file
}
.gif {
my reply set Content-Type {image/gif}
set reply_file $local_file
}
.cur - .ico {
my reply set Content-Type {image/x-icon}
set reply_file $local_file
}
.jpg - .jpeg - .jfif - .pjpeg - .pjp {
my reply set Content-Type {image/jpg}
set reply_file $local_file
}
.js {
my reply set Content-Type {text/javascript}
set reply_file $local_file
}
.md {
package require Markdown
my reply set Content-Type {text/html; charset=UTF-8}
set mdtxt [::fileutil::cat $local_file]
my puts [::Markdown::convert $mdtxt]
}
.png {
my reply set Content-Type {image/png}
set reply_file $local_file
}
.svgz -
.svg {
# FU magic screws it up
my reply set Content-Type {image/svg+xml}
set reply_file $local_file
}
.tcl {
my reply set Content-Type {text/html; charset=UTF-8}
try {
source $local_file
} on error {err errdat} {
my error 500 {Internal Error} [dict get $errdat -errorinfo]
}
}
.tiff {
my reply set Content-Type {image/tiff}
set reply_file $local_file
}
.tml {
my reply set Content-Type {text/html; charset=UTF-8}
set tmltxt [::fileutil::cat $local_file]
set headers [my request dump]
dict with headers {}
my puts [subst $tmltxt]
}
.txt {
my reply set Content-Type {text/plain}
set reply_file $local_file
}
.webp {
my reply set Content-Type {image/webp}
set reply_file $local_file
}
default {
###
# Assume we are returning a binary file
###
my reply set Content-Type [::fileutil::magic::filetype $local_file]
set reply_file $local_file
}
}
}
method Dispatch {} {
my variable reply_body reply_file reply_chan chan
try {
my reset
# Invoke the URL implementation.
my content
} on error {err errdat} {
my error 500 $err [dict get $errdat -errorinfo]
catch {
tailcall my DoOutput
}
}
if {$chan eq {}} return
catch {
# Causing random issues. Technically a socket is always open for read and write
# anyway
#my wait writable $chan
if {![info exists reply_file]} {
tailcall my DoOutput
}
chan configure $chan -translation {binary binary}
my log HttpAccess {}
###
# Return a stream of data from a file
###
set size [file size $reply_file]
my reply set Content-Length $size
append result [my reply output] \n
chan puts -nonewline $chan $result
set reply_chan [open $reply_file r]
my ChannelRegister $reply_chan
my log SendReply [list length $size]
###
# Output the file contents. With no -size flag, channel will copy until EOF
###
chan configure $reply_chan -translation {binary binary} -buffersize 4096 -buffering full -blocking 0
if {$size < 40960} {
# Raw copy small files
chan copy $reply_chan $chan
} else {
my ChannelCopy $reply_chan $chan -chunk 4096
}
}
}
}
|
