1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
|
/**************************************************************************
* This file is part of the WebIssues Desktop Client program
* Copyright (C) 2006 Michał Męciński
* Copyright (C) 2007-2017 WebIssues Team
*
* This program is free software: you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation, either version 3 of the License, or
* (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
**************************************************************************/
!define SRCDIR "..\.."
!define BUILDDIR "..\..\release"
!define UNINST_KEY "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\WebIssues Client 1.1"
Unicode true
!include "MUI2.nsh"
!ifdef INNER
SetCompress off
OutFile "$%TEMP%\innerinst.exe"
!else
!verbose 4
SetCompressor /SOLID lzma
SetCompressorDictSize 32
OutFile "webissues-${VERSION}-${ARCHITECTURE}.exe"
!endif
!define MULTIUSER_EXECUTIONLEVEL "Highest"
!define MULTIUSER_MUI
!define MULTIUSER_INSTALLMODE_COMMANDLINE
!define MULTIUSER_INSTALLMODE_DEFAULT_REGISTRY_KEY "${UNINST_KEY}"
!define MULTIUSER_INSTALLMODE_DEFAULT_REGISTRY_VALUENAME "UninstallString"
!define MULTIUSER_INSTALLMODE_INSTDIR "WebIssues Client\1.1"
!define MULTIUSER_INSTALLMODE_INSTDIR_REGISTRY_KEY "${UNINST_KEY}"
!define MULTIUSER_INSTALLMODE_INSTDIR_REGISTRY_VALUENAME "InstallLocation"
!if ${ARCHITECTURE} == "win_x64"
!define MULTIUSER_USE_PROGRAMFILES64
!endif
!ifndef INNER
!define MULTIUSER_NOUNINSTALL
!endif
!include "include\multiuser64.nsh"
Name "$(NAME)"
!define MUI_ICON "${SRCDIR}\src\webissues.ico"
!define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\modern-uninstall-blue.ico"
!define MUI_WELCOMEFINISHPAGE_BITMAP "images\wizard.bmp"
!define MUI_UNWELCOMEFINISHPAGE_BITMAP "images\wizard.bmp"
!define MUI_HEADERIMAGE
!define MUI_HEADERIMAGE_BITMAP "images\header.bmp"
!define MUI_HEADERIMAGE_RIGHT
!define MUI_WELCOMEPAGE_TITLE "$(TITLE)"
!define MUI_WELCOMEPAGE_TEXT "$(WELCOME_TEXT)"
!insertmacro MUI_PAGE_WELCOME
!define MUI_LICENSEPAGE_CHECKBOX
!insertmacro MUI_PAGE_LICENSE "${SRCDIR}\COPYING"
!insertmacro MULTIUSER_PAGE_INSTALLMODE
!insertmacro MUI_PAGE_DIRECTORY
ShowInstDetails nevershow
!insertmacro MUI_PAGE_INSTFILES
!define MUI_FINISHPAGE_TITLE "$(TITLE)"
!insertmacro MUI_PAGE_FINISH
!ifdef INNER
!define MUI_WELCOMEPAGE_TITLE "$(TITLE)"
!insertmacro MUI_UNPAGE_WELCOME
!insertmacro MUI_UNPAGE_CONFIRM
ShowUninstDetails nevershow
!insertmacro MUI_UNPAGE_INSTFILES
!define MUI_FINISHPAGE_TITLE "$(TITLE)"
!insertmacro MUI_UNPAGE_FINISH
!endif
!insertmacro MUI_LANGUAGE "English"
!include "languages\webissues_en.nsh"
VIProductVersion "${BUILDVERSION}"
VIAddVersionKey /LANG=${LANG_ENGLISH} "CompanyName" "WebIssues Team"
VIAddVersionKey /LANG=${LANG_ENGLISH} "FileDescription" "WebIssues Desktop Client Setup"
VIAddVersionKey /LANG=${LANG_ENGLISH} "FileVersion" "${VERSION}"
VIAddVersionKey /LANG=${LANG_ENGLISH} "LegalCopyright" "Copyright (C) 2007-2017 WebIssues Team"
VIAddVersionKey /LANG=${LANG_ENGLISH} "OriginalFilename" "webissues-${VERSION}-${ARCHITECTURE}.exe"
VIAddVersionKey /LANG=${LANG_ENGLISH} "ProductName" "WebIssues Desktop Client"
VIAddVersionKey /LANG=${LANG_ENGLISH} "ProductVersion" "${VERSION}"
Function .onInit
!if ${ARCHITECTURE} == "win_x64"
SetRegView 64
!endif
!ifdef INNER
WriteUninstaller "$%TEMP%\uninstall.exe"
Quit
!endif
!insertmacro MULTIUSER_INIT
FunctionEnd
Section
SetOutPath "$INSTDIR"
File "${SRCDIR}\ChangeLog"
File "${SRCDIR}\COPYING"
File "${SRCDIR}\README"
SetOutPath "$INSTDIR\bin"
Delete "$INSTDIR\bin\*.*"
File "${BUILDDIR}\webissues.exe"
File "qt.conf"
File "${QTDIR}\bin\Qt5Core.dll"
File "${QTDIR}\bin\Qt5Gui.dll"
File "${QTDIR}\bin\Qt5Network.dll"
File "${QTDIR}\bin\Qt5OpenGL.dll"
File "${QTDIR}\bin\Qt5PrintSupport.dll"
File "${QTDIR}\bin\Qt5Qml.dll"
File "${QTDIR}\bin\Qt5Quick.dll"
File "${QTDIR}\bin\Qt5Sql.dll"
File "${QTDIR}\bin\Qt5WebKit.dll"
File "${QTDIR}\bin\Qt5WebKitWidgets.dll"
File "${QTDIR}\bin\Qt5Widgets.dll"
File "${QTDIR}\bin\Qt5Xml.dll"
File "${QTDIR}\bin\icudt58.dll"
File "${QTDIR}\bin\icuin58.dll"
File "${QTDIR}\bin\icuuc58.dll"
File "${OPENSSLDIR}\bin\libeay32.dll"
File "${OPENSSLDIR}\bin\ssleay32.dll"
File "${VCRTDIR}\msvcp120.dll"
File "${VCRTDIR}\msvcr120.dll"
SetOutPath "$INSTDIR\plugins\platforms"
File "${QTDIR}\plugins\platforms\qwindows.dll"
SetOutPath "$INSTDIR\plugins\printsupport"
File "${QTDIR}\plugins\printsupport\windowsprintersupport.dll"
SetOutPath "$INSTDIR\doc"
Delete "$INSTDIR\doc\*.*"
File /r /x .svn "${SRCDIR}\doc\*.*"
SetOutPath "$INSTDIR\translations"
Delete "$INSTDIR\translations\*.*"
File "${SRCDIR}\translations\locale.ini"
File "${SRCDIR}\translations\webissues_cs.qm"
File "${SRCDIR}\translations\webissues_de.qm"
File "${SRCDIR}\translations\webissues_es.qm"
File "${SRCDIR}\translations\webissues_fr.qm"
File "${SRCDIR}\translations\webissues_hu.qm"
File "${SRCDIR}\translations\webissues_it.qm"
File "${SRCDIR}\translations\webissues_nl.qm"
File "${SRCDIR}\translations\webissues_pl.qm"
File "${SRCDIR}\translations\webissues_pt_BR.qm"
File "${SRCDIR}\translations\webissues_ru.qm"
File "${SRCDIR}\translations\webissues_zh_CN.qm"
File "${QTDIR}\translations\qt_cs.qm"
File "${QTDIR}\translations\qt_de.qm"
File "${QTDIR}\translations\qt_es.qm"
File "${QTDIR}\translations\qt_fr.qm"
File "${QTDIR}\translations\qt_hu.qm"
File "${QTDIR}\translations\qt_it.qm"
;File "${QTDIR}\translations\qt_nl.qm"
File "${QTDIR}\translations\qt_pl.qm"
File "${QTDIR}\translations\qt_pt.qm"
File "${QTDIR}\translations\qt_ru.qm"
File "${QTDIR}\translations\qt_zh_CN.qm"
File "${QTDIR}\translations\qtbase_cs.qm"
File "${QTDIR}\translations\qtbase_de.qm"
;File "${QTDIR}\translations\qtbase_es.qm"
File "${QTDIR}\translations\qtbase_fr.qm"
File "${QTDIR}\translations\qtbase_hu.qm"
File "${QTDIR}\translations\qtbase_it.qm"
;File "${QTDIR}\translations\qtbase_nl.qm"
File "${QTDIR}\translations\qtbase_pl.qm"
;File "${QTDIR}\translations\qtbase_pt.qm"
File "${QTDIR}\translations\qtbase_ru.qm"
;File "${QTDIR}\translations\qtbase_zh_CN.qm"
SetOutPath "$INSTDIR\bin"
CreateShortCut "$SMPROGRAMS\WebIssues Desktop Client 1.1.lnk" "$INSTDIR\bin\webissues.exe"
CreateShortCut "$DESKTOP\WebIssues Desktop Client 1.1.lnk" "$INSTDIR\bin\webissues.exe"
WriteRegStr SHCTX "${UNINST_KEY}" "DisplayIcon" '"$INSTDIR\bin\webissues.exe"'
WriteRegStr SHCTX "${UNINST_KEY}" "DisplayName" "WebIssues Desktop Client ${VERSION}${SUFFIX}"
WriteRegStr SHCTX "${UNINST_KEY}" "DisplayVersion" "${VERSION}"
WriteRegStr SHCTX "${UNINST_KEY}" "UninstallString" '"$INSTDIR\uninstall.exe" /$MultiUser.InstallMode'
WriteRegStr SHCTX "${UNINST_KEY}" "InstallLocation" "$INSTDIR"
WriteRegStr SHCTX "${UNINST_KEY}" "Publisher" "WebIssues Team"
WriteRegStr SHCTX "${UNINST_KEY}" "HelpLink" "http://webissues.mimec.org"
WriteRegStr SHCTX "${UNINST_KEY}" "URLInfoAbout" "http://webissues.mimec.org"
WriteRegStr SHCTX "${UNINST_KEY}" "URLUpdateInfo" "http://webissues.mimec.org/downloads"
WriteRegDWORD SHCTX "${UNINST_KEY}" "NoModify" 1
WriteRegDWORD SHCTX "${UNINST_KEY}" "NoRepair" 1
!ifndef INNER
SetOutPath "$INSTDIR"
File "$%TEMP%\uninstall.exe"
!endif
SectionEnd
!ifdef INNER
Function un.onInit
!if ${ARCHITECTURE} == "win_x64"
SetRegView 64
!endif
!insertmacro MULTIUSER_UNINIT
FunctionEnd
Section "Uninstall"
DeleteRegKey SHCTX "${UNINST_KEY}"
Delete "$SMPROGRAMS\WebIssues Desktop Client 1.1.lnk"
Delete "$DESKTOP\WebIssues Desktop Client 1.1.lnk"
Delete "$INSTDIR\ChangeLog"
Delete "$INSTDIR\COPYING"
Delete "$INSTDIR\README"
RMDir /r "$INSTDIR\bin"
RMDir /r "$INSTDIR\plugins"
RMDir /r "$INSTDIR\doc"
RMDir /r "$INSTDIR\translations"
Delete "$INSTDIR\uninstall.exe"
RMDir "$INSTDIR"
SectionEnd
!endif
|
