1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
|
# json.tcl --
#
# The JSON export plugin. Generation of Java Script Object Notation.
#
# Copyright (c) 2009 Andreas Kupries <andreas_kupries@sourceforge.net>
#
# See the file "license.terms" for information on usage and redistribution
# of this file, and for a DISCLAIMER OF ALL WARRANTIES.
#
# RCS: @(#) $Id: export_json.tcl,v 1.2 2009/08/07 18:53:11 andreas_kupries Exp $
# This package is a plugin for the doctools::idx v2 system. It takes
# the list serialization of a keyword index and produces text in JSON
# format.
# ### ### ### ######### ######### #########
## Requisites
# @mdgen NODEP: doctools::idx::export::plugin
package require Tcl 8.4
package require doctools::idx::export::plugin ; # Presence of this
# pseudo package
# indicates execution
# inside of a properly
# initialized plugin
# interpreter.
package require doctools::idx::structure ; # Verification that
# the input is proper.
package require textutil::adjust
# ### ### ### ######### ######### #########
## API.
proc export {serial configuration} {
# Phase I. Check that we got a canonical index serialization. That
# makes the unpacking easier, as we can mix it with the
# generation of the output, knowing that everything is
# already sorted as it should be.
::doctools::idx::structure verify-as-canonical $serial
# ### ### ### ######### ######### #########
# Configuration ...
# * Standard entries
# - user = person running the application doing the formatting
# - format = name of this format
# - file = name of the file the index came from. Optional.
# - map = maps symbolic references to actual file path. Optional.
# * json/format specific entries
# - indented = boolean. objects indented per the index structure.
# - aligned = boolean. object keys tabular aligned vertically.
#
# Notes
# * This format ignores 'map' even if set, as the written json
# contains the symbolic references and only them.
# * aligned => indented
# Combinations of the format specific entries
# N I A |
# - - - + ---------------------
# 0 0 0 | Ultracompact (no whitespace, single line)
# 1 0 0 | Compact (no whitespace, multiple lines)
# 1 1 0 | Indented
# 1 0 1 | Tabular aligned references
# 1 1 1 | Indented + Tabular aligned references
# - - - + ---------------------
# 0 1 0 | Not possible, per the implications above.
# 0 0 1 | ditto
# 0 1 1 | ditto
# - - - + ---------------------
# Import the configuration and initialize the internal state
array set config {
indented 0
aligned 0
}
array set config $configuration
# Force the implications mentioned in the notes above.
if {$config(aligned)} {
set config(indented) 1
}
# ### ### ### ######### ######### #########
# Phase II. Generate the output, taking the configuration into
# account. We construct this from the inside out.
# Unpack the serialization.
array set idx $serial
array set idx $idx(doctools::idx)
unset idx(doctools::idx)
set keywords {}
foreach {kw references} $idx(keywords) {
set tmp {}
foreach id $references { lappend tmp [JsonString $id] }
lappend keywords $kw [JsonArrayList $tmp]
}
if {$config(aligned)} { set max 9 }
set references {}
foreach {id decl} $idx(references) {
foreach {type label} $decl break
set type [JsonString $type]
set label [JsonString $label]
if {$config(aligned)} {
set type [FmtR max $type]
}
lappend references $id [JsonArray $type $label]
}
return [JsonObject doctools::idx \
[JsonObject \
label [JsonString $idx(label)] \
keywords [JsonObjectDict $keywords] \
references [JsonObjectDict $references] \
title [JsonString $idx(title)]]]
# ### ### ### ######### ######### #########
}
# ### ### ### ######### ######### #########
proc JsonQuotes {} {
return [list "\"" "\\\"" / \\/ \\ \\\\ \b \\b \f \\f \n \\n \r \\r \t \\t]
}
proc JsonString {s} {
return "\"[string map [JsonQuotes] $s]\""
}
proc JsonArray {args} {
upvar 1 config config
return [JsonArrayList $args]
}
proc JsonArrayList {list} {
# compact form.
return "\[[join $list ,]\]"
}
proc JsonObject {args} {
upvar 1 config config
return [JsonObjectDict $args]
}
proc JsonObjectDict {dict} {
# The dict maps string keys to json-formatted data. I.e. we have
# to quote the keys, but not the values, as the latter are already
# in the proper format.
upvar 1 config config
set tmp {}
foreach {k v} $dict { lappend tmp [JsonString $k] $v }
set dict $tmp
if {$config(aligned)} { Align $dict max }
if {$config(indented)} {
set content {}
foreach {k v} $dict {
if {$config(aligned)} { set k [FmtR max $k] }
if {[string match *\n* $v]} {
# multi-line value
lappend content " $k : [textutil::adjust::indent $v { } 1]"
} else {
# single line value.
lappend content " $k : $v"
}
}
if {[llength $content]} {
return "\{\n[join $content ,\n]\n\}"
} else {
return "\{\}"
}
} else {
# ultra compact form.
set tmp {}
foreach {k v} $dict { lappend tmp "$k:$v" }
return "\{[join $tmp ,]\}"
}
}
proc Align {dict mv} {
upvar 1 $mv max
# Generate a list of references sortable by name, and also find the
# max length of all relevant names.
set max 0
foreach {str _} $dict { Max max $str }
return
}
proc Max {v str} {
upvar 1 $v max
set x [string length $str]
if {$x <= $max} return
set max $x
return
}
proc FmtR {v str} {
upvar 1 $v max
return $str[string repeat { } [expr {$max - [string length $str]}]]
}
# ### ### ### ######### ######### #########
## Ready
package provide doctools::idx::export::json 0.1
return
|
