File: xcb_util_common.m4

package info (click to toggle)
xcb-util-image 0.3.9-1
  • links: PTS, VCS
  • area: main
  • in suites: wheezy
  • size: 1,792 kB
  • sloc: sh: 11,088; ansic: 1,933; makefile: 60
file content (44 lines) | stat: -rw-r--r-- 1,544 bytes parent folder | download | duplicates (9)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
# XCB_UTIL_COMMON(xcb-required-version, xcb-proto-required-version)
# -----------------------------------------------------------------
#
# Defines default options for xcb-util libraries.  xorg/util/macros >=
# 1.6.0 is  required for  cross-platform compiler  flags and  to build
# library documentation.
#
AC_DEFUN([XCB_UTIL_COMMON], [
m4_ifndef([AX_COMPARE_VERSION],
          [m4_fatal([could not find AX_COMPARE_VERSION in macros search path])])

AC_REQUIRE([AC_PROG_LIBTOOL])

# Define header files and pkgconfig paths
xcbincludedir='${includedir}/xcb'
AC_SUBST(xcbincludedir)
pkgconfigdir='${libdir}/pkgconfig'
AC_SUBST(pkgconfigdir)

# Check xcb version
PKG_CHECK_MODULES(XCB, xcb >= [$1])

# Check version of xcb-proto that xcb was compiled against
xcbproto_required=[$2]

AC_MSG_CHECKING([whether libxcb was compiled against xcb-proto >= $xcbproto_required])
xcbproto_version=`$PKG_CONFIG --variable=xcbproto_version xcb`
AX_COMPARE_VERSION([$xcbproto_version],[ge],[$xcbproto_required], xcbproto_ok="yes",
                   xcbproto_ok="no")
AC_MSG_RESULT([$xcbproto_ok])

if test $xcbproto_ok = no; then
   AC_MSG_ERROR([libxcb was compiled against xcb-proto $xcbproto_version; it needs to be compiled against version $xcbproto_required or higher])
fi

# Call macros from Xorg util-macros
m4_ifndef([XORG_MACROS_VERSION],
          [m4_fatal([must install xorg-macros 1.6.0 or later before running autoconf/autogen])])

XORG_MACROS_VERSION([1.6.0])
XORG_DEFAULT_OPTIONS
XORG_ENABLE_DEVEL_DOCS
XORG_WITH_DOXYGEN
]) # XCB_UTIL_COMMON