File: configure.ac

package info (click to toggle)
vcftools 0.1.14+dfsg-4+deb9u1
  • links: PTS, VCS
  • area: main
  • in suites: stretch
  • size: 1,908 kB
  • sloc: cpp: 13,928; perl: 11,080; ansic: 1,467; sh: 135; makefile: 100
file content (85 lines) | stat: -rw-r--r-- 2,093 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_PREREQ([2.63])
AC_INIT([vcftools],
        [m4_esyscmd([build-aux/git-version-gen .tarball-version])],
        [https://github.com/vcftools/vcftools/issues])
AC_CONFIG_SRCDIR([src/cpp/vcftools.cpp])
AC_CONFIG_HEADERS([config.h])

# Automake invocation.
AM_INIT_AUTOMAKE([foreign])

# Checks for programs.
AC_PROG_CXX
AC_PROG_CC
AC_PROG_CPP

# Checks for perl.
AC_PATH_PROGS([PERL], [perl] [perl5], [false])
if test "x$PERL" = xfalse ; then
  AC_MSG_ERROR([Perl not found; check your \$PATH.])
fi

pmdir_relative_path=`\
$PERL -MConfig \
      -wle '($_ = $Config{installsitelib})
            =~ s!^\Q$Config{siteprefix}/!!; \
            print'`

AC_ARG_WITH(
    [pmdir],
    AS_HELP_STRING(
      [--with-pmdir=DIR],
      [install Perl modules in DIR]),
    [PMDIR=${withval}],
    [PMDIR='${prefix}'/"$pmdir_relative_path"])

AC_SUBST([PMDIR])

# Checks for libraries.
PKG_CHECK_MODULES(ZLIB, zlib)

# Checks for header files.
AC_CHECK_HEADERS([arpa/inet.h fcntl.h limits.h netdb.h stdint.h stdlib.h string.h sys/socket.h unistd.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_HEADER_STDBOOL
AC_C_INLINE
AC_TYPE_INT16_T
AC_TYPE_INT32_T
AC_TYPE_INT64_T
AC_TYPE_INT8_T
AC_TYPE_OFF_T
AC_TYPE_SIZE_T
AC_TYPE_SSIZE_T
AC_TYPE_UINT16_T
AC_TYPE_UINT32_T
AC_TYPE_UINT8_T

# Checks for operating system services or capabilities.
AC_SYS_LARGEFILE

# Checks for library functions.
AC_FUNC_ERROR_AT_LINE
AC_FUNC_MALLOC
AC_FUNC_REALLOC
AC_CHECK_FUNCS([gethostbyaddr gethostbyname memset pow select socket sqrt strchr strdup strerror strstr strtol])

# Optional features.
AC_ARG_ENABLE([pca],
              AS_HELP_STRING([--enable-pca], [enable PCA feature]),
              [pca=${enableval}],
              [pca=no])

if test "x${pca}" = "xyes" ; then
  AC_CHECK_LIB(lapack, dgeev_)
fi

# Generate output.
AC_CONFIG_FILES([Makefile
                 src/Makefile
                 src/cpp/Makefile
                 src/perl/Makefile])
AC_OUTPUT