1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
|
/* valareturnstatement.vala
*
* Copyright (C) 2006-2010 Jürg Billeter
*
* This library is free software; you can redistribute it and/or
* modify it under the terms of the GNU Lesser General Public
* License as published by the Free Software Foundation; either
* version 2.1 of the License, or (at your option) any later version.
* This library is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
* Lesser General Public License for more details.
* You should have received a copy of the GNU Lesser General Public
* License along with this library; if not, write to the Free Software
* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
*
* Author:
* Jürg Billeter <j@bitron.ch>
*/
/**
* Represents a return statement in the source code.
*/
public class Vala.ReturnStatement : CodeNode, Statement {
/**
* The optional expression to return.
*/
public Expression? return_expression {
get { return _return_expression; }
set {
_return_expression = value;
if (_return_expression != null) {
_return_expression.parent_node = this;
}
}
}
private Expression _return_expression;
/**
* Creates a new return statement.
*
* @param return_expression the return expression
* @param source_reference reference to source code
* @return newly created return statement
*/
public ReturnStatement (Expression? return_expression = null, SourceReference? source_reference = null) {
this.source_reference = source_reference;
this.return_expression = return_expression;
}
public override void accept (CodeVisitor visitor) {
visitor.visit_return_statement (this);
}
public override void accept_children (CodeVisitor visitor) {
if (return_expression != null) {
return_expression.accept (visitor);
visitor.visit_end_full_expression (return_expression);
}
}
public override void replace_expression (Expression old_node, Expression new_node) {
if (return_expression == old_node) {
return_expression = new_node;
}
}
public override bool check (CodeContext context) {
if (checked) {
return !error;
}
checked = true;
if (return_expression != null) {
return_expression.target_type = context.analyzer.current_return_type.copy ();
}
if (return_expression != null && !return_expression.check (context)) {
// ignore inner error
error = true;
return false;
}
if (context.analyzer.current_return_type == null) {
error = true;
Report.error (source_reference, "Return not allowed in this context");
return false;
}
if (return_expression == null) {
if (!(context.analyzer.current_return_type is VoidType)) {
error = true;
Report.error (source_reference, "Return without value in non-void function");
}
return !error;
}
if (context.analyzer.current_return_type is VoidType) {
Report.error (source_reference, "Return with value in void function");
return false;
}
if (return_expression.value_type == null) {
error = true;
Report.error (source_reference, "Invalid expression in return value");
return false;
}
if (!return_expression.value_type.compatible (context.analyzer.current_return_type)) {
error = true;
Report.error (source_reference, "Return: Cannot convert from `%s' to `%s'".printf (return_expression.value_type.to_string (), context.analyzer.current_return_type.to_string ()));
return false;
}
if (return_expression.value_type.is_disposable () &&
!context.analyzer.current_return_type.value_owned) {
error = true;
Report.error (source_reference, "Return value transfers ownership but method return type hasn't been declared to transfer ownership");
return false;
}
var local = return_expression.symbol_reference as LocalVariable;
if (local != null && local.variable_type.is_disposable () &&
!context.analyzer.current_return_type.value_owned) {
error = true;
Report.error (source_reference, "Local variable with strong reference used as return value and method return type has not been declared to transfer ownership");
return false;
}
if (return_expression is NullLiteral
&& !context.analyzer.current_return_type.nullable) {
Report.warning (source_reference, "`null' incompatible with return type `%s'".printf (context.analyzer.current_return_type.to_string ()));
}
add_error_types (return_expression.get_error_types ());
return !error;
}
public override void emit (CodeGenerator codegen) {
if (return_expression != null) {
return_expression.emit (codegen);
codegen.visit_end_full_expression (return_expression);
}
codegen.visit_return_statement (this);
}
public override void get_defined_variables (Collection<Variable> collection) {
if (return_expression != null) {
return_expression.get_defined_variables (collection);
}
}
public override void get_used_variables (Collection<Variable> collection) {
if (return_expression != null) {
return_expression.get_used_variables (collection);
}
}
}
|
