1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
|
#-------------------------------------------------
#
# Project created by QtCreator 2020-03-16T09:30:00
#
#-------------------------------------------------
TEMPLATE = app
TARGET = ukui-settings-daemon
QT += core gui dbus
CONFIG += no_keywords link_prl link_pkgconfig c++20
CONFIG -= app_bundle
DEFINES += MODULE_NAME=\\\"Daemon\\\"
QM_FILES_INSTALL_PATH = /usr/share/$${TARGET}/translations/
DEFINES += QM_FILES_INSTALL_PATH='\\"$${QM_FILES_INSTALL_PATH}\\"'
greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
include($$PWD/../common/common.pri)
TRANSLATIONS += \
translations/ukui-settings-daemon_bo_CN.ts \
translations/ukui-settings-daemon_zh_CN.ts \
translations/ukui-settings-daemon_mn.ts \
translations/ukui-settings-daemon_zh_HK.ts \
translations/ukui-settings-daemon_de.ts \
translations/ukui-settings-daemon_es.ts \
translations/ukui-settings-daemon_fr.ts \
translations/ukui-settings-daemon_kk_KZ.ts \
translations/ukui-settings-daemon_ky_KG.ts \
translations/ukui-settings-daemon_ug_CN.ts
PKGCONFIG += \
glib-2.0\
gio-2.0\
gobject-2.0\
gmodule-2.0 \
dconf
#msgfmt, .po
PO_FILES = $$files(*.po, true)
msgfmt.name = msgfmt
msgfmt.input = PO_FILES
msgfmt.output = ${QMAKE_FILE_IN_PATH}/${QMAKE_FILE_IN_BASE}.mo
msgfmt.commands = msgfmt -o ${QMAKE_FILE_OUT} ${QMAKE_FILE_IN}
msgfmt.CONFIG = no_link
#lrelease, .ts
qtPrepareTool(QMAKE_LRELEASE, lrelease)
lrelease.name = lrelease
lrelease.input = TRANSLATIONS
lrelease.output = ${QMAKE_FILE_IN_PATH}/${QMAKE_FILE_IN_BASE}.qm
lrelease.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN} -qm ${QMAKE_FILE_OUT}
lrelease.CONFIG = no_link
QMAKE_EXTRA_COMPILERS += \
msgfmt \
lrelease
PRE_TARGETDEPS += \
compiler_msgfmt_make_all \
compiler_lrelease_make_all
for (PO_FILE, PO_FILES) {
MO_DIR = $$dirname(PO_FILE)
LANG = $$basename(MO_DIR)
$${LANG}.files = $$replace(PO_FILE, .po, .mo)
$${LANG}.path = /usr/share/locale/$${LANG}/LC_MESSAGES/
$${LANG}.CONFIG = no_check_exist
INSTALLS += $$LANG
}
qm_files.files = $$replace(TRANSLATIONS, .ts, .qm)
qm_files.path = $$QM_FILES_INSTALL_PATH
qm_files.CONFIG = no_check_exist
INSTALLS += qm_files
SOURCES += \
$$PWD/main.cpp\
$$PWD/plugin-info.cpp\
$$PWD/plugin-manager.cpp\
$$PWD/manager-interface.cpp
HEADERS += \
$$PWD/plugin-info.h\
$$PWD/plugin-manager.h\
$$PWD/manager-interface.h \
$$PWD/global.h
target.path = /usr/bin/
target.files = $$OUT_PWD/$$TARGET
!isEmpty(target.path): INSTALLS += target
|
