1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
|
/*
* Copyright (c) 2005 Washington University in St. Louis.
* All rights reserved.
*
* Redistribution and use in source and binary forms, with or without
* modification, are permitted provided that the following conditions
* are met:
*
* - Redistributions of source code must retain the above copyright
* notice, this list of conditions and the following disclaimer.
* - Redistributions in binary form must reproduce the above copyright
* notice, this list of conditions and the following disclaimer in the
* documentation and/or other materials provided with the
* distribution.
* - Neither the name of the copyright holders nor the names of
* its contributors may be used to endorse or promote products derived
* from this software without specific prior written permission.
*
* THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
* "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
* LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
* FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL
* THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
* INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
* (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
* SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
* HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
* STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
* ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
* OF THE POSSIBILITY OF SUCH DAMAGE.
*
*/
/*
* - Revision -------------------------------------------------------------
* $Revision: 1.7 $
* $Date: 2010-06-29 22:07:50 $
* ========================================================================
*/
/**
* Please refer to TEP 115 for more information about this component and its
* intended use.<br><br>
*
* This is the internal implementation of the deffered power management
* policy for managing the power states of non-virtualized devices.
* Non-virtualized devices are shared using a parameterized Resource
* interface, and are powered down according to some policy whenever there
* are no more pending requests to that Resource. The policy implemented
* by this component is to delay the power down of a device by some contant
* factor. Such a policy is useful whenever a device has a long wake-up
* latency. The cost of waiting for the device to power up can be
* avoided if the device is requested again before some predetermined
* amount of time.
*
* @param <b>delay</b> -- The amount of time the power manager should wait
* before shutting down the device once it is free.
*
* @author Kevin Klues (klueska@cs.wustl.edu)
*/
generic module DeferredPowerManagerP(uint32_t delay) {
uses {
interface StdControl;
interface SplitControl;
interface PowerDownCleanup;
interface ResourceDefaultOwner;
interface ArbiterInfo;
interface Timer<TMilli> as TimerMilli;
}
}
implementation {
norace bool stopping = FALSE;
norace bool requested = FALSE;
norace bool stopTimer = FALSE;
task void startTask() {
call TimerMilli.stop();
stopTimer = FALSE;
call StdControl.start();
if (call SplitControl.start()==EALREADY)
call ResourceDefaultOwner.release();
}
task void timerTask() {
call TimerMilli.startOneShot(delay);
}
async event void ResourceDefaultOwner.requested() {
if(stopping == FALSE) {
stopTimer = TRUE;
post startTask();
}
else requested = TRUE;
}
async event void ResourceDefaultOwner.immediateRequested() {
}
default command error_t StdControl.start() {
return SUCCESS;
}
default command error_t SplitControl.start() {
signal SplitControl.startDone(SUCCESS);
return SUCCESS;
}
event void SplitControl.startDone(error_t error) {
call ResourceDefaultOwner.release();
}
async event void ResourceDefaultOwner.granted() {
post timerTask();
}
event void TimerMilli.fired() {
atomic {
if(stopTimer == FALSE) {
stopping = TRUE;
call PowerDownCleanup.cleanup();
call StdControl.stop();
if (call SplitControl.stop()==EALREADY)
signal SplitControl.stopDone(SUCCESS);
}
}
}
event void SplitControl.stopDone(error_t error) {
if(requested == TRUE) {
call StdControl.start();
call SplitControl.start();
}
atomic {
requested = FALSE;
stopping = FALSE;
}
}
default command error_t StdControl.stop() {
return SUCCESS;
}
default command error_t SplitControl.stop() {
signal SplitControl.stopDone(SUCCESS);
return SUCCESS;
}
default async command void PowerDownCleanup.cleanup() {
}
}
|
