1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
|
// $Id: SchedulerBasicP.nc,v 1.11 2010-06-29 22:07:56 scipio Exp $
/*
* Copyright (c) 2000-2003 The Regents of the University of California.
* All rights reserved.
*
* Redistribution and use in source and binary forms, with or without
* modification, are permitted provided that the following conditions
* are met:
*
* - Redistributions of source code must retain the above copyright
* notice, this list of conditions and the following disclaimer.
* - Redistributions in binary form must reproduce the above copyright
* notice, this list of conditions and the following disclaimer in the
* documentation and/or other materials provided with the
* distribution.
* - Neither the name of the University of California nor the names of
* its contributors may be used to endorse or promote products derived
* from this software without specific prior written permission.
*
* THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
* "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
* LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
* FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL
* THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT,
* INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
* (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
* SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
* HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
* STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
* ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
* OF THE POSSIBILITY OF SUCH DAMAGE.
*
* Copyright (c) 2002-2003 Intel Corporation
* All rights reserved.
*
* This file is distributed under the terms in the attached INTEL-LICENSE
* file. If you do not find these files, copies can be found by writing to
* Intel Research Berkeley, 2150 Shattuck Avenue, Suite 1300, Berkeley, CA,
* 94704. Attention: Intel License Inquiry.
*/
/**
* SchedulerBasicP implements the default TinyOS scheduler sequence, as
* documented in TEP 106.
*
* @author Philip Levis
* @author Cory Sharp
* @date January 19 2005
*/
#include "hardware.h"
module SchedulerBasicP @safe() {
provides interface Scheduler;
provides interface TaskBasic[uint8_t id];
uses interface McuSleep;
}
implementation
{
enum
{
NUM_TASKS = uniqueCount("TinySchedulerC.TaskBasic"),
NO_TASK = 255,
};
uint8_t m_head;
uint8_t m_tail;
uint8_t m_next[NUM_TASKS];
// Helper functions (internal functions) intentionally do not have atomic
// sections. It is left as the duty of the exported interface functions to
// manage atomicity to minimize chances for binary code bloat.
// move the head forward
// if the head is at the end, mark the tail at the end, too
// mark the task as not in the queue
inline uint8_t popTask()
{
if( m_head != NO_TASK )
{
uint8_t id = m_head;
m_head = m_next[m_head];
if( m_head == NO_TASK )
{
m_tail = NO_TASK;
}
m_next[id] = NO_TASK;
return id;
}
else
{
return NO_TASK;
}
}
bool isWaiting( uint8_t id )
{
return (m_next[id] != NO_TASK) || (m_tail == id);
}
bool pushTask( uint8_t id )
{
if( !isWaiting(id) )
{
if( m_head == NO_TASK )
{
m_head = id;
m_tail = id;
}
else
{
m_next[m_tail] = id;
m_tail = id;
}
return TRUE;
}
else
{
return FALSE;
}
}
command void Scheduler.init()
{
atomic
{
memset( (void *)m_next, NO_TASK, sizeof(m_next) );
m_head = NO_TASK;
m_tail = NO_TASK;
}
}
command bool Scheduler.runNextTask()
{
uint8_t nextTask;
atomic
{
nextTask = popTask();
if( nextTask == NO_TASK )
{
return FALSE;
}
}
signal TaskBasic.runTask[nextTask]();
return TRUE;
}
command void Scheduler.taskLoop()
{
for (;;)
{
uint8_t nextTask;
atomic
{
while ((nextTask = popTask()) == NO_TASK)
{
call McuSleep.sleep();
}
}
signal TaskBasic.runTask[nextTask]();
}
}
/**
* Return SUCCESS if the post succeeded, EBUSY if it was already posted.
*/
async command error_t TaskBasic.postTask[uint8_t id]()
{
atomic { return pushTask(id) ? SUCCESS : EBUSY; }
}
default event void TaskBasic.runTask[uint8_t id]()
{
}
}
|
