1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
|
# text.tcl --
#
# The NROFF export plugin. Generation of man.macros based nroff markup.
#
# Copyright (c) 2009 Andreas Kupries <andreas_kupries@sourceforge.net>
#
# See the file "license.terms" for information on usage and redistribution
# of this file, and for a DISCLAIMER OF ALL WARRANTIES.
#
# RCS: @(#) $Id: export_nroff.tcl,v 1.4 2009/08/07 18:53:11 andreas_kupries Exp $
# This package is a plugin for the doctools::idx v2 system. It takes
# the list serialization of a keyword index and produces text in nroff
# format, man.macros based.
# ### ### ### ######### ######### #########
## Requisites
# @mdgen NODEP: doctools::idx::export::plugin
package require Tcl 8.4
package require doctools::idx::export::plugin ; # Presence of this
# pseudo package
# indicates execution
# inside of a properly
# initialized plugin
# interpreter.
package require doctools::idx::structure ; # Verification that the
# input is proper.
package require doctools::text ; # Text assembly package
package require doctools::nroff::man_macros ; # Macro definitions for result.
doctools::text::import ;# -> ::text::*
# ### ### ### ######### ######### #########
## API.
proc export {serial configuration} {
# Phase I. Check that we got a canonical index serialization. That
# makes the unpacking easier, as we can mix it with the
# generation of the output, knowing that everything is
# already sorted as it should be.
::doctools::idx::structure verify-as-canonical $serial
# ### ### ### ######### ######### #########
# Configuration ...
# * Standard entries
# - user = person running the application doing the formatting
# - format = name of this format
# - file = name of the file the index came from. Optional.
# - map = maps symbolic references to actual file path. Ignored
#
# Specific
# - inline = boolean. if set (default) man.macros is inlined in
# the output. other a .so reference to the file is
# generated.
# Import the configuration and initialize the internal state
array set config {
inline 1
}
array set config $configuration
# ### ### ### ######### ######### #########
# Phase II. Generate the output, taking the configuration into
# account.
# Unpack the serialization.
array set idx $serial
array set idx $idx(doctools::idx)
unset idx(doctools::idx)
array set r $idx(references)
text::begin
text::indenting 0 ; # Just in case someone tries to.
Provenance
if {$config(inline)} {
text::newline?
text::+ [doctools::nroff::man_macros::contents]
} else {
.so man.macros
}
.TH $idx(label)
.SH index
if {$idx(title) ne {}} {
text::+ $idx(title)
}
.RS
# Iterate over the keys and their references
foreach {keyword references} $idx(keywords) {
# Print the key
text::+ $keyword
text::newline
# Iterate over the references
.RS
foreach id $references {
foreach {type label} $r($id) break
.TP [BOLD $id]
text::newline
text::+ $label
text::newline
}
.RE
if {[llength $references]} {
.PP
}
}
return [text::done]
}
# ### ### ### ######### ######### #########
proc Provenance {} {
upvar 1 config config
COMMENT "Generated @ [clock format [clock seconds]]"
COMMENT "By $config(user)"
if {[info exists config(file)] && ($config(file) ne {})} {
COMMENT "From file $config(file)"
}
return
}
proc .so {file} {
text::newline?
text::+ ".so $file"
text::newline
return
}
proc .TP {text} {
text::newline?
text::+ .TP
text::newline
text::+ $text
return
}
proc COMMENT {text} {
set pfx "'\\\" " ;#
text::newline?
foreach line [split $text \n] {
text::+ $pfx
text::+ $line
text::newline
}
#text::+ $pfx[join [split $text \n] \n$pfx]
return
}
proc BOLD {text} {
return \\fB$text\\fR
}
proc .RS {} {
text::newline?
text::+ .RS
text::newline
return
}
proc .RE {} {
text::newline?
text::+ .RE
text::newline
return
}
proc .PP {} {
text::newline?
text::+ .PP
text::newline
return
}
proc .SH {name} {
text::newline?
text::+ ".SH "
set hasspaces [regexp {[ ]} $name]
set name [string toupper $name]
if {$hasspaces} { text::+ \" }
text::+ $name
if {$hasspaces} { text::+ \" }
text::newline
return
}
proc .TH {name} {
text::newline?
text::+ ".TH "
set hasspaces [regexp {[ ]} $name]
set name [string toupper $name]
if {$hasspaces} { text::+ \" }
text::+ $name
if {$hasspaces} { text::+ \" }
text::newline
return
}
# ### ### ### ######### ######### #########
## Ready
package provide doctools::idx::export::nroff 0.3
return
|
