1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
" VimTeX - LaTeX plugin for Vim
"
" Maintainer: Karl Yngve Lervåg
" Email: karl.yngve@gmail.com
"
function! vimtex#fold#markers#new(config) abort " {{{1
return extend(deepcopy(s:folder), a:config).init()
endfunction
" }}}1
let s:folder = {
\ 'name' : 'markers',
\ 'open' : '{{{',
\ 'close' : '}}}',
\ 're' : {},
\ 'opened' : 0,
\}
function! s:folder.init() abort dict " {{{1
let self.re.start = '%.*' . self.open
let self.re.end = '%.*' . self.close
let self.re.text = [
\ [self.re.start . '\d\?\s*\zs.*', '% ' . self.open . ' '],
\ ['%\s*\zs.*\ze' . self.open, '% ' . self.open . ' '],
\ ['^.*\ze\s*%', ''],
\]
let self.re.fold_re = escape(self.open . '|' . self.close, '{}%+*.')
return self
endfunction
" }}}1
function! s:folder.level(line, lnum) abort dict " {{{1
let l:start = matchlist(a:line, self.re.start .. '\(\d\?\)')
let l:end = matchlist(a:line, self.re.end .. '\(\d\?\)')
if !empty(l:start)
let self.opened = 1
return empty(l:start[1])
\ ? 'a1'
\ : '>' .. l:start[1]
elseif !empty(l:end)
let self.opened = 0
return empty(l:end[1])
\ ? 's1'
\ : '<' .. l:end[1]
endif
endfunction
" }}}1
function! s:folder.text(line, level) abort dict " {{{1
for [l:re, l:pre] in self.re.text
let l:text = matchstr(a:line, l:re)
if !empty(l:text) | return l:pre . l:text | endif
endfor
return '% ' . self.open . ' ' . getline(v:foldstart + 1)
endfunction
" }}}1
|
