File: web2c.ac

package info (click to toggle)
texlive-bin 2018.20181218.49446-1
  • links: PTS, VCS
  • area: main
  • in suites: buster
  • size: 186,920 kB
  • sloc: ansic: 873,264; cpp: 311,278; perl: 82,918; sh: 23,243; makefile: 8,590; lex: 4,939; python: 4,462; pascal: 3,813; java: 3,569; yacc: 2,901; tcl: 2,379; exp: 2,031; xml: 844; ruby: 678; lisp: 398; sed: 331; asm: 140; csh: 46; awk: 30
file content (85 lines) | stat: -rw-r--r-- 4,077 bytes parent folder | download | duplicates (2)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
## texk/web2c/ac/web2c.ac: configure.ac fragment for the TeX Live subdirectory texk/web2c/
dnl
dnl Copyright (C) 2009-2015 Peter Breitenlohner <tex-live@tug.org>
dnl You may freely use, modify and/or distribute this file.
dnl
## configure options for TeX and MF
m4_define_default([kpse_indent_26], [26])[]dnl
AC_ARG_WITH([banner-add],
            AS_HELP_STRING([--with-banner-add=STR],
                           [add STR to version string appended to banner lines]))[]dnl
AC_ARG_WITH([editor],
            AS_HELP_STRING([--with-editor=CMD],
                           [invoke CMD from the `e' option @<:@vi +%d '%s'@:>@
                            or @<:@texworks --position=%d "%s"@:>@]))[]dnl
AC_ARG_ENABLE([auto-core],
              AS_HELP_STRING([--enable-auto-core],
                             [cause TeX&MF to dump core, given a certain filename],
                             kpse_indent_26))[]dnl
AC_ARG_ENABLE([dump-share],
              AS_HELP_STRING([--disable-dump-share],
                             [make fmt/base files architecture-dependent],
                             kpse_indent_26))[]dnl
## configure options for TeX
AC_ARG_ENABLE([ipc],
              AS_HELP_STRING([--disable-ipc],
                             [disable TeX's --ipc option, i.e., pipe to a program],
                             kpse_indent_26))[]dnl
dnl [PROG, BUILD-OR-NO, SYNC-OR-NO, TEXT, REQUIRED-LIBS]
m4_define([kpse_tex_progs], [dnl
[[tex],       [yes], [no],  [TeX],        []],
[[etex],      [no],  [yes], [e-TeX],      []],
[[ptex],      [yes], [yes], [pTeX],       [ptexenc]],
[[eptex],     [yes], [yes], [e-pTeX],     [ptexenc]],
[[uptex],     [yes], [yes], [upTeX],      [ptexenc]],
[[euptex],    [yes], [yes], [e-upTeX],    [ptexenc]],
[[aleph],     [yes], [],    [Aleph],      []],
[[pdftex],    [yes], [yes], [pdfTeX],     [xpdf libpng]],
[[luatex],    [yes], [],    [LuaTeX],     [poppler mpfr libpng zziplib lua52]],
[[luatex53],  [yes], [],    [LuaTeX53],   [poppler mpfr libpng zziplib lua53]],
[[luajittex], [yes], [],    [LuaJITTeX],  [poppler mpfr libpng zziplib luajit]],
[[mp],        [yes], [],    [MetaPost],   [mpfr cairo libpng]],
[[pmp],       [yes], [],    [pMetaPost],  [mpfr cairo libpng ptexenc]],
[[upmp],      [yes], [],    [upMetaPost], [mpfr cairo libpng ptexenc]],
[[xetex],     [yes], [yes], [XeTeX],      [poppler libpng freetype2 teckit harfbuzz]],
])[]dnl
m4_foreach([Kpse_Prog], [kpse_tex_progs],
           [m4_ifset([Kpse_Prog],
                     [KPSE_WITH_XTEX(Kpse_Prog)])])[]dnl
## configure options for MF
dnl [PROG, BUILD-OR-NO, NOWIN-OR-NO, TEXT, REQUIRED-LIBS]
m4_define([kpse_mf_progs], [dnl
[[mf],       [yes], [yes], [METAFONT], []],
[[mflua],    [yes], [no],  [MFLua],    [lua52]],
[[mfluajit], [yes], [no],  [MFLuaJIT], [luajit]],
])[]dnl
m4_foreach([Kpse_Prog], [kpse_mf_progs],
           [m4_ifset([Kpse_Prog],
                     [KPSE_WITH_XMF(Kpse_Prog)])])[]dnl
AC_ARG_WITH([mf-x-toolkit],
            AS_HELP_STRING([--with-mf-x-toolkit],
                           [use X toolkit for METAFONT]))[]dnl
m4_define([kpse_mf_win], [dnl
[[epsf],      [EPSF],      [EPSF pseudo]],
[[hp2627],    [HP2627],    [HP 2627]],
[[mftalk],    [MFTALK],    [mftalk (generic server)]],
[[next],      [NEXT],      [NeXT]],
[[regis],     [REGIS],     [Regis]],
[[suntools],  [SUN],       [old Suntools (not X)]],
[[tektronix], [TEKTRONIX], [Tektronix]],
[[uniterm],   [UNITERM],   [Uniterm]],
])[]dnl
m4_foreach([Kpse_Win], [kpse_mf_win],
           [m4_ifset([Kpse_Win],
                     [KPSE_WITH_MFWIN(Kpse_Win)])])[]dnl
## configure options for WEB programs
AC_ARG_ENABLE([web-progs],
              AS_HELP_STRING([--disable-web-progs],
                             [do not build WEB programs bibtex ... weave],
                             kpse_indent_26))[]dnl
## configure option for the SyncTeX library and tool
AC_ARG_ENABLE([synctex],
              AS_HELP_STRING([--disable-synctex],
                             [do not build the SyncTeX library and tool],
                             kpse_indent_26))[]dnl