1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
|
# classic_polyns.tcl --
# Implement procedures for the classic orthogonal polynomials
#
package require math::polynomials
namespace eval ::math::special {
if {[info commands addPolyn] == {} } {
namespace import ::math::polynomials::*
}
}
# legendre --
# Return the nth degree Legendre polynomial
#
# Arguments:
# n The degree of the polynomial
# Result:
# Polynomial definition
#
proc ::math::special::legendre {n} {
if { ! [string is integer -strict $n] || $n < 0 } {
return -code error "Degree must be a non-negative integer"
}
set pnm1 [polynomial 1.0]
set pn [polynomial {0.0 1.0}]
if { $n == 0 } {return $pnm1}
if { $n == 1 } {return $pn}
set degree 1
while { $degree < $n } {
set an [expr {(2.0*$degree+1.0)/($degree+1.0)}]
set bn 0.0
set cn [expr {$degree/($degree+1.0)}]
set factor_n [polynomial [list $bn $an]]
set term_nm1 [multPolyn $pnm1 [expr {-1.0*$cn}]]
set term_n [multPolyn $factor_n $pn]
set pnp1 [addPolyn $term_n $term_nm1]
set pnm1 $pn
set pn $pnp1
incr degree
}
return $pnp1
}
# chebyshev --
# Return the nth degree Chebeyshev polynomial of the first kind
#
# Arguments:
# n The degree of the polynomial
# Result:
# Polynomial definition
#
proc ::math::special::chebyshev {n} {
if { ! [string is integer -strict $n] || $n < 0 } {
return -code error "Degree must be a non-negative integer"
}
set pnm1 [polynomial 1.0]
set pn [polynomial {0.0 1.0}]
if { $n == 0 } {return $pnm1}
if { $n == 1 } {return $pn}
set degree 1
while { $degree < $n } {
set an 2.0
set bn 0.0
set cn 1.0
set factor_n [polynomial [list $bn $an]]
set term_nm1 [multPolyn $pnm1 [expr {-1.0*$cn}]]
set term_n [multPolyn $factor_n $pn]
set pnp1 [addPolyn $term_n $term_nm1]
set pnm1 $pn
set pn $pnp1
incr degree
}
return $pnp1
}
# laguerre --
# Return the nth degree Laguerre polynomial with parameter alpha
#
# Arguments:
# alpha The parameter for the polynomial
# n The degree of the polynomial
# Result:
# Polynomial definition
#
proc ::math::special::laguerre {alpha n} {
if { ! [string is double -strict $alpha] } {
return -code error "Parameter must be a double"
}
if { ! [string is integer -strict $n] || $n < 0 } {
return -code error "Degree must be a non-negative integer"
}
set pnm1 [polynomial 1.0]
set pn [polynomial [list [expr {1.0-$alpha}] -1.0]]
if { $n == 0 } {return $pnm1}
if { $n == 1 } {return $pn}
set degree 1
while { $degree < $n } {
set an [expr {-1.0/($degree+1.0)}]
set bn [expr {(2.0*$degree+$alpha+1)/($degree+1.0)}]
set cn [expr {($degree+$alpha)/($degree+1.0)}]
set factor_n [polynomial [list $bn $an]]
set term_nm1 [multPolyn $pnm1 [expr {-1.0*$cn}]]
set term_n [multPolyn $factor_n $pn]
set pnp1 [addPolyn $term_n $term_nm1]
set pnm1 $pn
set pn $pnp1
incr degree
}
return $pnp1
}
# hermite --
# Return the nth degree Hermite polynomial
#
# Arguments:
# n The degree of the polynomial
# Result:
# Polynomial definition
#
proc ::math::special::hermite {n} {
if { ! [string is integer -strict $n] || $n < 0 } {
return -code error "Degree must be a non-negative integer"
}
set pnm1 [polynomial 1.0]
set pn [polynomial {0.0 2.0}]
if { $n == 0 } {return $pnm1}
if { $n == 1 } {return $pn}
set degree 1
while { $degree < $n } {
set an 2.0
set bn 0.0
set cn [expr {2.0*$degree}]
set factor_n [polynomial [list $bn $an]]
set term_n [multPolyn $factor_n $pn]
set term_nm1 [multPolyn $pnm1 [expr {-1.0*$cn}]]
set pnp1 [addPolyn $term_n $term_nm1]
set pnm1 $pn
set pn $pnp1
incr degree
}
return $pnp1
}
# some tests --
#
if { 0 } {
set prec $::tcl_precision
if {![package vsatisfies [package provide Tcl] 8.5]} {
set ::tcl_precision 17
} else {
set ::tcl_precision 0
}
puts "Legendre:"
foreach n {0 1 2 3 4} {
puts [::math::special::legendre $n]
}
puts "Chebyshev:"
foreach n {0 1 2 3 4} {
puts [::math::special::chebyshev $n]
}
puts "Laguerre (alpha=0):"
foreach n {0 1 2 3 4} {
puts [::math::special::laguerre 0.0 $n]
}
puts "Laguerre (alpha=1):"
foreach n {0 1 2 3 4} {
puts [::math::special::laguerre 1.0 $n]
}
puts "Hermite:"
foreach n {0 1 2 3 4} {
puts [::math::special::hermite $n]
}
set ::tcl_precision $prec
}
|
