1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535 536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576 577 578 579 580 581 582 583 584 585 586 587 588 589 590 591 592 593 594 595 596 597 598 599 600 601 602 603 604 605 606 607 608 609 610 611 612 613 614 615 616 617 618 619 620 621 622 623 624 625 626 627 628 629 630 631 632 633 634 635 636 637 638 639 640 641 642 643 644 645 646 647 648 649 650 651 652 653 654 655 656 657 658 659 660 661 662 663 664 665 666 667 668 669 670 671 672 673 674 675 676 677 678 679 680 681 682 683 684 685 686 687 688 689 690 691 692 693 694 695 696 697 698 699 700 701 702 703 704 705 706 707 708 709 710 711 712 713 714 715 716 717 718 719 720 721 722 723 724 725 726 727 728 729 730 731 732 733 734 735 736 737 738 739 740 741 742 743 744 745 746 747 748 749 750 751 752 753 754 755 756 757 758 759 760 761 762 763 764 765 766 767 768 769 770 771 772 773 774 775 776 777 778 779 780 781 782 783 784 785 786 787 788 789 790 791 792 793 794 795 796 797 798 799 800 801 802 803 804 805 806 807 808 809 810 811 812 813 814 815 816 817 818 819 820 821 822 823 824 825 826 827 828 829 830 831 832 833 834 835 836 837 838 839 840 841 842 843 844 845 846 847 848 849 850 851 852 853 854 855 856 857 858 859 860 861 862 863 864 865 866 867 868 869 870 871 872 873 874 875 876 877 878 879 880 881 882 883 884 885 886 887 888 889 890 891 892 893 894 895 896 897 898 899 900 901 902 903 904 905 906 907 908 909 910 911 912 913 914 915 916 917 918 919 920 921 922 923 924 925 926 927 928 929 930 931 932 933 934 935 936 937 938 939 940 941 942 943 944 945 946 947 948 949 950 951 952 953 954 955 956 957 958 959 960 961 962 963 964 965 966 967 968 969 970 971 972 973 974 975 976 977 978 979 980 981 982 983 984 985 986 987 988 989 990 991 992 993 994 995 996 997 998 999 1000 1001 1002 1003 1004 1005 1006 1007 1008 1009 1010 1011 1012 1013 1014 1015 1016 1017 1018 1019 1020 1021 1022 1023 1024 1025 1026 1027 1028 1029 1030 1031 1032 1033 1034 1035 1036 1037 1038 1039 1040 1041 1042 1043 1044 1045 1046 1047 1048 1049 1050 1051 1052 1053 1054 1055 1056 1057 1058 1059 1060 1061 1062 1063 1064 1065 1066 1067 1068 1069 1070 1071 1072 1073 1074 1075 1076 1077 1078 1079 1080 1081 1082 1083 1084 1085 1086 1087 1088 1089 1090 1091 1092 1093 1094 1095 1096 1097 1098 1099 1100 1101 1102 1103 1104 1105 1106 1107 1108 1109 1110 1111
|
" ============================================================================
" File: texviewer.vim
" Author: Mikolaj Machowski
" Created: Sun Jan 26 06:00 PM 2003
" Description: make a viewer for various purposes: \cite{, \ref{
" License: Vim Charityware License
" Part of vim-latexSuite: http://vim-latex.sourceforge.net
" ============================================================================
" Tex_SetTexViewerMaps: sets maps for this ftplugin {{{
function! Tex_SetTexViewerMaps()
inoremap <silent> <Plug>Tex_Completion <Esc>:call Tex_Complete("default","text")<CR>
if !hasmapto('<Plug>Tex_Completion', 'i')
if has('gui_running')
imap <buffer> <silent> <F9> <Plug>Tex_Completion
else
imap <buffer> <F9> <Plug>Tex_Completion
endif
endif
endfunction
augroup LatexSuite
au LatexSuite User LatexSuiteFileType
\ call Tex_Debug('texviewer.vim: Catching LatexSuiteFileType event', 'view') |
\ call Tex_SetTexViewerMaps()
augroup END
command -nargs=1 TLook call Tex_Complete(<q-args>, 'tex')
command -nargs=1 TLookAll call Tex_Complete(<q-args>, 'all')
command -nargs=1 TLookBib call Tex_Complete(<q-args>, 'bib')
" }}}
" ==============================================================================
" Main completion function
" ==============================================================================
" Tex_Complete: main function {{{
" Description:
function! Tex_Complete(what, where)
" Get info about current window and position of cursor in file
let s:winnum = winnr()
let s:pos = Tex_GetPos()
" Change to the directory of the file being edited before running all the
" :grep commands. We will change back to the original directory after we
" finish with the grep.
let s:origdir = fnameescape(getcwd())
exe 'cd '.fnameescape(expand('%:p:h'))
unlet! s:type
unlet! s:typeoption
if Tex_GetVarValue('Tex_WriteBeforeCompletion') == 1
wall
endif
if a:where == "text"
" What to do after <F9> depending on context
let s:curline = strpart(getline('.'), 0, col('.'))
let s:prefix = matchstr(s:curline, '.*{\zs.\{-}\(}\|$\)')
" a command is of the type
" \includegraphics[option=value]{file name}
" Thus
" s:curline = '\includegraphics[option=value]{file name'
" (with possibly some junk before \includegraphics)
" from which we need to extract
" s:type = 'includegraphics'
" s:typeoption = '[option=value]'
let pattern = '.*\\\(\w\{-}\)\(\[.\{-}\]\)*{\([^ [\]\t]\+\)\?$'
if s:curline =~ pattern
let s:type = substitute(s:curline, pattern, '\1', 'e')
let s:typeoption = substitute(s:curline, pattern, '\2', 'e')
call Tex_Debug('Tex_Complete: s:type = '.s:type.', typeoption = '.s:typeoption, 'view')
endif
if exists("s:type") && s:type =~ 'ref'
if Tex_GetVarValue('Tex_UseOutlineCompletion') == 1
call Tex_Debug("Tex_Complete: using outline search method", "view")
call Tex_StartOutlineCompletion()
elseif Tex_GetVarValue('Tex_UseSimpleLabelSearch') == 1
call Tex_Debug("Tex_Complete: searching for \\labels with prefix '" . s:prefix . '"in all .tex files in the present directory', "view")
call Tex_Grep('\\\%(nl\)\?label{'.s:prefix, '*.tex')
call <SID>Tex_SetupCWindow()
elseif Tex_GetVarValue('Tex_ProjectSourceFiles') != ''
call Tex_Debug('Tex_Complete: searching for \\labels in all Tex_ProjectSourceFiles', 'view')
exec 'cd '.fnameescape(Tex_GetMainFileName(':p:h'))
call Tex_Grep('\\\%(nl\)\?label{'.s:prefix, Tex_GetVarValue('Tex_ProjectSourceFiles'))
call <SID>Tex_SetupCWindow()
else
call Tex_Debug("Tex_Complete: calling Tex_GrepHelper", "view")
" Clear the quickfix list
cexpr []
call Tex_GrepHelper(s:prefix, 'label')
call <SID>Tex_SetupCWindow()
endif
redraw!
elseif exists("s:type") && s:type =~ '[Cc]ite'
let s:prefix = matchstr(s:prefix, '\([^,]\+,\)*\zs\([^,]\+\)\ze$')
call Tex_Debug(":Tex_Complete: using s:prefix = ".s:prefix, "view")
if Tex_UsePython()
\ && Tex_GetVarValue('Tex_UseCiteCompletionVer2') == 1
exe 'cd '.s:origdir
silent! call Tex_StartCiteCompletion()
call Tex_EchoBibShortcuts()
elseif Tex_GetVarValue('Tex_UseJabref') == 1
exe 'cd '.s:origdir
let g:Remote_WaitingForCite = 1
let citation = input('Enter citation from jabref (<enter> to leave blank): ')
let g:Remote_WaitingForCite = 0
call Tex_CompleteWord(citation, strlen(s:prefix))
else
" Clear the quickfix list
cexpr []
if g:Tex_RememberCiteSearch && exists('s:citeSearchHistory')
call <SID>Tex_SetupCWindow(s:citeSearchHistory)
else
call Tex_GrepHelper(s:prefix, 'bib')
redraw!
call <SID>Tex_SetupCWindow()
endif
if g:Tex_RememberCiteSearch && &ft == 'qf'
let _a = @a
silent! normal! ggVG"ay
let s:citeSearchHistory = @a
let @a = _a
endif
endif
elseif exists("s:type") && s:type =~ 'includegraphics'
call Tex_SetupFileCompletion(
\ '',
\ '^\.\\|\.tex$\\|\.bib$\\|\.bbl$\\|\.zip$\\|\.gz$',
\ 'noext',
\ Tex_GetVarValue('Tex_ImageDir', '.'),
\ Tex_GetVarValue('Tex_ImageDir', ''))
elseif exists("s:type") && s:type == 'bibliography'
call Tex_SetupFileCompletion(
\ '\.b..$',
\ '',
\ 'noext',
\ '.',
\ '')
elseif exists("s:type") && s:type =~ 'include\(only\)\='
call Tex_SetupFileCompletion(
\ '\.t..$',
\ '',
\ 'noext',
\ '.',
\ '')
elseif exists("s:type") && s:type == 'input'
call Tex_SetupFileCompletion(
\ '',
\ '',
\ 'ext',
\ '.',
\ '')
elseif exists('s:type') && exists("g:Tex_completion_".s:type)
call <SID>Tex_CompleteRefCiteCustom('plugin_'.s:type)
else
let s:word = expand('<cword>')
if s:word == ''
call Tex_SwitchToInsertMode()
return
endif
call Tex_Debug("Tex_Grep('\<'".s:word."'\>', '*.tex')", 'view')
call Tex_Grep('\<'.s:word.'\>', '*.tex')
call <SID>Tex_SetupCWindow()
endif
elseif a:where == 'tex'
" Process :TLook command
call Tex_Grep(a:what, "*.tex")
call <SID>Tex_SetupCWindow()
elseif a:where == 'bib'
" Process :TLookBib command
call Tex_Grep(a:what, "*.bib")
call Tex_Grepadd(a:what, "*.bbl")
call <SID>Tex_SetupCWindow()
elseif a:where == 'all'
" Process :TLookAll command
call Tex_Grep(a:what, "*")
call <SID>Tex_SetupCWindow()
endif
endfunction
" }}}
" Tex_CompleteWord: inserts a word at the chosen location {{{
" Description: This function is meant to be called when the user press
" ``<enter>`` in one of the [Error List] windows which shows the list of
" matches. completeword is the rest of the word which needs to be inserted.
" prefixlength characters are deleted before completeword is inserted
function! Tex_CompleteWord(completeword, prefixlength)
" Set cursor to window and position recorded when completion was invoked.
exe s:winnum.' wincmd w'
call Tex_SetPos(s:pos)
" Complete word, check if add closing }
if a:prefixlength > 0
if a:prefixlength > 1
exe 'normal! '.(a:prefixlength-1).'h'
endif
exe 'normal! '.a:prefixlength.'s'.a:completeword."\<Esc>"
else
exe 'normal! a'.a:completeword."\<Esc>"
endif
if getline('.')[col('.')-1] !~ '{' && getline('.')[col('.')] !~ '}'
exe "normal! a}\<Esc>"
endif
" Return to Insert mode
call Tex_SwitchToInsertMode()
endfunction " }}}
" ==============================================================================
" File name completion helper functions
" ==============================================================================
" Tex_SetupFileCompletion: {{{
" Description:
function! Tex_SetupFileCompletion(accept, reject, ext, dir, root)
call FB_SetVar('FB_AllowRegexp', a:accept)
call FB_SetVar('FB_RejectRegexp', a:reject)
call FB_SetVar('FB_CallBackFunction', 'Tex_CompleteFileName')
call FB_SetVar('FB_CallBackFunctionArgs', '"'.a:ext.'", "'.a:root.'"')
call FB_OpenFileBrowser(a:dir)
endfunction " }}}
" Tex_CompleteFileName: {{{
" Description:
function! Tex_CompleteFileName(filename, ext, root)
let root = (a:root == '' ? Tex_GetMainFileName(':p:h') : a:root)
call Tex_Debug('+Tex_CompleteFileName: getting filename '.a:filename, 'view')
if a:ext == 'noext'
let completeword = fnamemodify(a:filename, ':r')
else
let completeword = a:filename
endif
let completeword = Tex_RelPath(completeword, root)
call Tex_Debug(":Tex_CompleteFileName: completing with ".completeword, "view")
call Tex_CompleteWord(completeword, strlen(s:prefix))
endfunction " }}}
" Tex_Common: common part of strings {{{
function! s:Tex_Common(path1, path2)
" Assume the caller handles 'ignorecase'
if a:path1 == a:path2
return a:path1
endif
let n = 0
while a:path1[n] == a:path2[n]
let n = n+1
endwhile
return strpart(a:path1, 0, n)
endfunction " }}}
" Tex_NormalizePath: {{{
" Description:
function! Tex_NormalizePath(path)
let retpath = a:path
if has("win32") || has("win16") || has("dos32") || has("dos16")
let retpath = substitute(retpath, '\\', '/', 'ge')
endif
if isdirectory(retpath) && retpath !~ '/$'
let retpath = retpath.'/'
endif
return retpath
endfunction " }}}
" Tex_RelPath: ultimate file name {{{
function! Tex_RelPath(explfilename,texfilename)
let path1 = Tex_NormalizePath(a:explfilename)
let path2 = Tex_NormalizePath(a:texfilename)
let n = matchend(<SID>Tex_Common(path1, path2), '.*/')
let path1 = strpart(path1, n)
let path2 = strpart(path2, n)
if path2 !~ '/'
let subrelpath = ''
else
let subrelpath = substitute(path2, '[^/]\{-}/', '../', 'ge')
let subrelpath = substitute(subrelpath, '[^/]*$', '', 'ge')
endif
let relpath = subrelpath.path1
return escape(Tex_NormalizePath(relpath), ' ')
endfunction " }}}
" ==============================================================================
" Helper functions for dealing with the 'quickfix' and 'preview' windows.
" ==============================================================================
" Tex_SetupCWindow: set maps and local settings for cwindow {{{
" Description: Set local maps jkJKq<cr> for cwindow. Also size and basic
" settings
"
function! s:Tex_SetupCWindow(...)
call Tex_Debug('+Tex_SetupCWindow', 'view')
cclose
exe 'copen '. g:Tex_ViewerCwindowHeight
" If called with an argument, it means we want to re-use some search
" history from last time. Therefore, just paste it here and proceed.
if a:0 == 1
set modifiable
% d _
silent! 0put!=a:1
$ d _
endif
setlocal nonumber
setlocal nowrap
let s:scrollOffVal = &scrolloff
call <SID>Tex_SyncPreviewWindow()
" If everything went well, then we should be situated in the quickfix
" window. If there were problems, (no matches etc), then we will not be.
" Therefore return.
if &ft != 'qf'
call Tex_Debug('not in quickfix window, quitting', 'view')
return
endif
nnoremap <buffer> <silent> j j:call <SID>Tex_SyncPreviewWindow()<CR>
nnoremap <buffer> <silent> k k:call <SID>Tex_SyncPreviewWindow()<CR>
nnoremap <buffer> <silent> <up> <up>:call <SID>Tex_SyncPreviewWindow()<CR>
nnoremap <buffer> <silent> <down> <down>:call <SID>Tex_SyncPreviewWindow()<CR>
" Change behaviour of <cr> only for 'ref' and 'cite' context.
if exists("s:type") && s:type =~ 'ref\|cite'
exec 'nnoremap <buffer> <silent> <cr> '
\ .':set scrolloff='.s:scrollOffVal.'<CR>'
\ .':cd '.s:origdir.'<CR>'
\ .':silent! call <SID>Tex_CompleteRefCiteCustom("'.s:type.'")<CR>'
else
" In other contexts jump to place described in cwindow and close small
" windows
exec 'nnoremap <buffer> <silent> <cr> '
\ .':set scrolloff='.s:scrollOffVal.'<CR>'
\ .':cd '.s:origdir.'<CR>'
\ .':call <SID>Tex_GoToLocation()<cr>'
endif
" Scroll the preview window while in the quickfix window
nnoremap <buffer> <silent> J :wincmd j<cr><c-e>:wincmd k<cr>
nnoremap <buffer> <silent> K :wincmd j<cr><c-y>:wincmd k<cr>
" Exit the quickfix window without doing anything.
exe 'nnoremap <buffer> <silent> q '
\ .':set scrolloff='.s:scrollOffVal.'<CR>'
\ .':cd '.s:origdir.'<CR>'
\ .':call Tex_CloseSmallWindows()<CR>'
endfunction " }}}
" Tex_CompleteRefCiteCustom: complete/insert name for current item {{{
" Description: handle completion of items depending on current context
"
function! s:Tex_CompleteRefCiteCustom(type)
let prefixlength=strlen(s:prefix)
if a:type =~ 'cite'
" Look for a '\bibitem'
let bibkey = matchstr(getline('.'), '\\bibitem\s*\%(\[.\{-}\]\)\?\s*{\zs.\{-}\ze}')
if bibkey == ""
" Look for a '@article{bibkey,'
let bibkey = matchstr(getline('.'), '@\w*{\zs\w*\ze,')
endif
let completeword = bibkey
elseif a:type =~ 'ref'
let label = matchstr(getline('.'), '\\\%(nl\)\?label{\zs.\{-}\ze}')
let completeword = label
elseif a:type =~ '^plugin_'
let type = substitute(a:type, '^plugin_', '', '')
let completeword = <SID>Tex_DoCompletion(type)
" use old behaviour for plugins because of backward compatibility
let prefixlength=0
endif
call Tex_CloseSmallWindows()
call Tex_Debug(":Tex_CompleteRefCiteCustom: completing with ".completeword, "view")
call Tex_CompleteWord(completeword, prefixlength)
endfunction " }}}
" Tex_SyncPreviewWindow: synchronize quickfix and preview window {{{
" Description: Usually quickfix engine takes care about most of these things
" but we discard it for better control of events.
"
function! s:Tex_SyncPreviewWindow()
call Tex_Debug('+Tex_SyncPreviewWindow', 'view')
let viewfile = matchstr(getline('.'), '^\f*\ze|\d')
let viewline = matchstr(getline('.'), '|\zs\d\+\ze')
" Hilight current line in cwindow
" Normally hightlighting is done with quickfix engine but we use something
" different and have to do it separately
syntax clear
runtime syntax/qf.vim
exe 'syn match vTodo /\%'. line('.') .'l.*/'
hi link vTodo Todo
" Close preview window and open it again in new place
pclose
exe 'silent! bot pedit +'.viewline.' '.viewfile
" Vanilla 6.1 has bug. This additional setting of cwindow height prevents
" resizing of this window
exe g:Tex_ViewerCwindowHeight.' wincmd _'
" Handle situation if there is no item beginning with s:prefix.
" Unfortunately, because we know it late we have to close everything and
" return as in complete process
if v:errmsg =~ 'E32\>'
exe s:winnum.' wincmd w'
call Tex_SetPos(s:pos)
pclose!
cclose
if exists("s:prefix")
echomsg 'No bibkey, label or word beginning with "'.s:prefix.'"'
endif
call Tex_SwitchToInsertMode()
let v:errmsg = ''
call Tex_Debug('Tex_SyncPreviewWindow: got error E32, no matches found, quitting', 'view')
return 0
endif
" Move to preview window. Really is it under cwindow?
wincmd j
" Settings of preview window
exe g:Tex_ViewerPreviewHeight.' wincmd _'
setlocal nofoldenable
if exists('s:type') && s:type =~ 'cite'
" In cite context place bibkey at the top of preview window.
setlocal scrolloff=0
normal! zt
else
" In other contexts in the middle. Highlight this line?
setlocal scrolloff=100
normal! z.
endif
" Return to cwindow
wincmd p
endfunction " }}}
" Tex_CloseSmallWindows: {{{
" Description:
"
function! Tex_CloseSmallWindows()
pclose!
cclose
exe s:winnum.' wincmd w'
call Tex_SetPos(s:pos)
endfunction " }}}
" Tex_GoToLocation: Go to chosen location {{{
" Description: Get number of current line and go to this number
"
function! s:Tex_GoToLocation()
pclose!
let errmsg = v:errmsg
let v:errmsg = ''
exe 'silent! cc ' . line('.')
" If the current buffer is modified, then split
if v:errmsg =~ '^E37:'
split
exe 'silent! cc ' . line('.')
endif
cclose
let v:errmsg = errmsg
endfunction " }}}
" ==============================================================================
" Functions for finding \\label's or \\bibitem's in the main file.
" ==============================================================================
" Tex_GrepHelper: grep main filename for \\bibitem's or \\label's {{{
" Description:
function! Tex_GrepHelper(prefix, what)
let _path = &path
let _suffixesadd = &suffixesadd
let _hidden = &hidden
let mainfname = Tex_GetMainFileName(':p')
" If we are already editing the file, then use :split without any
" arguments so it works even if the file is modified.
" FIXME: If mainfname is being presently edited in another window and
" is 'modified', then the second split statement will not work.
" We will need to travel to that window and back.
if mainfname == expand('%:p')
split
else
exec 'split '.fnameescape(mainfname)
endif
let pos = Tex_GetPos()
if a:what =~ 'bib'
call Tex_ScanFileForCite(a:prefix)
else
call Tex_ScanFileForLabels(a:prefix)
endif
call Tex_SetPos(pos)
q
let &path = _path
let &suffixesadd = _suffixesadd
endfunction " }}}
" Tex_ScanFileForCite: search for \bibitem's in .bib or .bbl or tex files {{{
" Description:
" Search for bibliographic entries in the presently edited file in the
" following manner:
" 1. First see if the file has a \bibliography command.
" If YES:
" 1. If a .bib file corresponding to the \bibliography command can be
" found, then search for '@.*'.a:prefix inside it.
" 2. Otherwise, if a .bbl file corresponding to the \bibliography command
" can be found, then search for '\bibitem'.a:prefix inside it.
" 2. Next see if the file has a \thebibliography environment
" If YES:
" 1. Search for '\bibitem'.a:prefix in this file.
"
" If neither a \bibliography or \begin{thebibliography} are found, then repeat
" steps 1 and 2 for every file \input'ed into this file. Abort any searching
" as soon as the first \bibliography or \begin{thebibliography} is found.
function! Tex_ScanFileForCite(prefix)
call Tex_Debug('+Tex_ScanFileForCite: searching for bibkeys.', 'view')
let bibfiles = Tex_FindBibFiles( "", 0 )
if bibfiles =~ '\S'
let i = 1
while 1
let bibname = Tex_Strntok(bibfiles, "\n", i)
if bibname == ''
break
endif
" first try to find if a .bib file exists. If so do not search in
" the corresponding .bbl file. (because the .bbl file will most
" probably be generated automatically from the .bib file with
" bibtex).
let fname = Tex_FindFile(bibname, '.,'.g:Tex_BIBINPUTS, '.bib')
if fname != ''
call Tex_Debug('finding .bib file ['.bufname('%').']', 'view')
exec 'split '.fnameescape(fname)
call Tex_Grepadd('@.*{'.a:prefix, "%")
q
else
let fname = Tex_FindFile(bibname, '.,'.g:Tex_BIBINPUTS, '.bbl')
if fname != ''
exec 'split '.fnameescape(fname)
call Tex_Debug('finding .bbl file ['.bufname('.').']', 'view')
call Tex_Grepadd('\\bibitem{'.a:prefix, "%")
q
else
" Assume that file is a full path - can also be a remote
" file or url, such as http://..., which is useful for
" use with zotero.
exec 'split "'.fnameescape(bibname).'"'
call Tex_Debug('opening bibliography file', 'view')
call Tex_Grepadd('@.*{'.a:prefix, "%")
q
endif
endif
let i = i + 1
endwhile
return 1
endif
let foundCiteFile = 0
" If we have a thebibliography environment, then again assume that this is
" the only file which defines the bib-keys. And convey this information
" upwards by returning 1.
if search('^\s*\\begin{thebibliography}', 'w')
call Tex_Debug('got a thebibliography environment in '.bufname('%'), 'view')
let foundCiteFile = 1
split
exec 'lcd'.fnameescape(expand('%:p:h'))
call Tex_Debug("Tex_Grepadd('\\bibitem\s*[\[|{]'".a:prefix.", \"%\")", 'view')
call Tex_Grepadd('\\bibitem\s*[\[|{]'.a:prefix, "%")
q
return 1
endif
" If we have not found any \bibliography or \thebibliography environment
" in this file, search for these environments in all the files which this
" file includes.
exec 0
let wrap = 'w'
while search('^\s*\\\(input\|include\)', wrap)
let wrap = 'W'
let filename = matchstr(getline('.'), '\\\(input\|include\){\zs.\{-}\ze}')
let foundfile = Tex_FindFile(filename, '.,'.Tex_GetVarValue('Tex_TEXINPUTS'), '.tex')
if foundfile != ''
exec 'split '.fnameescape(foundfile)
call Tex_Debug('scanning recursively in ['.foundfile.']', 'view')
let foundCiteFile = Tex_ScanFileForCite(a:prefix)
q
endif
if foundCiteFile
return 1
endif
endwhile
return 0
endfunction " }}}
" Tex_ScanFileForLabels: greps present file and included files for \\label's {{{
" Description:
" Grep the presently edited file for \\label's. If the present file \include's
" or \input's other files, then recursively scan those as well, i.e we support
" arbitrary levels of \input'ed-ness.
function! Tex_ScanFileForLabels(prefix)
call Tex_Debug("+Tex_ScanFileForLabels: grepping in file [".bufname('%')."]", "view")
exec 'lcd'.fnameescape(expand('%:p:h'))
call Tex_Grepadd('\\\%(nl\)\?label{'.a:prefix, "%")
" Then recursively grep for all \include'd or \input'ed files.
exec 0
let wrap = 'w'
while search('^\s*\\\(input\|include\)', wrap)
let wrap = 'W'
let filename = matchstr(getline('.'), '\\\(input\|include\){\zs.\{-}\ze}')
let foundfile = Tex_FindFile(filename, '.,'.Tex_GetVarValue('Tex_TEXINPUTS'), '.tex')
if foundfile != ''
exec 'split '.fnameescape(foundfile)
call Tex_Debug('Tex_ScanFileForLabels: scanning recursively in ['.foundfile.']', 'view')
call Tex_ScanFileForLabels(a:prefix)
q
endif
endwhile
endfunction " }}}
" ==============================================================================
" Functions for custom command completion
" ==============================================================================
" Tex_completion_{var}: similar variables can be set in package files {{{
let g:Tex_completion_bibliographystyle = 'abbr,alpha,plain,unsrt'
let g:Tex_completion_addtocontents = 'lof}{,lot}{,toc}{'
let g:Tex_completion_addcontentsline = 'lof}{figure}{,lot}{table}{,toc}{chapter}{,toc}{part}{,'.
\ 'toc}{section}{,toc}{subsection}{,toc}{paragraph}{,'.
\ 'toc}{subparagraph}{'
" }}}
" Tex_PromptForCompletion: prompts for a completion {{{
" Description:
function! s:Tex_PromptForCompletion(texcommand,ask)
let common_completion_prompt =
\ Tex_CreatePrompt(g:Tex_completion_{a:texcommand}, 2, ',') . "\n" .
\ 'Enter number or completion: '
let inp = input(a:ask."\n".common_completion_prompt)
if inp =~ '^[0-9]\+$'
let completion = Tex_Strntok(g:Tex_completion_{a:texcommand}, ',', inp)
else
let completion = inp
endif
return completion
endfunction " }}}
" Tex_DoCompletion: fast insertion of completion {{{
" Description:
"
function! s:Tex_DoCompletion(texcommand)
let completion = <SID>Tex_PromptForCompletion(a:texcommand, 'Choose a completion to insert: ')
if completion != ''
return completion
else
return ''
endif
endfunction " }}}
" ==============================================================================
" Functions for presenting an outlined version for completion
" ==============================================================================
" Tex_StartOutlineCompletion: sets up an outline window {{{
" get the place where this plugin resides for setting cpt and dict options.
" these lines need to be outside the function.
let s:path = expand('<sfile>:p:h')
if Tex_UsePython()
exec g:Tex_PythonCmd . " import sys, re"
exec g:Tex_PythonCmd . " sys.path += [r'". s:path . "']"
exec g:Tex_PythonCmd . " import outline"
endif
function! Tex_StartOutlineCompletion()
let mainfname = Tex_GetMainFileName(':p')
" open the buffer
let _report = &report
let _cmdheight=&cmdheight
let _lazyredraw = &lazyredraw
set report=1000
set cmdheight=1
set lazyredraw
bot split __OUTLINE__
exec Tex_GetVarValue('Tex_OutlineWindowHeight', 15).' wincmd _'
setlocal modifiable
setlocal noswapfile
setlocal buftype=nowrite
setlocal bufhidden=delete
setlocal nowrap
setlocal foldmethod=marker
setlocal foldmarker=<<<,>>>
if Tex_UsePython()
exec g:Tex_PythonCmd . ' retval = outline.main(r"""' . mainfname . '""", """' . s:prefix . '""")'
exec g:Tex_PythonCmd . ' vim.current.buffer[:] = retval.splitlines()'
else
" delete everything in it to the blackhole
% d _
let retval = system(shellescape(s:path.'/outline.py').' '.shellescape(mainfname).' '.shellescape(s:prefix))
0put!=retval
endif
0
call Tex_SetupOutlineSyntax()
exec 'nnoremap <buffer> <silent> <cr> '
\ .':cd '.s:origdir.'<CR>'
\ .':call Tex_FinishOutlineCompletion()<CR>'
exec 'nnoremap <buffer> <silent> q '
\ .':cd '.s:origdir.'<CR>'
\ .':close<CR>'
\ .':call Tex_SwitchToInsertMode()<CR>'
" once the buffer is initialized, go back to the original settings.
setlocal nomodifiable
setlocal nomodified
let &report = _report
let &cmdheight = _cmdheight
let &lazyredraw = _lazyredraw
endfunction " }}}
" Tex_SetupOutlineSyntax: sets up the syntax items for the outline {{{
" Description:
function! Tex_SetupOutlineSyntax()
syn match outlineFileName "<\f\+>$" contained
syn match foldMarkers "<<<\d$" contained
syn match firstSemiColon '^:' contained
syn match firstAngle '^>' contained
syn match sectionNames '\(\d\.\)\+ .*' contains=foldMarkers
syn match previousLine '^:.*' contains=firstSemiColon
syn match labelLine '^>.*' contains=firstAngle,outlineFileName
hi def link outlineFileName Ignore
hi def link foldMarkers Ignore
hi def link firstSemiColon Ignore
hi def link firstAngle Ignore
hi def link sectionNames Type
hi def link previousLine Special
hi def link labelLine Comment
endfunction " }}}
" Tex_FinishOutlineCompletion: inserts the reference back in the text {{{
function! Tex_FinishOutlineCompletion()
if getline('.') !~ '^[>:]'
return
endif
if getline('.') =~ '^>'
let ref_complete = matchstr(getline('.'), '^>\s\+\zs\S\+\ze')
elseif getline('.') =~ '^:'
let ref_complete = matchstr(getline(line('.')-1), '^>\s\+\zs\S\+\ze')
endif
close
call Tex_CompleteWord(ref_complete, strlen(s:prefix))
endfunction " }}}
" ==============================================================================
" Functions for presenting a nicer list of bibtex entries
" ==============================================================================
" Tex_FindBibFiles: finds all .bib files used by the current or main file {{{
" Description:
" a:filename : we look in this file. If this string is empty, look in the currently edited file
" a:recursive: look into included/inputed files
function! Tex_FindBibFiles( currfile, recursive )
call Tex_Debug(":Tex_FindBibFiles: ", "view")
if a:currfile !=# ""
split
exec 'silent! e '.fnameescape(a:currfile)
endif
" No bibfiles found yet
let bibfiles = ''
" Position the cursor at the start of the file
call setpos('.', [0,1,1,0])
while 1
let line_start = search('\%(\\\@<!\%(\\\\\)*%.*\)\@<!\\\%(\%(no\)\?bibliography\|addbibresource\%(\[.*\]\)\?\)\zs{', 'W')
if line_start == 0
break
endif
call Tex_Debug('Tex_FindBibFiles: found bibliography command in '.bufname('%'), 'view')
" extract the bibliography filenames from the command.
" First, look for the closing brace
let line_end = search('\%(\\\@<!\%(\\\\\)*%.*\)\@<!}', 'nWc')
call Tex_Debug(":Tex_FindBibFiles: bib command from line " . line_start . " to line " . line_end, "view")
" Now, extract all these lines
" In the first line, start at the bib-command (current column)
let lines = strpart(getline(line_start), getpos('.')[2])
for line_nr in range(line_start+1, line_end)
" Strip comments and concatenate
let lines .= substitute(getline(line_nr), '\\\@<!\%(\\\\\)*\zs%.*$','','')
endfor
call Tex_Debug(":Tex_FindBibFiles: concatenated bib command: \"" . lines . "\"", "view")
" Finally, extract the file names
let bibnames = matchstr(lines, '^\zs.\{-}\ze}')
let bibnames = substitute(bibnames, '\s', '', 'g')
call Tex_Debug(':Tex_FindBibFiles: trying to search through ['.bibnames.']', 'view')
let i = 1
while 1
let bibname = Tex_Strntok(bibnames, ',', i)
if bibname == ''
break
endif
let fname = Tex_FindFile(bibname, '.,'.g:Tex_BIBINPUTS, '.bib')
if fname != ''
let bibfiles = bibfiles.fname."\n"
endif
let i = i + 1
endwhile
if getline('.') =~# '\%(\\\@<!\%(\\\\\)*%.*\)\@<!\\\%(no\)\?bibliography{'
" Only one \[no]bibliography allowed by LaTeX
break
endif
endwhile
call Tex_Debug(":Tex_FindBibFiles: in this file: [".bibfiles."]", "view")
if a:recursive
" Now, search recursively
" Position the cursor at the start of the file
call setpos('.', [0,1,1,0])
" Accept a match at the very beginning of the file
let flags = 'cW'
while search('^\s*\\\%(input\|include\)', flags)
let flags = 'W'
let filename = matchstr(getline('.'), '^\s*\\\%(input\|include\){\zs.\{-}\ze}')
let foundfile = Tex_FindFile(filename, '.,'.Tex_GetVarValue('Tex_TEXINPUTS'), '.tex')
if foundfile != ''
call Tex_Debug(':Tex_FindBibFiles: scanning recursively in ['.foundfile.']', 'view')
let bibfiles .= Tex_FindBibFiles( foundfile, a:recursive )
endif
endwhile
endif
call Tex_Debug(":Tex_FindBibFiles: with included files: [".bibfiles."]", "view")
if a:currfile !=# ""
q
endif
return bibfiles
endfunction " }}}
" Tex_StartBibtexOutline: sets up an outline window {{{
" get the place where this plugin resides for setting cpt and dict options.
" these lines need to be outside the function.
if Tex_UsePython()
exec g:Tex_PythonCmd . " import sys, re"
exec g:Tex_PythonCmd . " sys.path += [r'". s:path . "']"
exec g:Tex_PythonCmd . " import bibtools"
endif
function! Tex_StartCiteCompletion()
let bibfiles = Tex_FindBibFiles( Tex_GetMainFileName(':p'), 1 )
if bibfiles !~ '\S'
call Tex_Debug(':Tex_StartCiteCompletion: No bibfiles found.', 'view')
call Tex_SwitchToInsertMode()
return
endif
bot split __OUTLINE__
exec Tex_GetVarValue('Tex_OutlineWindowHeight', 15).' wincmd _'
exec g:Tex_PythonCmd . ' Tex_BibFile = bibtools.BibFile(r"""'.bibfiles.'""")'
exec g:Tex_PythonCmd . ' Tex_BibFile.addfilter(r"key ^'.s:prefix.'")'
call Tex_DisplayBibList()
"call Tex_EchoBibShortcuts()
nnoremap <buffer> <Plug>Tex_JumpToNextBibEntry :call search('^\S.*\]$', 'W')<CR>z.:call Tex_EchoBibShortcuts()<CR>
nnoremap <buffer> <Plug>Tex_JumpToPrevBibEntry :call search('^\S.*\]$', 'bW')<CR>z.:call Tex_EchoBibShortcuts()<CR>
nnoremap <buffer> <Plug>Tex_FilterBibEntries :call Tex_HandleBibShortcuts('filter')<CR>
nnoremap <buffer> <Plug>Tex_RemoveBibFilters :call Tex_HandleBibShortcuts('remove_filters')<CR>
nnoremap <buffer> <Plug>Tex_SortBibEntries :call Tex_HandleBibShortcuts('sort')<CR>
nnoremap <buffer> <Plug>Tex_CompleteCiteEntry :call Tex_CompleteCiteEntry()<CR>
nmap <buffer> <silent> n <Plug>Tex_JumpToNextBibEntry
nmap <buffer> <silent> p <Plug>Tex_JumpToPrevBibEntry
nmap <buffer> <silent> f <Plug>Tex_FilterBibEntries
nmap <buffer> <silent> s <Plug>Tex_SortBibEntries
nmap <buffer> <silent> a <Plug>Tex_RemoveBibFilters
nmap <buffer> <silent> q :close<CR>:call Tex_SwitchToInsertMode()<CR>
nmap <buffer> <silent> <CR> <Plug>Tex_CompleteCiteEntry
endfunction " }}}
" Tex_DisplayBibList: displays the list of bibtex entries {{{
" Description:
function! Tex_DisplayBibList()
" open the buffer
let _report = &report
let _cmdheight=&cmdheight
let _lazyredraw = &lazyredraw
set report=1000
set cmdheight=1
set lazyredraw
setlocal modifiable
setlocal noswapfile
setlocal buftype=nowrite
setlocal bufhidden=delete
setlocal nowrap
setlocal foldmethod=marker
setlocal foldmarker=<<<,>>>
" delete everything in it to the blackhole
% d _
exec g:Tex_PythonCmd . ' vim.current.buffer[:] = Tex_BibFile.__str__().splitlines()'
call Tex_SetupBibSyntax()
0
" once the buffer is initialized, go back to the original settings.
setlocal nomodifiable
setlocal nomodified
let &report = _report
let &cmdheight = _cmdheight
let &lazyredraw = _lazyredraw
endfunction " }}}
" Tex_EchoBibShortcuts: echos all the shortcuts in the status line {{{
" Description:
function! Tex_EchoBibShortcuts()
echomsg '(a) all (f) filter (s) sort (n) next (p) previous (q) quit (<CR>) choose'
endfunction " }}}
" Tex_SetupBibSyntax: sets up the syntax items for the outline {{{
" Description:
function! Tex_SetupBibSyntax()
syn match BibTitleHeader "^TI" contained
syn match BibAuthorHeader "^AU" contained
syn match BibLocationHeader "^IN" contained
syn match BibMiscHeader "^MI" contained
syn match BibKeyLine '^\S.*\]$' contains=BibKey
syn match BibTitle "^TI .*" contains=BibTitleHeader
syn match BibAuthor "^AU .*" contains=BibAuthorHeader
syn match BibLocation "^IN .*" contains=BibLocationHeader
syn match BibMisc "^MI .*" contains=BibMiscHeader
hi def link BibTitleHeader Ignore
hi def link BibAuthorHeader Ignore
hi def link BibLocationHeader Ignore
hi def link BibMiscHeader Ignore
hi def link BibKeyLine Visual
hi def link BibTitle Type
hi def link BibAuthor Special
hi def link BibLocation Comment
hi def link BibMisc Comment
endfunction " }}}
" Tex_HandleBibShortcuts: handles user keypresses {{{
" Description:
function! Tex_HandleBibShortcuts(command)
if a:command == 'filter' || a:command == 'sort'
let fieldprompt =
\ "Field acronyms: (`:let g:Tex_EchoBibFields = 0` to avoid this message)\n" .
\ " [t] title [a] author [b] booktitle \n" .
\ " [j] journal [y] year [p] bibtype \n" .
\ " (you can also enter the complete field name) \n"
let fieldprompt = Tex_GetVarValue('Tex_BibFieldPrompt', fieldprompt)
if Tex_GetVarValue('Tex_EchoBibFields', 1) == 1
echo fieldprompt
endif
if a:command == 'filter'
let inp = input('Enter '.a:command.' criterion [field<space>value]: ')
if inp !~ '\v^\S+\s+\S.*'
echohl WarningMsg
echomsg 'Invalid filter specification. Use "field<space>value"'
echohl None
return
endif
else
let inp = input('Enter '.a:command.' criterion [field]: ')
endif
if inp != ''
" If the field is specified as a single character, then replace
" it with the corresponding 'full form'.
if inp =~ '^[a-z]\>'
if Tex_GetVarValue('Tex_BibAcronym_'.inp[0]) != ''
let inp = substitute(inp, '.', Tex_GetVarValue('Tex_BibAcronym_'.inp[0]), '')
elseif fieldprompt =~ '\['.inp[0].'\]'
let full = matchstr(fieldprompt, '\['.inp[0].'\] \zs\w\+\ze')
let inp = substitute(inp, '.', full, '')
endif
endif
call Tex_Debug(":Tex_HandleBibShortcuts: using inp = [".inp."]", "view")
if a:command == 'filter'
exec g:Tex_PythonCmd . ' Tex_BibFile.addfilter(r"'.inp.'")'
elseif a:command == 'sort'
exec g:Tex_PythonCmd . " Tex_BibFile.addsortfield(r\"".inp."\")"
exec g:Tex_PythonCmd . ' Tex_BibFile.sort()'
endif
silent! call Tex_DisplayBibList()
endif
elseif a:command == 'remove_filters'
exec g:Tex_PythonCmd . ' Tex_BibFile.rmfilters()'
exec g:Tex_PythonCmd . ' Tex_BibFile.addfilter(r"key ^'.s:prefix.'")'
call Tex_DisplayBibList()
endif
endfunction " }}}
" Tex_CompleteCiteEntry: completes cite entry {{{
" Description:
function! Tex_CompleteCiteEntry()
normal! $
call search('\[\S\+\]$', 'bc')
if getline('.') !~ '\[\S\+\]$'
return
endif
let ref = matchstr(getline('.'), '\[\zs\S\+\ze\]$')
close
call Tex_Debug(":Tex_CompleteCiteEntry: completing with ".ref, "view")
call Tex_CompleteWord(ref, strlen(s:prefix))
endfunction " }}}
" Tex_SwitchToInsertMode: Switch to insert mode {{{
" Description: This is usually called when completion is finished
function! Tex_SwitchToInsertMode()
call Tex_Debug(":Tex_SwitchToInsertMode: ", "view")
if col('.') == strlen(getline('.'))
startinsert!
else
normal! l
startinsert
endif
endfunction " }}}
com! -nargs=0 TClearCiteHist unlet! s:citeSearchHistory
" vim:fdm=marker:nowrap:noet:ff=unix:ts=4:sw=4
|