1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
|
/* $Id: QueueC.nc,v 1.7 2009-06-25 18:37:24 scipio Exp $ */
/*
* Copyright (c) 2006 Stanford University.
* All rights reserved.
*
* Redistribution and use in source and binary forms, with or without
* modification, are permitted provided that the following conditions
* are met:
* - Redistributions of source code must retain the above copyright
* notice, this list of conditions and the following disclaimer.
* - Redistributions in binary form must reproduce the above copyright
* notice, this list of conditions and the following disclaimer in the
* documentation and/or other materials provided with the
* distribution.
* - Neither the name of the Stanford University nor the names of
* its contributors may be used to endorse or promote products derived
* from this software without specific prior written permission.
*
* THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
* ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
* LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
* FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL STANFORD
* UNIVERSITY OR ITS CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
* INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
* (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
* SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
* HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
* STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
* ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
* OF THE POSSIBILITY OF SUCH DAMAGE.
*/
/**
* A general FIFO queue component, whose queue has a bounded size.
*
* @author Philip Levis
* @author Geoffrey Mainland
* @date $Date: 2009-06-25 18:37:24 $
*/
generic module QueueC(typedef queue_t, uint8_t QUEUE_SIZE) {
provides interface Queue<queue_t>;
}
implementation {
queue_t ONE_NOK queue[QUEUE_SIZE];
uint8_t head = 0;
uint8_t tail = 0;
uint8_t size = 0;
command bool Queue.empty() {
return size == 0;
}
command uint8_t Queue.size() {
return size;
}
command uint8_t Queue.maxSize() {
return QUEUE_SIZE;
}
command queue_t Queue.head() {
return queue[head];
}
void printQueue() {
#ifdef TOSSIM
int i, j;
dbg("QueueC", "head <-");
for (i = head; i < head + size; i++) {
dbg_clear("QueueC", "[");
for (j = 0; j < sizeof(queue_t); j++) {
uint8_t v = ((uint8_t*)&queue[i % QUEUE_SIZE])[j];
dbg_clear("QueueC", "%0.2hhx", v);
}
dbg_clear("QueueC", "] ");
}
dbg_clear("QueueC", "<- tail\n");
#endif
}
command queue_t Queue.dequeue() {
queue_t t = call Queue.head();
dbg("QueueC", "%s: size is %hhu\n", __FUNCTION__, size);
if (!call Queue.empty()) {
head++;
if (head == QUEUE_SIZE) head = 0;
size--;
printQueue();
}
return t;
}
command error_t Queue.enqueue(queue_t newVal) {
if (call Queue.size() < call Queue.maxSize()) {
dbg("QueueC", "%s: size is %hhu\n", __FUNCTION__, size);
queue[tail] = newVal;
tail++;
if (tail == QUEUE_SIZE) tail = 0;
size++;
printQueue();
return SUCCESS;
}
else {
return FAIL;
}
}
command queue_t Queue.element(uint8_t idx) {
idx += head;
if (idx >= QUEUE_SIZE) {
idx -= QUEUE_SIZE;
}
return queue[idx];
}
}
|
