File: shim_headers.gni

package info (click to toggle)
thunderbird 1%3A91.13.0-1~deb11u1
  • links: PTS, VCS
  • area: main
  • in suites: bullseye
  • size: 2,953,400 kB
  • sloc: cpp: 6,084,049; javascript: 4,790,441; ansic: 3,341,496; python: 862,958; asm: 366,542; xml: 204,277; java: 152,477; sh: 111,436; makefile: 21,388; perl: 15,312; yacc: 4,583; objc: 3,026; lex: 1,720; exp: 762; pascal: 635; awk: 564; sql: 453; php: 436; lisp: 432; ruby: 99; sed: 69; csh: 45
file content (41 lines) | stat: -rw-r--r-- 1,067 bytes parent folder | download | duplicates (14) 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
 
# Copyright 2016 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

template("shim_headers") {
  action_name = "gen_${target_name}"
  config_name = "${target_name}_config"
  shim_headers_path = "${root_gen_dir}/shim_headers/${target_name}"

  config(config_name) {
    include_dirs = [ shim_headers_path ]
  }

  action(action_name) {
    script = "//tools/generate_shim_headers/generate_shim_headers.py"
    args = [
      "--generate",
      "--headers-root",
      rebase_path(invoker.root_path),
      "--output-directory",
      rebase_path(shim_headers_path),
    ]
    if (defined(invoker.prefix)) {
      args += [
        "--prefix",
        invoker.prefix,
      ]
    }
    args += invoker.headers

    outputs = process_file_template(invoker.headers,
                                    "${shim_headers_path}/{{source_file_part}}")
  }

  group(target_name) {
    deps = [
      ":${action_name}",
    ]
    all_dependent_configs = [ ":${config_name}" ]
  }
}