1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
|
" VimTeX - LaTeX plugin for Vim
"
" Maintainer: Karl Yngve Lervåg
" Email: karl.yngve@gmail.com
"
function! vimtex#qf#bibtex#addqflist(blg) abort " {{{1
if get(g:vimtex_quickfix_blgparser, 'disable') | return | endif
try
call s:qf.addqflist(a:blg)
catch /BibTeX Aborted/
endtry
endfunction
" }}}1
let s:qf = {
\ 'file' : '',
\ 'types' : [],
\ 'db_files' : [],
\}
function! s:qf.set_errorformat() abort dict "{{{1
setlocal errorformat=
setlocal errorformat+=%+EName%.%#has\ a\ comma\ at\ the\ end%.%#
setlocal errorformat+=%+EI\ found\ %.%#---while\ reading\ file\ %f
setlocal errorformat+=%+WWarning--empty\ %.%#\ in\ %.%m
setlocal errorformat+=%+WWarning--entry\ type\ for%m
setlocal errorformat+=%-Cwhile\ executing---line\ %l\ of\ file\ %f
setlocal errorformat+=%-C--line\ %l\ of\ file\ %f
setlocal errorformat+=%-G%.%#
endfunction
" }}}1
function! s:qf.addqflist(blg) abort " {{{1
let self.file = a:blg
if empty(self.file) || !filereadable(self.file) | throw 'BibTeX Aborted' | endif
let self.types = map(
\ filter(items(s:), 'v:val[0] =~# ''^type_'''),
\ 'v:val[1]')
let self.db_files = []
call vimtex#qf#u#caddfile(self, fnameescape(self.file))
call self.fix_paths()
endfunction
" }}}1
function! s:qf.fix_paths() abort " {{{1
let l:qflist = getqflist()
try
let l:title = getqflist({'title': 1})
catch /E118/
let l:title = 'VimTeX errors'
endtry
for l:qf in l:qflist
for l:type in self.types
if l:type.fix(self, l:qf) | break | endif
endfor
endfor
call setqflist(l:qflist, 'r')
" Set title if supported
try
call setqflist([], 'r', l:title)
catch
endtry
endfunction
" }}}1
function! s:qf.get_db_files() abort " {{{1
if empty(self.db_files)
let l:out_dir = fnamemodify(
\ b:vimtex.compiler.get_file('log'), ':.:h') . '/'
for l:file in map(
\ filter(readfile(self.file), 'v:val =~# ''Database file #\d:'''),
\ 'matchstr(v:val, '': \zs.*'')')
if filereadable(l:file)
call add(self.db_files, l:file)
elseif filereadable(l:out_dir . l:file)
call add(self.db_files, l:out_dir . l:file)
endif
endfor
endif
return self.db_files
endfunction
" }}}1
function! s:qf.get_key_loc(key) abort " {{{1
for l:file in self.get_db_files()
let l:lines = readfile(l:file)
let l:lnum = 0
for l:line in l:lines
let l:lnum += 1
if l:line =~# '^\s*@\w*{\s*\V' . a:key
return [l:file, l:lnum]
endif
endfor
endfor
return []
endfunction
" }}}1
"
" Parsers for the various warning types
"
let s:type_syn_error = {}
function! s:type_syn_error.fix(ctx, entry) abort " {{{1
if a:entry.text =~# '---line \d\+ of file'
let a:entry.text = split(a:entry.text, '---')[0]
return 1
endif
endfunction
" }}}1
let s:type_empty = {
\ 're' : '\vWarning--empty (.*) in ([^ ;]*)(.*)',
\}
function! s:type_empty.fix(ctx, entry) abort " {{{1
let l:matches = matchlist(a:entry.text, self.re)
if empty(l:matches) | return 0 | endif
let l:type = l:matches[1]
let l:key = l:matches[2]
let l:more = matchstr(l:matches[3], '; \zs.*')
unlet a:entry.bufnr
let a:entry.text = empty(l:more)
\ ? printf('Missing "%s" in "%s"', l:type, l:key)
\ : printf('Missing "%s" in "%s" (%s)', l:type, l:key, l:more)
let l:loc = a:ctx.get_key_loc(l:key)
if !empty(l:loc)
let a:entry.filename = l:loc[0]
let a:entry.lnum = l:loc[1]
endif
return 1
endfunction
" }}}1
let s:type_style_file_defined = {
\ 're' : '\vWarning--entry type for "(\w+)"',
\}
function! s:type_style_file_defined.fix(ctx, entry) abort " {{{1
let l:matches = matchlist(a:entry.text, self.re)
if empty(l:matches) | return 0 | endif
let l:key = l:matches[1]
unlet a:entry.bufnr
let a:entry.text = 'Entry type for "' . l:key . '" isn''t style-file defined'
let l:loc = a:ctx.get_key_loc(l:key)
if !empty(l:loc)
let a:entry.filename = l:loc[0]
let a:entry.lnum = l:loc[1]
endif
return 1
endfunction
" }}}1
let s:type_no_bibstyle = {}
function! s:type_no_bibstyle.fix(ctx, entry) abort " {{{1
if a:entry.text =~# 'I found no \\bibstyle'
let a:entry.text = 'BibTeX found no \bibstyle command (missing \bibliographystyle?)'
let a:entry.filename = b:vimtex.tex
unlet a:entry.bufnr
for [l:file, l:lnum, l:line] in vimtex#parser#tex(b:vimtex.tex)
if l:line =~# g:vimtex#re#not_comment . '\\bibliography'
let a:entry.lnum = l:lnum
let a:entry.filename = l:file
break
endif
endfor
return 1
endif
endfunction
" }}}1
let s:type_fix_bst_path = {}
function! s:type_fix_bst_path.fix(ctx, entry) abort " {{{1
let l:filename = has_key(a:entry, 'filename')
\ ? a:entry.filename
\ : has_key(a:entry, 'bufnr')
\ ? bufname(a:entry.bufnr)
\ : ''
if l:filename =~# '\.bst$' && !filereadable(l:filename)
let l:path = vimtex#kpsewhich#find(l:filename)
if filereadable(l:path)
let a:entry.filename = l:path
unlet! a:entry.bufnr
endif
endif
endfunction
" }}}1
|
