File: sendmail.el

package info (click to toggle)
xemacs21-packages 2009.02.17.dfsg.2-4
  • links: PTS
  • area: main
  • in suites: buster, stretch
  • size: 116,276 kB
  • ctags: 89,333
  • sloc: lisp: 1,232,060; ansic: 16,570; java: 13,514; xml: 6,477; sh: 4,617; makefile: 4,022; asm: 3,007; perl: 840; cpp: 500; ruby: 257; csh: 96; haskell: 93; awk: 49; python: 47
file content (1860 lines) | stat: -rw-r--r-- 68,911 bytes parent folder | download | duplicates (5)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
1001
1002
1003
1004
1005
1006
1007
1008
1009
1010
1011
1012
1013
1014
1015
1016
1017
1018
1019
1020
1021
1022
1023
1024
1025
1026
1027
1028
1029
1030
1031
1032
1033
1034
1035
1036
1037
1038
1039
1040
1041
1042
1043
1044
1045
1046
1047
1048
1049
1050
1051
1052
1053
1054
1055
1056
1057
1058
1059
1060
1061
1062
1063
1064
1065
1066
1067
1068
1069
1070
1071
1072
1073
1074
1075
1076
1077
1078
1079
1080
1081
1082
1083
1084
1085
1086
1087
1088
1089
1090
1091
1092
1093
1094
1095
1096
1097
1098
1099
1100
1101
1102
1103
1104
1105
1106
1107
1108
1109
1110
1111
1112
1113
1114
1115
1116
1117
1118
1119
1120
1121
1122
1123
1124
1125
1126
1127
1128
1129
1130
1131
1132
1133
1134
1135
1136
1137
1138
1139
1140
1141
1142
1143
1144
1145
1146
1147
1148
1149
1150
1151
1152
1153
1154
1155
1156
1157
1158
1159
1160
1161
1162
1163
1164
1165
1166
1167
1168
1169
1170
1171
1172
1173
1174
1175
1176
1177
1178
1179
1180
1181
1182
1183
1184
1185
1186
1187
1188
1189
1190
1191
1192
1193
1194
1195
1196
1197
1198
1199
1200
1201
1202
1203
1204
1205
1206
1207
1208
1209
1210
1211
1212
1213
1214
1215
1216
1217
1218
1219
1220
1221
1222
1223
1224
1225
1226
1227
1228
1229
1230
1231
1232
1233
1234
1235
1236
1237
1238
1239
1240
1241
1242
1243
1244
1245
1246
1247
1248
1249
1250
1251
1252
1253
1254
1255
1256
1257
1258
1259
1260
1261
1262
1263
1264
1265
1266
1267
1268
1269
1270
1271
1272
1273
1274
1275
1276
1277
1278
1279
1280
1281
1282
1283
1284
1285
1286
1287
1288
1289
1290
1291
1292
1293
1294
1295
1296
1297
1298
1299
1300
1301
1302
1303
1304
1305
1306
1307
1308
1309
1310
1311
1312
1313
1314
1315
1316
1317
1318
1319
1320
1321
1322
1323
1324
1325
1326
1327
1328
1329
1330
1331
1332
1333
1334
1335
1336
1337
1338
1339
1340
1341
1342
1343
1344
1345
1346
1347
1348
1349
1350
1351
1352
1353
1354
1355
1356
1357
1358
1359
1360
1361
1362
1363
1364
1365
1366
1367
1368
1369
1370
1371
1372
1373
1374
1375
1376
1377
1378
1379
1380
1381
1382
1383
1384
1385
1386
1387
1388
1389
1390
1391
1392
1393
1394
1395
1396
1397
1398
1399
1400
1401
1402
1403
1404
1405
1406
1407
1408
1409
1410
1411
1412
1413
1414
1415
1416
1417
1418
1419
1420
1421
1422
1423
1424
1425
1426
1427
1428
1429
1430
1431
1432
1433
1434
1435
1436
1437
1438
1439
1440
1441
1442
1443
1444
1445
1446
1447
1448
1449
1450
1451
1452
1453
1454
1455
1456
1457
1458
1459
1460
1461
1462
1463
1464
1465
1466
1467
1468
1469
1470
1471
1472
1473
1474
1475
1476
1477
1478
1479
1480
1481
1482
1483
1484
1485
1486
1487
1488
1489
1490
1491
1492
1493
1494
1495
1496
1497
1498
1499
1500
1501
1502
1503
1504
1505
1506
1507
1508
1509
1510
1511
1512
1513
1514
1515
1516
1517
1518
1519
1520
1521
1522
1523
1524
1525
1526
1527
1528
1529
1530
1531
1532
1533
1534
1535
1536
1537
1538
1539
1540
1541
1542
1543
1544
1545
1546
1547
1548
1549
1550
1551
1552
1553
1554
1555
1556
1557
1558
1559
1560
1561
1562
1563
1564
1565
1566
1567
1568
1569
1570
1571
1572
1573
1574
1575
1576
1577
1578
1579
1580
1581
1582
1583
1584
1585
1586
1587
1588
1589
1590
1591
1592
1593
1594
1595
1596
1597
1598
1599
1600
1601
1602
1603
1604
1605
1606
1607
1608
1609
1610
1611
1612
1613
1614
1615
1616
1617
1618
1619
1620
1621
1622
1623
1624
1625
1626
1627
1628
1629
1630
1631
1632
1633
1634
1635
1636
1637
1638
1639
1640
1641
1642
1643
1644
1645
1646
1647
1648
1649
1650
1651
1652
1653
1654
1655
1656
1657
1658
1659
1660
1661
1662
1663
1664
1665
1666
1667
1668
1669
1670
1671
1672
1673
1674
1675
1676
1677
1678
1679
1680
1681
1682
1683
1684
1685
1686
1687
1688
1689
1690
1691
1692
1693
1694
1695
1696
1697
1698
1699
1700
1701
1702
1703
1704
1705
1706
1707
1708
1709
1710
1711
1712
1713
1714
1715
1716
1717
1718
1719
1720
1721
1722
1723
1724
1725
1726
1727
1728
1729
1730
1731
1732
1733
1734
1735
1736
1737
1738
1739
1740
1741
1742
1743
1744
1745
1746
1747
1748
1749
1750
1751
1752
1753
1754
1755
1756
1757
1758
1759
1760
1761
1762
1763
1764
1765
1766
1767
1768
1769
1770
1771
1772
1773
1774
1775
1776
1777
1778
1779
1780
1781
1782
1783
1784
1785
1786
1787
1788
1789
1790
1791
1792
1793
1794
1795
1796
1797
1798
1799
1800
1801
1802
1803
1804
1805
1806
1807
1808
1809
1810
1811
1812
1813
1814
1815
1816
1817
1818
1819
1820
1821
1822
1823
1824
1825
1826
1827
1828
1829
1830
1831
1832
1833
1834
1835
1836
1837
1838
1839
1840
1841
1842
1843
1844
1845
1846
1847
1848
1849
1850
1851
1852
1853
1854
1855
1856
1857
1858
1859
1860
;;; sendmail.el --- mail sending commands for Emacs.  -*- byte-compile-dynamic: t -*-

;; Copyright (C) 1985, 86, 92, 93, 94, 95, 96, 98, 2000, 2001, 2002, 2003
;;   Free Software Foundation, Inc.

;; Maintainer: FSF
;; Keywords: mail

;; This file is part of XEmacs.

;; XEmacs is free software; you can redistribute it and/or modify it
;; under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; XEmacs is distributed in the hope that it will be useful, but
;; WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;; General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with XEmacs; see the file COPYING.  If not, write to the 
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Synched up with: Emacs 21.3

;;; Commentary:

;; This mode provides mail-sending facilities from within Emacs.  It is
;; documented in the Emacs user's manual.

;;; Code:

(require 'rfc822)

(defgroup sendmail nil
  "Mail sending commands for Emacs."
  :prefix "mail-"
  :group 'mail)

;;;###autoload
(defcustom mail-from-style 'angles "\
*Specifies how \"From:\" fields look.

If `nil', they contain just the return address like:
	king@grassland.com
If `parens', they look like:
	king@grassland.com (Elvis Parsley)
If `angles', they look like:
	Elvis Parsley <king@grassland.com>
If `system-default', allows the mailer to insert its default From field
derived from the envelope-from address.

The email address passed to the mailer to specify the envelope-from
address is controlled by `mail-specify-envelope-from'."
  :type '(choice (const nil) (const parens) (const angles)
		 (const system-default))
  :group 'sendmail)

;;;###autoload
(defcustom mail-specify-envelope-from nil
  "*If non-nil, specify the envelope-from address when sending mail.
The value used to specify it is whatever is found in
`mail-envelope-from', with `user-mail-address' as fallback.

On most systems, specifying the envelope-from address
is a privileged operation."
  :type 'boolean
  :group 'sendmail)

(defcustom mail-envelope-from nil
  "*If non-nil, designate the envelope-from address when sending mail.
If this is nil while `mail-specify-envelope-from' is non-nil, the
content of `user-mail-address' is used."
  :type '(choice (string :tag "From-name")
		 (const :tag "Use From: header from message" header)
		 (const :tag "Use `user-mail-address'" nil))
  :group 'sendmail)

;;;###autoload
(defcustom mail-self-blind nil "\
*Non-nil means insert BCC to self in messages to be sent.
This is done when the message is initialized,
so you can remove or alter the BCC field to override the default."
  :type 'boolean
  :group 'sendmail)

;;;###autoload
(defcustom mail-interactive nil "\
*Non-nil means when sending a message wait for and display errors.
nil means let mailer mail back a message to report errors."
  :type 'boolean
  :group 'sendmail)

;;; XEmacs change: moved rmail-ignored-headers here from rmail.el so that
;;; the value of mail-yank-ignored-headers can default from it.  Both of
;;; these end up in loaddefs.el, but "sendmail" comes before "rmail", so...
;;;
;;;###autoload
(defvar rmail-ignored-headers 
  (purecopy
   (concat
    "^\\("
    (mapconcat
     'identity
     '(;; RFC822
       "Sender:" "References:" "Return-Path:" "Received:"
       "[^: \t\n]*Message-ID:" "Errors-To:"
       ;; RFC977 (NNTP)
       "Path:" "Expires:" "Xref:" "Lines:" "Approved:" "Distribution:"
       ;; SYSV mail:
       "Content-Length:"
       ;; MIME:
       "Mime-Version:" "Content-Type:" "Content-Transfer-Encoding:"
       ;; X400
       "X400-Received:" "X400-Originator:" "X400-Mts-Identifier:"
       "X400-Content-Type:" "Content-Identifier:"
       ;; RMAIL and /usr/ucb/mail:
       "Status:" "Summary-Line:"
       ;; Supercite:
       "X-Attribution:"
       ;; Other random junk occasionally seen:
       "Via:" "Sent-Via:" "Mail-From:" "Origin:" "Comments:" "Originator:"
       "NF-ID:" "NF-From:" "Posting-Version:" "Posted:" "Posted-Date:"
       "Date-Received:" "Relay-Version:" "Article-I\\.D\\.:" "NNTP-Version:"
       "NNTP-Posting-Host:" "X-Mailer:" "X-Newsreader:" "News-Software:"
       "X-Received:" "X-References:" "X-Envelope-To:"
       "X-VMS-" "Remailed-" "X-Plantation:" "X-Windows:" "X-Pgp-"
       )
     "\\|")
    "\\)"))
  "*Gubbish header fields one would rather not see.")


;;;###autoload
(defcustom mail-yank-ignored-headers
  (purecopy
   (concat rmail-ignored-headers "\\|"
	   "^\\("
	   (mapconcat 'identity
		      '(;; RFC822
			"Resent-To:" "Resent-By:" "Resent-CC:"
			"To:" "Subject:" "In-Reply-To:"
			)
		      "\\|")
	   "\\)")) "\
*Delete these headers from old message when it's inserted in a reply."
  :type 'regexp
  :group 'sendmail)

;; Useful to set in site-init.el
;;;###autoload
(defcustom send-mail-function (if (or (eq system-type 'windows-nt)
				      (eq system-type 'cygwin32))
				  ;; there is no sendmail on windows.
				  'smtpmail-send-it
				'sendmail-send-it)
  "Function to call to send the current buffer as mail.
The headers should be delimited by a line which is
not a valid RFC822 header or continuation line,
that match the variable `mail-header-separator'.
This is used by the default mail-sending commands.  See also
`message-send-mail-function' for use with the Message package."
  :type '(radio (function-item sendmail-send-it :tag "Use Sendmail package")
		(function-item smtpmail-send-it :tag "Use SMTPmail package")
		(function-item feedmail-send-it :tag "Use Feedmail package")
		function)
  :group 'sendmail)

;;;###autoload
(defcustom mail-header-separator "--text follows this line--" "\
*Line used to separate headers from text in messages being composed."
  :type 'string
  :group 'sendmail)

;; Set up mail-header-separator for use as a category text property.
(put 'mail-header-separator 'rear-nonsticky '(category))
;;; This was a nice idea, for preventing accidental modification of
;;; the separator.   But I found it also prevented or obstructed
;;; certain deliberate operations, such as copying the separator line
;;; up to the top to send myself a copy of an already sent outgoing message
;;; and other things.  So I turned it off.  --rms.
;;;(put 'mail-header-separator 'read-only t)

;;;###autoload
(defcustom mail-archive-file-name nil "\
*Name of file to write all outgoing messages in, or nil for none.
This can be an inbox file or an Rmail file."
  :type '(choice file (const nil))
  :group 'sendmail)

;;;###autoload
(defcustom mail-default-reply-to nil
  "*Address to insert as default Reply-to field of outgoing messages.
If nil, it will be initialized from the REPLYTO environment variable
when you first send mail."
  :type '(choice (const nil) string)
  :group 'sendmail)

;;;###autoload
(defcustom mail-alias-file nil
  "*If non-nil, the name of a file to use instead of `/usr/lib/aliases'.
This file defines aliases to be expanded by the mailer; this is a different
feature from that of defining aliases in `.mailrc' to be expanded in Emacs.
This variable has no effect unless your system uses sendmail as its mailer."
  :type '(choice (const nil) file)
  :group 'sendmail)

; XEmacs:
(defvaralias 'mail-personal-alias-file 'mail-abbrev-mailrc-file)

(defcustom mail-setup-hook nil
  "Normal hook, run each time a new outgoing mail message is initialized.
The function `mail-setup' runs this hook."
  :type 'hook
  :options '(fortune-to-signature spook mail-abbrevs-setup)
  :group 'sendmail)

;; XEmacs: `mail-aliases' moved to `mail-abbrevs.el'.

(defvar mail-alias-modtime nil
  "The modification time of your mail alias file when it was last examined.")

;;;###autoload
(defcustom mail-yank-prefix "> "		; XEmacs change
  "*Prefix insert on lines of yanked message being replied to.
nil means use indentation."
  :type '(choice (const nil) string)
  :group 'sendmail)

(defcustom mail-indentation-spaces 3
  "*Number of spaces to insert at the beginning of each cited line.
Used by `mail-yank-original' via `mail-indent-citation'."
  :type 'integer
  :group 'sendmail)
(defvar mail-yank-hooks nil
  "Obsolete hook for modifying a citation just inserted in the mail buffer.
Each hook function can find the citation between (point) and (mark t).
And each hook function should leave point and mark around the citation
text as modified.

This is a normal hook, misnamed for historical reasons.
It is semi-obsolete and mail agents should no longer use it.")

(defcustom mail-citation-hook nil
  "*Hook for modifying a citation just inserted in the mail buffer.
Each hook function can find the citation between (point) and (mark t),
and should leave point and mark around the citation text as modified.
The hook functions can find the header of the cited message
in the variable `mail-citation-header', whether or not this is included
in the cited portion of the message.

If this hook is entirely empty (nil), a default action is taken
instead of no action."
  :type 'hook
  :group 'sendmail)

(defvar mail-citation-header nil
  "While running `mail-citation-hook', this variable holds the message header.
This enables the hook functions to see the whole message header
regardless of what part of it (if any) is included in the cited text.")

(defcustom mail-citation-prefix-regexp "[ \t]*[-a-z0-9A-Z]*>+[ \t]*\\|[ \t]*"
  "*Regular expression to match a citation prefix plus whitespace.
It should match whatever sort of citation prefixes you want to handle,
with whitespace before and after; it should also match just whitespace.
The default value matches citations like `foo-bar>' plus whitespace."
  :type 'regexp
  :group 'sendmail)

(defvar mail-abbrevs-loaded nil)
(defvar mail-mode-map nil)

; XEmacs: Removed autoloads of `build-mail-aliases' and `expand-mail-aliases'.
; See `mail-abbrevs.el'.

;;;###autoload
(defcustom mail-signature nil
  "*Text inserted at end of mail buffer when a message is initialized.
If t, it means to insert the contents of the file `mail-signature-file'.
If a string, that string is inserted.
 (To make a proper signature, the string should begin with \\n\\n-- \\n,
  which is the standard way to delimit a signature in a message.)
Otherwise, it should be an expression; it is evaluated
and should insert whatever you want to insert."
  :type '(choice (const :tag "None" nil)
		 (const :tag "Use `.signature' file" t)
		 (string :tag "String to insert")
		 (sexp :tag "Expression to evaluate"))
  :group 'sendmail)
(put 'mail-signature 'risky-local-variable t)

(defcustom mail-signature-file "~/.signature"
  "*File containing the text inserted at end of mail buffer."
  :type 'file
  :group 'sendmail)

;;;###autoload
(defcustom mail-default-directory "~/"
  "*Directory for mail buffers.
Value of `default-directory' for mail buffers.
This directory is used for auto-save files of mail buffers."
  :type '(directory :tag "Directory")
  :group 'sendmail
  :version "21.4")

(defvar mail-reply-action nil)
(defvar mail-send-actions nil
  "A list of actions to be performed upon successful sending of a message.")
(put 'mail-reply-action 'permanent-local t)
(put 'mail-send-actions 'permanent-local t)

(defcustom mail-default-headers nil
  "*A string containing header lines, to be inserted in outgoing messages.
It is inserted before you edit the message,
so you can edit or delete these lines."
  :type '(choice (const nil) string)
  :group 'sendmail)

(defcustom mail-bury-selects-summary t
  "*If non-nil, try to show RMAIL summary buffer after returning from mail.
The functions \\[mail-send-on-exit] or \\[mail-dont-send] select
the RMAIL summary buffer before returning, if it exists and this variable
is non-nil."
  :type 'boolean
  :group 'sendmail)

(defcustom mail-send-nonascii 'mime
  "*Specify whether to allow sending non-ASCII characters in mail.
If t, that means do allow it.  nil means don't allow it.
`query' means ask the user each time.
`mime' means add an appropriate MIME header if none already present.
The default is `mime'.
Including non-ASCII characters in a mail message can be problematical
for the recipient, who may not know how to decode them properly."
  :type '(choice (const t) (const nil) (const query) (const mime))
  :group 'sendmail)

(defcustom mail-use-dsn nil
  "*Ask MTA for notification of failed, delayed or successful delivery.
Note that only some MTAs (currently only recent versions of Sendmail)
support Delivery Status Notification."
  :group 'sendmail
  :type '(repeat (radio (const :tag "Failure" failure)
			(const :tag "Delay" delay)
			(const :tag "Success" success)))
  :version "21.4")

;; Note: could use /usr/ucb/mail instead of sendmail;
;; options -t, and -v if not interactive.
(defvar mail-mailer-swallows-blank-line
  (if (and (string-match "sparc-sun-sunos\\(\\'\\|[^5]\\)" system-configuration)
	   (file-readable-p "/etc/sendmail.cf")
	   (let ((buffer (get-buffer-create " *temp*")))
	     (unwind-protect
		 (save-excursion
		   (set-buffer buffer)
		   (insert-file-contents "/etc/sendmail.cf")
		   (goto-char (point-min))
		   (let ((case-fold-search nil))
		     (re-search-forward "^OR\\>" nil t)))
	       (kill-buffer buffer))))
      ;; According to RFC822, "The field-name must be composed of printable
      ;; ASCII characters (i.e. characters that have decimal values between
      ;; 33 and 126, except colon)", i.e. any chars except ctl chars,
      ;; space, or colon.
      '(looking-at "[ \t]\\|[][!\"#$%&'()*+,-./0-9;<=>?@A-Z\\\\^_`a-z{|}~]+:"))
  "Set this non-nil if the system's mailer runs the header and body together.
\(This problem exists on Sunos 4 when sendmail is run in remote mode.)
The value should be an expression to test whether the problem will
actually occur.")

;; XEmacs: RMS doesn't like this behavior but it seems more logical to
;; me. --ben
(defcustom mail-use-multiple-buffers-p t 
  "Non-nil means `mail' will create a new buffer if one already exists."
  :type 'boolean
  :group 'sendmail)

(defvar mail-mode-syntax-table
  (let ((st (make-syntax-table)))
    ;; define-derived-mode will make it inherit from text-mode-syntax-table.
    (modify-syntax-entry ?% ". " st)
    st)
  "Syntax table used while in `mail-mode'.")

(defvar mail-font-lock-keywords
  (eval-when-compile
    (let* ((cite-chars "[>|}]")
	   (cite-prefix "[A-Za-z]")
	   (cite-suffix (concat cite-prefix "0-9_.@-`'\"")))
      (list '("^\\(To\\|Newsgroups\\):" . font-lock-function-name-face)
	    '("^\\(B?CC\\|Reply-to\\):" . font-lock-keyword-face)
	    '("^\\(Subject:\\)[ \t]*\\(.+\\)?"
	      (1 font-lock-comment-face) (2 font-lock-type-face nil t))
	    ;; Use EVAL to delay in case `mail-header-separator' gets changed.
	    '(eval .
	      (let ((separator (if (zerop (length mail-header-separator))
				   " \\`\\' "
				 (regexp-quote mail-header-separator))))
		(cons (concat "^" separator "$") 'font-lock-warning-face)))
	    ;; Use MATCH-ANCHORED to effectively anchor the regexp left side.
	    `(,cite-chars
	      (,(concat "\\=[ \t]*"
			"\\(\\([" cite-prefix "]+[" cite-suffix "]*\\)?"
			"\\(" cite-chars "[ \t]*\\)\\)+"
			"\\(.*\\)")
	       (beginning-of-line) (end-of-line)
	       (2 font-lock-constant-face nil t)
	       (4 font-lock-comment-face nil t)))
	    '("^\\(X-[A-Za-z0-9-]+\\|In-reply-to\\):.*\\(\n[ \t]+.*\\)*$"
	      . font-lock-string-face))))
  "Additional expressions to highlight in Mail mode.")
(put 'mail-mode 'font-lock-defaults '(mail-font-lock-keywords t t))

;; Courtesy of Per Abrahamsen <abraham@dina.kvl.dk> in an attempt to make
;; Emacs and XEmacs less stupid about default mail addresses.

;; We trust the administrator if he has set `mail-host-address'.
;; We trust the user if he has already customized `user-mail-address'.
(defcustom query-user-mail-address (and (not mail-host-address)
					(not user-mail-address))
  "If non-nil, prompt the user for his mail address."
  :group 'message
  :type 'boolean)

;;;###autoload
(defun user-mail-address ()
  "Query the user for his mail address, unless it is already known."
  (interactive)
  (when (and (not noninteractive) query-user-mail-address)
    (let ((addr (or user-mail-address
		    (concat (user-login-name) "@"
				    (or mail-host-address
					(system-name))))))
      (setq user-mail-address
	    (read-string "Your mail address? " (cons addr 0)))
      (setq query-user-mail-address nil)
      ;; TODO: Run sanity check from Gnus here.
      (when (y-or-n-p "Save address for future sessions? ")
	(put 'user-mail-address 'saved-value
	     (list user-mail-address))
	(put 'query-user-mail-address 'saved-value '(nil))
        (require 'cus-edit)
	(custom-save-all))))
  (if user-mail-address
      user-mail-address
    (setq user-mail-address (concat (user-login-name) "@"
                                    (or mail-host-address
                                        (system-name))))))

(defun sendmail-sync-aliases ()
  (let ((modtime (nth 5 (file-attributes (mail-abbrev-mailrc-file))))) ; XEmacs
    (or (equal mail-alias-modtime modtime)
	(setq mail-alias-modtime modtime
	      mail-aliases t))))

(defun mail-setup (to subject in-reply-to cc replybuffer actions)
  (require 'mail-abbrevs)
  (or mail-default-reply-to
      (setq mail-default-reply-to (getenv "REPLYTO")))
  (sendmail-sync-aliases)
  (if (eq mail-aliases t)
      (progn
	(setq mail-aliases nil)
	;; XEmacs: call to `build-mail-alias' removed, done by
	;; `mail-aliases-setup' below.
	))
  ;; Don't leave this around from a previous message.
  (kill-local-variable 'buffer-file-coding-system)
  ;; This doesn't work for enable-multibyte-characters.
  ;; (kill-local-variable 'enable-multibyte-characters)
  ;; XEmacs, don't (set-buffer-multibyte default-enable-multibyte-characters)
  (if (and (boundp 'current-input-method) current-input-method) ;; XEmacs
      (inactivate-input-method))
  (setq mail-send-actions actions)
  (mail-aliases-setup) ;; XEmacs
  (setq mail-reply-action replybuffer)
  (goto-char (point-min))
  (insert "To: ")
  (save-excursion
    (if to
        ;; Here removed code to extract names from within <...>
        ;; on the assumption that mail-strip-quoted-names
        ;; has been called and has done so.
	(let ((fill-prefix "\t")
              (address-start (point)))
	  (insert to "\n")
          (fill-region-as-paragraph address-start (point-max))
	  (goto-char (point-max))
	  (unless (bolp)
	    (newline)))
      (newline))
    (if cc
	(let ((fill-prefix "\t")
	      (address-start (progn (insert "CC: ") (point))))
	  (insert cc "\n")
	  (fill-region-as-paragraph address-start (point-max))
	  (goto-char (point-max))
	  (unless (bolp)
	    (newline))))
    (if in-reply-to
        (let ((fill-prefix "\t")
	      (fill-column 78)
	      (address-start (point)))
	  (insert "In-reply-to: " in-reply-to "\n")
	  (fill-region-as-paragraph address-start (point-max))
	  (goto-char (point-max))
	  (unless (bolp)
	    (newline))))
    (insert "Subject: " (or subject "") "\n")
    (if mail-default-headers
	(insert mail-default-headers))
    (if mail-default-reply-to
	(insert "Reply-to: " mail-default-reply-to "\n"))
    (if mail-self-blind
	(insert "BCC: " (user-login-name) "\n")) ;; XEmacs
    (if mail-archive-file-name
	(insert "FCC: " mail-archive-file-name "\n"))
    (put-text-property (point)
		       (progn
			 (insert mail-header-separator "\n")
			 (1- (point)))
		       'category 'mail-header-separator)
    ;; Insert the signature.  But remember the beginning of the message.
    (if to (setq to (point)))
    (cond ((eq mail-signature t)
	   (if (file-exists-p mail-signature-file)
	       (progn
		 (insert "\n\n-- \n")
		 (insert-file-contents mail-signature-file))))
	  ((stringp mail-signature)
	   (insert mail-signature))
	  (t
	   (eval mail-signature)))
    (goto-char (point-max))
    (or (bolp) (newline)))
  (if to (goto-char to))
  (or to subject in-reply-to
      (set-buffer-modified-p nil))
  (run-hooks 'mail-setup-hook))

(defcustom mail-mode-hook nil
  "Hook run by Mail mode."
  :group 'sendmail
  :type 'hook
  :options '(footnote-mode))

(defvar mail-mode-abbrev-table text-mode-abbrev-table)
;;;###autoload
(define-derived-mode mail-mode text-mode "Mail"
  "Major mode for editing mail to be sent.
Like Text Mode but with these additional commands:
\\[mail-send]  mail-send (send the message)    \\[mail-send-and-exit]  mail-send-and-exit
Here are commands that move to a header field (and create it if there isn't):
	 \\[mail-to]  move to To:	\\[mail-subject]  move to Subject:
	 \\[mail-cc]  move to CC:	\\[mail-bcc]  move to BCC:
	 \\[mail-fcc]  move to FCC:      \\[mail-reply-to] move to Reply-To:
\\[mail-text]  mail-text (move to beginning of message text).
\\[mail-signature]  mail-signature (insert `mail-signature-file' file).
\\[mail-yank-original]  mail-yank-original (insert current message, in Rmail).
\\[mail-fill-yanked-message]  mail-fill-yanked-message (fill what was yanked).
\\[mail-sent-via]  mail-sent-via (add a Sent-via field for each To or CC).
Turning on Mail mode runs the normal hooks `text-mode-hook' and
`mail-mode-hook' (in that order)."
  (make-local-variable 'mail-reply-action)
  (make-local-variable 'mail-send-actions)
  (setq buffer-offer-save t)
  (setq mail-reply-action nil)
  (make-local-variable 'mail-send-actions)
  (make-local-variable 'paragraph-separate)
  (make-local-variable 'paragraph-start)
  (make-local-variable 'normal-auto-fill-function)
  (setq normal-auto-fill-function 'mail-mode-auto-fill)
  (make-local-variable 'fill-paragraph-function)
  (setq fill-paragraph-function 'mail-mode-fill-paragraph)
  ;; Allow using comment commands to add/remove quoting (this only does
  ;; anything if mail-yank-prefix is set to a non-nil value).
  (set (make-local-variable 'comment-start) mail-yank-prefix)
  (make-local-variable 'adaptive-fill-regexp)
  (setq adaptive-fill-regexp
	(concat "[ \t]*[-[A-Za-z0-9]]+>+[ \t]*\\|"
		adaptive-fill-regexp))
  (make-local-variable 'adaptive-fill-first-line-regexp)
  (setq adaptive-fill-first-line-regexp
	(concat "[ \t]*[-[A-Za-z0-9]]*>+[ \t]*\\|"
		adaptive-fill-first-line-regexp))
  (turn-on-auto-fill)	; XEmacs - maybe filladapt should be default, too.
  ;; `-- ' precedes the signature.  `-----' appears at the start of the
  ;; lines that delimit forwarded messages.
  ;; Lines containing just >= 3 dashes, perhaps after whitespace,
  ;; are also sometimes used and should be separators.
  (setq paragraph-start (concat (regexp-quote mail-header-separator)
				"$\\|\t*\\([-|#;>* ]\\|(?[0-9]+[.)]\\)+$"
				"\\|[ \t]*[[A-Za-z0-9]]*>+[ \t]*$\\|[ \t]*$\\|"
				"-- $\\|---+$\\|"
				page-delimiter))
  (setq paragraph-separate paragraph-start)
  (if (featurep 'menubar)
      (easy-menu-add mail-menubar-menu)))

(defun mail-header-end ()
  "Return the buffer location of the end of headers, as a number."
  (save-restriction
    (widen)
    (save-excursion
      (rfc822-goto-eoh)
      (point))))

(defun mail-text-start ()
  "Return the buffer location of the start of text, as a number."
  (save-restriction
    (widen)
    (save-excursion
      (rfc822-goto-eoh)
      (forward-line 1)
      (point))))

(defun mail-sendmail-delimit-header ()
  "Set up whatever header delimiter convention sendmail will use.
Concretely: replace the first blank line in the header with the separator."
  (rfc822-goto-eoh)
  (insert mail-header-separator)
  (point))

(defun mail-sendmail-undelimit-header ()
  "Remove header separator to put the message in correct form for sendmail.
Leave point at the start of the delimiter line."
  (rfc822-goto-eoh)
  (delete-region (point) (progn (end-of-line) (point))))

(defun mail-mode-auto-fill ()
  "Carry out Auto Fill for Mail mode.
If within the headers, this makes the new lines into continuation lines."
  (if (< (point) (mail-header-end))
      (let ((old-line-start (save-excursion (beginning-of-line) (point))))
	(if (do-auto-fill)
	    (save-excursion
	      (beginning-of-line)
	      (while (not (eq (point) old-line-start))
		;; Use insert-before-markers in case we're inserting
		;; before the saved value of point (which is common).
		(insert-before-markers "   ")
		(forward-line -1))
	      t)))
    (do-auto-fill)))

(defun mail-mode-fill-paragraph (arg)
  ;; Do something special only if within the headers.
  (if (< (point) (mail-header-end))
      (let (beg end fieldname)
	(when (prog1 (re-search-backward "^[-a-zA-Z]+:" nil 'yes)
		(setq beg (point)))
	(setq fieldname
		(downcase (buffer-substring beg (1- (match-end 0))))))
	(forward-line 1)
	;; Find continuation lines and get rid of their continuation markers.
	(while (looking-at "[ \t]")
	  (delete-horizontal-space)
	  (forward-line 1))
	(setq end (point-marker))
	(goto-char beg)
	;; If this field contains addresses,
	;; make sure we can fill after each address.
	(if (member fieldname
		    '("to" "cc" "bcc" "from" "reply-to"
		      "resent-to" "resent-cc" "resent-bcc"
		      "resent-from" "resent-reply-to"))
	    (while (search-forward "," end t)
	      (or (looking-at "[ \t]")
		  (insert " "))))
	(fill-region-as-paragraph beg end)
	;; Mark all lines except the first as continuations.
	(goto-char beg)
	(forward-line 1)
	(while (< (point) end)
	  (insert "  ")
	  (forward-line 1))
	(move-marker end nil)
	t)))

;;; Set up keymap.

(if mail-mode-map
    nil
  (setq mail-mode-map (make-sparse-keymap))
  ;; XEmacs: (define-key mail-mode-map "\M-\t" 'mail-complete)
  (define-key mail-mode-map "\C-c?" 'describe-mode)
  (define-key mail-mode-map "\C-c\C-f\C-t" 'mail-to)
  (define-key mail-mode-map "\C-c\C-f\C-b" 'mail-bcc)
  (define-key mail-mode-map "\C-c\C-f\C-f" 'mail-fcc)
  (define-key mail-mode-map "\C-c\C-f\C-c" 'mail-cc)
  (define-key mail-mode-map "\C-c\C-f\C-s" 'mail-subject)
  (define-key mail-mode-map "\C-c\C-f\C-r" 'mail-reply-to)
  (define-key mail-mode-map "\C-c\C-t" 'mail-text)
  (define-key mail-mode-map "\C-c\C-y" 'mail-yank-original)
  (define-key mail-mode-map "\C-c\C-r" 'mail-yank-region)
  ;; XEmacs: (define-key mail-mode-map [remap split-line] 'mail-split-line)
  (define-key mail-mode-map "\C-c\C-q" 'mail-fill-yanked-message)
  (define-key mail-mode-map "\C-c\C-w" 'mail-signature)
  ;; XEmacs: (define-key mail-mode-map "\C-c\C-v" 'mail-sent-via)
  (define-key mail-mode-map "\C-c\C-c" 'mail-send-and-exit)
  (define-key mail-mode-map "\C-c\C-s" 'mail-send)
  (define-key mail-mode-map "\C-c\C-i" 'mail-attach-file))

;;; mail-mode popup menu

(defvar mail-menubar-menu
  (purecopy
   '("Mail"
     "Sending Mail:"
     "----"
     ["Send and Exit"		mail-send-and-exit		t]
     ["Send Mail"		mail-send			t]
     "----"
     "Navigation:"
     "----"
     ["To:"			mail-to				t]
     ["Subject:"		mail-subject			t]
     ["CC:"			mail-cc				t]
     ["FCC:"			mail-fcc			t]
     ["BCC:"			mail-bcc			t]
     ["Reply-To:"		mail-reply-to			t]
     ;; XEmacs   ["Sent Via:"		mail-sent-via			t]
     ["Text"			mail-text			t]
     "----"
     "Miscellaneous Commands:"
     "----"
     ["Expand Aliases"          expand-mail-aliases             t]
     ["Yank Original"		mail-yank-original
      (not (null mail-reply-action))]
     ["Fill Yanked Message"	mail-fill-yanked-message
      (save-excursion
	(goto-char (point-min))
	(and (search-forward (concat "\n" mail-header-separator
				     "\n") nil t)
	     (not (looking-at "[ \t\n]*\\'"))))]
     ["Insert Signature"	mail-signature
      (and (stringp mail-signature-file)
	   (file-exists-p mail-signature-file))]
     ["Insert File..."		insert-file			t]
     ["Insert Buffer..."	insert-buffer			t]
     "----"
     ["Cancel"			mail-dont-send			t]
     ))
   "Menubar menu for `mail-mode'.")

(defvar mail-popup-menu
  (purecopy
   (cons "Sendmail Commands"
	 (cdr mail-menubar-menu)))
  "Menubar menu for `mail-mode'.")


;; User-level commands for sending.

(defun mail-send-and-exit (arg)
  "Send message like `mail-send', then, if no errors, exit from mail buffer.
Prefix arg means don't delete this window."
  (interactive "P")
  (mail-send)
  (mail-bury arg))

(defun mail-dont-send (arg)
  "Don't send the message you have been editing.
Prefix arg means don't delete this window."
  (interactive "P")
  (mail-bury arg))

(defun mail-bury (arg)
  "Bury this mail buffer."
  (let ((newbuf (other-buffer (current-buffer))))
    (bury-buffer (current-buffer))
    (if (and (or (window-dedicated-p (frame-selected-window))
		 (cdr (assq 'mail-dedicated-frame (frame-parameters))))
	     (not (null (delq (selected-frame) (visible-frame-list)))))
	(delete-frame (selected-frame))
      (let (rmail-flag summary-buffer)
	(and (not arg)
	     (not (one-window-p))
	     (save-excursion
	       (set-buffer (window-buffer (next-window (selected-window) 'not)))
	       (setq rmail-flag (eq major-mode 'rmail-mode))
	       (setq summary-buffer
		     (and mail-bury-selects-summary
			  (boundp 'rmail-summary-buffer)
			  rmail-summary-buffer
			  (buffer-name rmail-summary-buffer)
			  (not (get-buffer-window rmail-summary-buffer))
			  rmail-summary-buffer))))
	(if rmail-flag
	    ;; If the Rmail buffer has a summary, show that.
	    (if summary-buffer (switch-to-buffer summary-buffer)
	      (delete-window))
	  (switch-to-buffer newbuf))))))

(defcustom mail-send-hook nil
  "Hook run just before sending mail with `mail-send'."
  :type 'hook
  :options '(flyspell-mode-off)
  :group 'sendmail)

(defun mail-send ()
  "Send the message in the current buffer.
If `mail-interactive' is non-nil, wait for success indication
or error messages, and inform user.
Otherwise any failure is reported in a message back to
the user from the mailer."
  (interactive)
  (if (if buffer-file-name
        (y-or-n-p "Send buffer contents as mail message? ")
      (or (buffer-modified-p)
          (y-or-n-p "Message already sent; resend? ")))
      (let ((inhibit-read-only t)
	    (opoint (point)))
	;; Complain about any invalid line.
	(goto-char (point-min))
	(while (< (point) (mail-header-end))
	  (unless (looking-at "[ \t]\\|.*:\\|$")
	    (push-mark opoint)
	    (error "Invalid header line (maybe a continuation line lacks initial whitespace)"))
	  (forward-line 1))
	(goto-char opoint)
	(if (interactive-p) (expand-abbrev))  ;; XEmacs: for mail-abbrevs
	(run-hooks 'mail-send-hook)
	(message "Sending...")
	(funcall send-mail-function)
	;; Now perform actions on successful sending.
	(while mail-send-actions
	  (condition-case nil
	      (apply (car (car mail-send-actions))
		     (cdr (car mail-send-actions)))
	    (error))
	  (setq mail-send-actions (cdr mail-send-actions)))
	(message "Sending...done")

        ;; If buffer has no file, mark it as unmodified and delete autosave.
        (cond ((or (not buffer-file-name)
                   (not (buffer-modified-p)))
               (set-buffer-modified-p nil)
               (delete-auto-save-file-if-necessary t))
              ((or noninteractive
                   (y-or-n-p (format "Save file %s? " buffer-file-name)))
               (save-buffer))))))

(defun mail-envelope-from ()
  "Return the envelope mail address to use when sending mail.
This function uses `mail-envelope-from'."
  (if (eq mail-envelope-from 'header)
      (nth 1 (mail-extract-address-components
 	      (mail-fetch-field "From")))
    mail-envelope-from))

;; This does the real work of sending a message via sendmail.
;; It is called via the variable send-mail-function.

(defun sendmail-send-it ()
  "Send the current mail buffer using the Sendmail package.
This is a suitable value for `send-mail-function'.  It sends using the
external program defined by `sendmail-program'."
  (require 'mail-utils)
  (let ((errbuf (if mail-interactive
		    (generate-new-buffer " sendmail errors")
		  0))
	(tembuf (generate-new-buffer " sendmail temp"))
	;; XEmacs: comment out
;	(multibyte enable-multibyte-characters)
	(case-fold-search nil)
	;; XEmacs: comment out
;	(selected-coding (select-message-coding-system))
;;;	resend-to-addresses
	delimline
	fcc-was-found
	(mailbuf (current-buffer))
	(program (if (boundp 'sendmail-program)
		     sendmail-program
		   "/usr/lib/sendmail"))
	;; Examine these variables now, so that
	;; local binding in the mail buffer will take effect.
	(envelope-from
	 (and mail-specify-envelope-from
	      ;; XEmacs: use (user-mail-address)
	      (or (mail-envelope-from) (user-mail-address)))))
    (unwind-protect
	(save-excursion
	  (set-buffer tembuf)
	  (erase-buffer)
	  ;; XEmacs: commented out
; 	  (unless multibyte
; 	    (set-buffer-multibyte nil))
	  (insert-buffer-substring mailbuf)
	  (goto-char (point-max))
	  ;; require one newline at the end.
	  (or (= (preceding-char) ?\n)
	      (insert ?\n))
	  ;; Change header-delimiter to be what sendmail expects.
	  (goto-char (mail-header-end))
	  (delete-region (point) (progn (end-of-line) (point)))
	  (setq delimline (point-marker))
;XEmacs removed.  See second paragraph in `mail-abbrevs.el' for rationale.
;	  (sendmail-sync-aliases)
;	  (if mail-aliases
;	      (expand-mail-aliases (point-min) delimline))
	  (goto-char (point-min))
	  ;; Ignore any blank lines in the header
	  (while (and (re-search-forward "\n\n\n*" delimline t)
		      (< (point) delimline))
	    (replace-match "\n"))
	  (goto-char (point-min))
	  (let ((case-fold-search t))
;;;	    (goto-char (point-min))
;;;	    (while (re-search-forward "^Resent-\\(to\\|cc\\|bcc\\):" delimline t)
;;;	      (setq resend-to-addresses
;;;		    (save-restriction
;;;		      (narrow-to-region (point)
;;;					(save-excursion
;;;					  (forward-line 1)
;;;					  (while (looking-at "^[ \t]")
;;;					    (forward-line 1))
;;;					  (point)))
;;;		      (append (mail-parse-comma-list)
;;;			      resend-to-addresses)))
;;;	      ;; Delete Resent-BCC ourselves
;;;	      (if (save-excursion (beginning-of-line)
;;;				  (looking-at "resent-bcc"))
;;;		  (delete-region (save-excursion (beginning-of-line) (point))
;;;				 (save-excursion (end-of-line) (1+ (point))))))
;;; Apparently this causes a duplicate Sender.
;;;	    ;; If the From is different than current user, insert Sender.
;;;	    (goto-char (point-min))
;;;	    (and (re-search-forward "^From:"  delimline t)
;;;		 (progn
;;;		   (require 'mail-utils)
;;;		   (not (string-equal
;;;			 (mail-strip-quoted-names
;;;			  (save-restriction
;;;			    (narrow-to-region (point-min) delimline)
;;;			    (mail-fetch-field "From")))
;;;			 (user-login-name))))
;;;		 (progn
;;;		   (forward-line 1)
;;;		   (insert "Sender: " (user-login-name) "\n")))
	    ;; Don't send out a blank subject line
	    (goto-char (point-min))
	    (if (re-search-forward "^Subject:\\([ \t]*\n\\)+\\b" delimline t)
		(replace-match "")
	      ;; This one matches a Subject just before the header delimiter.
	      (if (and (re-search-forward "^Subject:\\([ \t]*\n\\)+" delimline t)
		       (= (match-end 0) delimline))
		  (replace-match "")))
	    ;; Put the "From:" field in unless for some odd reason
	    ;; they put one in themselves.
	    (goto-char (point-min))
	    (if (not (re-search-forward "^From:" delimline t))
		(let* ((login (user-mail-address))
		       (fullname (user-full-name)))
		  (cond ((eq mail-from-style 'angles)
			 (insert "From: " fullname)
			 (let ((fullname-start (+ (point-min) 6))
			       (fullname-end (point-marker)))
			   (goto-char fullname-start)
			   ;; Look for a character that cannot appear unquoted
			   ;; according to RFC 822.
			   (if (re-search-forward "[^- !#-'*+/-9=?A-Z^-~]"
						  fullname-end 1)
			       (progn
				 ;; Quote fullname, escaping specials.
				 (goto-char fullname-start)
				 (insert "\"")
				 (while (re-search-forward "[\"\\]"
							   fullname-end 1)
				   (replace-match "\\\\\\&" t))
				 (insert "\""))))
			 (insert " <" login ">\n"))
			((eq mail-from-style 'parens)
			 (insert "From: " login " (")
			 (let ((fullname-start (point)))
			   (insert fullname)
			   (let ((fullname-end (point-marker)))
			     (goto-char fullname-start)
			     ;; RFC 822 says \ and nonmatching parentheses
			     ;; must be escaped in comments.
			     ;; Escape every instance of ()\ ...
			     (while (re-search-forward "[()\\]" fullname-end 1)
			       (replace-match "\\\\\\&" t))
			     ;; ... then undo escaping of matching parentheses,
			     ;; including matching nested parentheses.
			     (goto-char fullname-start)
			     (while (re-search-forward
				     "\\(\\=\\|[^\\]\\(\\\\\\\\\\)*\\)\\\\(\\(\\([^\\]\\|\\\\\\\\\\)*\\)\\\\)"
				     fullname-end 1)
			       (replace-match "\\1(\\3)" t)
			       (goto-char fullname-start))))
			 (insert ")\n"))
			((null mail-from-style)
			 (insert "From: " login "\n"))
			((eq mail-from-style 'system-default)
			 nil)
			(t (error "Invalid value for `mail-from-style'")))))
	    ;; XEmacs: commented out #### why?
; 	    ;; Possibly add a MIME header for the current coding system
; 	    (let (charset)
; 	      (goto-char (point-min))
; 	      (and (eq mail-send-nonascii 'mime)
; 		   (not (re-search-forward "^MIME-version:" delimline t))
; 		   (progn (skip-chars-forward "\0-\177")
; 			  (/= (point) (point-max)))
; 		   selected-coding
; 		   (setq charset
; 			 (coding-system-get selected-coding 'mime-charset))
; 		   (goto-char delimline)
; 		   (insert "MIME-version: 1.0\n"
; 			   "Content-type: text/plain; charset="
; 			   (symbol-name charset) "\n"
; 			   "Content-Transfer-Encoding: 8bit\n")))
	    ;; Insert an extra newline if we need it to work around
	    ;; Sun's bug that swallows newlines.
	    (goto-char (1+ delimline))
	    (if (eval mail-mailer-swallows-blank-line)
		(newline))
	    ;; Find and handle any FCC fields.
	    (goto-char (point-min))
	    (if (re-search-forward "^FCC:" delimline t)
		(progn
		  (setq fcc-was-found t)
		  (mail-do-fcc delimline)))
	    (if mail-interactive
		(save-excursion
		  (set-buffer errbuf)
		  (erase-buffer))))

	  ;; XEmacs change
	  (mail-check-safe-charset)

	  (goto-char (point-min))
	  (if (let ((case-fold-search t))
		(re-search-forward "^To:\\|^cc:\\|^bcc:\\|^resent-to:\
\\|^resent-cc:\\|^resent-bcc:"
				   delimline t))
	      (let* ((default-directory "/")
		     ;; XEmacs: changed to no-conversion-unix
		     (coding-system-for-write 'no-conversion-unix)
		     (args
		      (append (list (point-min) (point-max)
				    program
				    nil errbuf nil "-oi")
			      ;; Always specify who from,
			      ;; since some systems have
			      ;; broken sendmails.
			      (and envelope-from
				   (list "-f" envelope-from))
;;; 			      ;; Don't say "from root" if running under su.
;;; 			      (and (equal (user-real-login-name) "root")
;;; 				   (list "-f" (user-login-name)))
			      (and mail-alias-file
				   (list (concat "-oA" mail-alias-file)))
			      (if mail-interactive
				  ;; These mean "report errors to terminal"
				  ;; and "deliver interactively"
				  '("-oep" "-odi")
				;; These mean "report errors by mail"
				;; and "deliver in background".
				'("-oem" "-odb"))
;;;			      ;; Get the addresses from the message
;;;			      ;; unless this is a resend.
;;;			      ;; We must not do that for a resend
;;;			      ;; because we would find the original addresses.
;;;			      ;; For a resend, include the specific addresses.
;;;			      (or resend-to-addresses
				  '("-t")
;;;				  )
			      (if mail-use-dsn
				  (list "-N" (mapconcat 'symbol-name
							mail-use-dsn ",")))
			      )
		      )
		     (exit-value (apply 'call-process-region args)))
		(or (null exit-value) (zerop exit-value)
		    (error "Sending...failed with exit value %d" exit-value)))
	    (or fcc-was-found
		(error "No recipients")))
	  (if mail-interactive
	      (save-excursion
		(set-buffer errbuf)
		(goto-char (point-min))
		(while (re-search-forward "\n\n* *" nil t)
		  (replace-match "; "))
		(if (not (zerop (buffer-size)))
		    (error "Sending...failed to %s"
			   (buffer-substring (point-min) (point-max)))))))
      (kill-buffer tembuf)
      (if (bufferp errbuf)
	  (kill-buffer errbuf)))))

;;; XEmacs FCC hackery, by jwz.  This version works on BABYL and VM buffers.
;;; To accomplish the latter, VM is loaded when this file is compiled.
;;; Don't worry, it's only loaded at compile-time.
;;; The hackery somewhat reverted by jas to prevent mail lossage.

(defun mail-do-fcc (header-end)
  (let (fcc-list
	(rmailbuf (current-buffer))
	(time (current-time))
	(tembuf (generate-new-buffer " rmail output"))
	(case-fold-search t))
    (or (markerp header-end) (error "header-end must be a marker"))
    (save-excursion
      (goto-char (point-min))
      (while (re-search-forward "^FCC:[ \t]*" header-end t)
	(setq fcc-list (cons (buffer-substring (point)
					       (progn
						 (end-of-line)
						 (skip-chars-backward " \t")
						 (point)))
			     fcc-list))
	(delete-region (match-beginning 0)
		       (progn (forward-line 1) (point))))
      (set-buffer tembuf)
      (erase-buffer)
      ;; This initial newline is written out if the fcc file already exists.
      (insert "\nFrom " (user-login-name) " "
	      (current-time-string time) "\n")
      ;; Insert the time zone before the year.
      (forward-char -1)
      (forward-word -1)
      (require 'mail-utils)
      (insert (mail-rfc822-time-zone time) " ")
      (goto-char (point-max))
      (insert-buffer-substring rmailbuf)
      ;; Make sure messages are separated.
      (goto-char (point-max))
      (insert ?\n)
      (goto-char 2)
      ;; ``Quote'' "^From " as ">From "
      ;;  (note that this isn't really quoting, as there is no requirement
      ;;   that "^[>]+From " be quoted in the same transparent way.)
      (let ((case-fold-search nil))
	(while (search-forward "\nFrom " nil t)
	  (forward-char -5)
	  (insert ?>)))
      (while fcc-list
	(let* ((buffer (find-buffer-visiting (car fcc-list)))
	       (curbuf (current-buffer))
	       dont-write-the-file
	       buffer-matches-file
	       (beg (point-min)) (end (point-max))
	       (beg2 (save-excursion (goto-char (point-min))
				     (forward-line 2) (point))))
	  (if buffer
	      ;; File is present in a buffer => append to that buffer.
	      (save-excursion
		(set-buffer buffer)
		(setq buffer-matches-file
		      (and (not (buffer-modified-p))
			   (verify-visited-file-modtime buffer)))
		;; Keep the end of the accessible portion at the same place
		;; unless it is the end of the buffer.
		(let ((max (if (/= (1+ (buffer-size)) (point-max))
			       (point-max))))
		  (unwind-protect
		      ;; Code below lifted from rmailout.el
		      ;; function rmail-output-to-rmail-file:
		      (let ((buffer-read-only nil)
			    (msg (and (boundp 'rmail-current-message)
				      rmail-current-message)))
			;; If MSG is non-nil, buffer is in RMAIL mode.
			(if msg
			    (progn
			      ;; Append to an ordinary buffer as a
			      ;; Unix mail message.
			      (rmail-maybe-set-message-counters)
			      (widen)
			      (narrow-to-region (point-max) (point-max))
			      (insert "\C-l\n0, unseen,,\n*** EOOH ***\n"
				      "Date: " (mail-rfc822-date) "\n")
			      (insert-buffer-substring curbuf beg2 end)
			      (insert "\n\C-_")
			      (goto-char (point-min))
			      (widen)
			      (search-backward "\n\^_")
			      (narrow-to-region (point) (point-max))
			      (rmail-count-new-messages t)
			      (rmail-show-message msg)
			      (setq max nil))
			  (if (with-current-buffer buffer ;; XEmacs
				(eq major-mode 'vm-mode))
			      (with-current-buffer buffer
				(mail-do-fcc-vm-internal tembuf))
			    ;; Output file not in rmail mode
			    ;; => just insert at the end.
			    (narrow-to-region (point-min) (1+ (buffer-size)))
			    (goto-char (point-max))
			    (insert-buffer-substring curbuf beg end)))
			(or buffer-matches-file
			    (progn
			      (if (y-or-n-p (format "Save file %s? "
						    (car fcc-list)))
				  (save-buffer))
			      (setq dont-write-the-file t))))
		    (if max (narrow-to-region (point-min) max))))))
	  ;; Append to the file directly,
	  ;; unless we've already taken care of it.
	  ;; (It's OK if it is an RMAIL or VM file -- the message will be
	  ;; parsed when the file is read in.)
	  (unless dont-write-the-file
	    (if (and (file-exists-p (car fcc-list))
		     ;; Check that the file isn't empty.  We don't
		     ;; want to insert a newline at the start of an
		     ;; empty file.
		     (not (zerop (nth 7 (file-attributes (car fcc-list)))))
		     (mail-file-babyl-p (car fcc-list)))
		;; If the file is a Babyl file,
		;; convert the message to Babyl format.
		(let ((coding-system-for-write
		       (or rmail-file-coding-system
			   ;; XEmacs change; emacs-mule is not available,
			   ;; escape-quoted serves much the same
			   ;; purpose. #### This means an incompatibility
			   ;; with Babyl files created with GNU Emacs, but
			   ;; that's probably okay, since no-one uses them.
			   'escape-quoted)))
		  (save-excursion
		    (set-buffer (get-buffer-create " mail-temp"))
		    (setq buffer-read-only nil)
		    (erase-buffer)
		    (insert "\C-l\n0, unseen,,\n*** EOOH ***\n"
			    "Date: " (mail-rfc822-date) "\n")
		    (insert-buffer-substring curbuf beg2 end)
		    (insert "\n\C-_")
		    (write-region (point-min) (point-max) (car fcc-list) t)
		    (erase-buffer)))
	      ;; MIME processing should have eliminated any characters
	      ;; outside the range 0-255; if MIME processing hasn't been
	      ;; done, there's no reasonable expectation that the data will
	      ;; be preserved in a Unix mailbox, so we just write tildes for
	      ;; those chars. We set the coding system for write to 'binary
	      ;; to prevent any double-encoding that may occur if
	      ;; buffer-file-coding-system has been initialised to a
	      ;; non-binary-compatible coding system like, say, UTF-8.
	      (let ((coding-system-for-write 'binary))
		(write-region (1+ (point-min)) (point-max) (car fcc-list) t))))
	  (and buffer (not dont-write-the-file)
	       (with-current-buffer buffer
		 (set-visited-file-modtime))))
	(setq fcc-list (cdr fcc-list))))
    (kill-buffer tembuf)))

;; XEmacs:
(defun mail-do-fcc-vm-internal (buffer)
  (or (eq major-mode 'vm-mode) (error "this only works in vm-mode"))
  (let ((buffer-read-only nil)
	(foreign-folder-p (not (eq vm-folder-type 'From_))))

    (if foreign-folder-p
	;; `buffer' has already been prepared with a "From " line which
	;; has a sensible user-id and date in it, but if we're FCCing to
	;; a VM folder that isn't in From_ format, we must discard that
	;; and let VM do whatever voodoo it needs to do.  (Actually we
	;; could do this all the time, but then all FCCed messages would
	;; have "From VM ..." envelopes, which is less attractive.)
	(save-excursion
	  (set-buffer buffer)
	  (goto-char (point-min))
	  (skip-chars-forward "\n")
	  (forward-line)
	  (delete-region (point-min) (point))))

    ;; Use eval to inhibit compilation of the following code.
    ;; The code contains macros, and to compile them a (reuqire
    ;; 'vm-misc) is needed.  When VM stopped being bundled with
    ;; XEmacs, this require call became impossible.
    (eval
     (quote
      ;; Largely copied from #'vm-save-message in vm-save.el
      (vm-save-restriction
       (widen)
       (goto-char (point-max))
       (if foreign-folder-p
	   (vm-write-string (current-buffer)
			    (vm-leading-message-separator vm-folder-type)))
       (insert-buffer-substring buffer)
       (if foreign-folder-p
	   (vm-write-string (current-buffer)
			    (vm-trailing-message-separator vm-folder-type)))

       (vm-increment vm-messages-not-on-disk)
       (vm-set-buffer-modified-p t)
       (vm-clear-modification-flag-undos)
       (vm-check-for-killed-summary)
       (vm-assimilate-new-messages)
       (vm-update-summary-and-mode-line))))))

(defun mail-sent-via ()
  "Make a Sent-via header line from each To or CC header line."
  (interactive)
  (save-excursion
    ;; put a marker at the end of the header
    (let ((end (copy-marker (mail-header-end)))
	  (case-fold-search t)
	  ;to-line
	  )
      (goto-char (point-min))
      ;; search for the To: lines and make Sent-via: lines from them
      ;; search for the next To: line
      (while (re-search-forward "^\\(to\\|cc\\):" end t)
	;; Grab this line plus all its continuations, sans the `to:'.
	(let ((to-line
	       (buffer-substring (point)
				 (progn
				   (if (re-search-forward "^[^ \t\n]" end t)
				       (backward-char 1)
				     (goto-char end))
				   (point)))))
	  ;; Insert a copy, with altered header field name.
	  (insert-before-markers "Sent-via:" to-line))))))

(defun mail-to ()
  "Move point to end of To-field."
  (interactive)
  (if (interactive-p) (expand-abbrev))  ; XEmacs: for mail-abbrevs
  (mail-position-on-field "To"))

(defun mail-subject ()
  "Move point to end of Subject-field."
  (interactive)
  (if (interactive-p) (expand-abbrev))  ; XEmacs: for mail-abbrevs
  (mail-position-on-field "Subject"))

(defun mail-cc ()
  "Move point to end of CC-field.  Create a CC field if none."
  (interactive)
  (if (interactive-p) (expand-abbrev))  ; XEmacs: for mail-abbrevs
  (or (mail-position-on-field "cc" t)
      (progn (mail-position-on-field "to")
	     (insert "\nCC: "))))

(defun mail-bcc ()
  "Move point to end of BCC-field.  Create a BCC field if none."
  (interactive)
  (if (interactive-p) (expand-abbrev))  ; XEmacs: for mail-abbrevs
  (or (mail-position-on-field "bcc" t)
      (progn (mail-position-on-field "to")
	     (insert "\nBCC: "))))

(defun mail-fcc (folder)
  "Add a new FCC field, with file name completion."
  (interactive "FFolder carbon copy: ")
  (if (interactive-p) (expand-abbrev))  ; XEmacs: for mail-abbrevs
  (or (mail-position-on-field "fcc" t)	;Put new field after exiting FCC.
      (mail-position-on-field "to"))
  (insert "\nFCC: " folder))

(defun mail-reply-to ()
  "Move point to end of Reply-To-field.  Create a Reply-To field if none."
  (interactive)
  (if (interactive-p) (expand-abbrev))  ; XEmacs: for mail-abbrevs
  (mail-position-on-field "Reply-To"))

(defun mail-position-on-field (field &optional soft)
  (let (end
	(case-fold-search t))
    (setq end (mail-header-end))
    (goto-char (point-min))
    (if (re-search-forward (concat "^" (regexp-quote field) ":") end t)
	(progn
	  (re-search-forward "^[^ \t]" nil 'move)
	  (beginning-of-line)
	  (skip-chars-backward "\n")
	  t)
      (or soft
	  (progn (goto-char end)
		 (insert field ": \n")
		 (skip-chars-backward "\n")))
      nil)))

(defun mail-text ()
  "Move point to beginning of message text."
  (interactive)
  (if (interactive-p) (expand-abbrev))  ; XEmacs: for mail-abbrevs
  (goto-char (mail-text-start)))

(defun mail-signature (&optional atpoint)
  "Sign letter with signature based on `mail-signature-file'.
Prefix arg means put contents at point."
  (interactive "P")
  (save-excursion
    (or atpoint
	(goto-char (point-max)))
    (skip-chars-backward " \t\n")
    (end-of-line)
    (or atpoint
	(delete-region (point) (point-max)))
    (if (stringp mail-signature)
	(insert mail-signature)
      (insert "\n\n-- \n")
      (insert-file-contents (expand-file-name mail-signature-file)))))

(defun mail-fill-yanked-message (&optional justifyp)
  "Fill the paragraphs of a message yanked into this one.
Numeric argument means justify as well."
  (interactive "P")
  (save-excursion
    (goto-char (mail-text-start))
    (fill-individual-paragraphs (point)
				(point-max)
				justifyp
				mail-citation-prefix-regexp)))

(defun mail-indent-citation ()
  "Modify text just inserted from a message to be cited.
The inserted text should be the region.
When this function returns, the region is again around the modified text.

Normally, indent each nonblank line `mail-indentation-spaces' spaces.
However, if `mail-yank-prefix' is non-nil, insert that prefix on each line."
  (mail-yank-clear-headers (region-beginning) (region-end))
  (if (null mail-yank-prefix)
      (indent-rigidly (region-beginning) (region-end)
		      mail-indentation-spaces)
    (save-excursion
      (let ((end (set-marker (make-marker) (region-end))))
	(goto-char (region-beginning))
	(while (< (point) end)
	  (insert mail-yank-prefix)
	  (forward-line 1))))))

(defun mail-yank-original (arg)
  "Insert the message being replied to, if any (in rmail).
Puts point after the text and mark before.
Normally, indents each nonblank line ARG spaces (default 3).
However, if `mail-yank-prefix' is non-nil, insert that prefix on each line.

Just \\[universal-argument] as argument means don't indent, insert no prefix,
and don't delete any header fields."
  (interactive "P")
  (if mail-reply-action
      (let ((start (point))
	    (original mail-reply-action))
	(and (consp original) (eq (car original) 'insert-buffer)
	     (setq original (nth 1 original)))
	(if (consp original)
	    (apply (car original) (cdr original))
	  ;; If the original message is in another window in the same frame,
	  ;; delete that window to save screen space.
	  ;; t means don't alter other frames.
	  (delete-windows-on original t)
	  (insert-buffer original)
	  (set-text-properties (point) (mark t) nil))
	(if (consp arg)
	    nil
	  (goto-char start)
	  (let ((mail-indentation-spaces (if arg (prefix-numeric-value arg)
					   mail-indentation-spaces))
		;; Avoid error in Transient Mark mode
		;; on account of mark's being inactive.
		(mark-even-if-inactive t))
	    (cond (mail-citation-hook
		   ;; Bind mail-citation-header to the inserted
		   ;; message's header.
		   (let ((mail-citation-header
			  (buffer-substring-no-properties
			   start
			   (save-excursion
			     (save-restriction
			       (narrow-to-region start (point-max))
			       (goto-char start)
			       (rfc822-goto-eoh)
			       (point))))))
		     (run-hooks 'mail-citation-hook)))
		  (mail-yank-hooks
		   (run-hooks 'mail-yank-hooks))
		  (t
		   (mail-indent-citation)))))
	;; This is like exchange-point-and-mark, but doesn't activate the mark.
	;; It is cleaner to avoid activation, even though the command
	;; loop would deactivate the mark because we inserted text.
	(goto-char (prog1 (mark t)
		     (set-marker (mark-marker) (point) (current-buffer))))
	(if (not (eolp)) (insert ?\n)))))

(defun mail-yank-clear-headers (start end)
  (if (< end start)
      (let (temp)
	(setq temp start start end end temp)))
  (if mail-yank-ignored-headers
      (save-excursion
	(goto-char start)
	(if (search-forward "\n\n" end t)
	    (save-restriction
	      (narrow-to-region start (point))
	      (goto-char start)
	      (while (let ((case-fold-search t))
		       (re-search-forward mail-yank-ignored-headers nil t))
		(beginning-of-line)
		(delete-region (point)
			       (progn (re-search-forward "\n[^ \t]")
				      (forward-char -1)
				      (point)))))))))

(defun mail-yank-region (arg)
  "Insert the selected region from the message being replied to.
Puts point after the text and mark before.
Normally, indents each nonblank line ARG spaces (default 3).
However, if `mail-yank-prefix' is non-nil, insert that prefix on each line.

Just \\[universal-argument] as argument means don't indent, insert no prefix,
and don't delete any header fields."
  (interactive "P")
  (and (consp mail-reply-action)
       (eq (car mail-reply-action) 'insert-buffer)
       (with-current-buffer (nth 1 mail-reply-action)
	 (or (mark t)
	     (error "No mark set: %S" (current-buffer))))
       (let ((buffer (nth 1 mail-reply-action))
	     (start (point))
	     ;; Avoid error in Transient Mark mode
	     ;; on account of mark's being inactive.
	     (mark-even-if-inactive t))
	 ;; Insert the citation text.
	 (insert (with-current-buffer buffer
		   (buffer-substring-no-properties (point) (mark))))
	 (push-mark start)
	 ;; Indent or otherwise annotate the citation text.
	 (if (consp arg)
	     nil
	   (let ((mail-indentation-spaces (if arg (prefix-numeric-value arg)
					    mail-indentation-spaces)))
	     (if mail-citation-hook
		 ;; Bind mail-citation-hook to the original message's header.
		 (let ((mail-citation-header
			(with-current-buffer buffer
			  (buffer-substring-no-properties
			   (point-min)
			   (save-excursion
			     (goto-char (point-min))
			     (rfc822-goto-eoh)
			     (point))))))
		   (run-hooks 'mail-citation-hook))
	       (if mail-yank-hooks
		   (run-hooks 'mail-yank-hooks)
		 (mail-indent-citation))))))))

(defun mail-split-line ()
  "Split current line, moving portion beyond point vertically down.
If the current line has `mail-yank-prefix', insert it on the new line."
  (interactive "*")
  (split-line
   ;; XEmacs: #### fix this
   ;mail-yank-prefix
   ))


(defun mail-attach-file (&optional file)
  "Insert a file at the end of the buffer, with separator lines around it."
  (interactive "fAttach file: ")
  (save-excursion
    (goto-char (point-max))
    (or (bolp) (newline))
    (newline)
    (let ((start (point))
	  middle)
      (insert (format "===File %s===" file))
      (insert-char ?= (max 0 (- 60 (current-column))))
      (newline)
      (setq middle (point))
      (insert "============================================================\n")
      (push-mark)
      (goto-char middle)
      (insert-file-contents file)
      (or (bolp) (newline))
      (goto-char start))))

;; Put these commands last, to reduce chance of lossage from quitting
;; in middle of loading the file.

;;;###autoload (add-hook 'same-window-buffer-names "*mail*")

;;;###autoload
(defun mail (&optional noerase to subject in-reply-to cc replybuffer actions)
  "Edit a message to be sent.  Prefix arg means resume editing (don't erase).
When this function returns, the buffer `*mail*' is selected.
The value is t if the message was newly initialized; otherwise, nil.

Optionally, the signature file `mail-signature-file' can be inserted at the
end; see the variable `mail-signature'.

\\<mail-mode-map>
While editing message, type \\[mail-send-and-exit] to send the message and exit.

Various special commands starting with C-c are available in sendmail mode
to move to message header fields:
\\{mail-mode-map}

If `mail-self-blind' is non-nil, a BCC to yourself is inserted
when the message is initialized.

If `mail-default-reply-to' is non-nil, it should be an address (a string);
a Reply-to: field with that address is inserted.

If `mail-archive-file-name' is non-nil, an FCC field with that file name
is inserted.

The normal hook `mail-setup-hook' is run after the message is
initialized.  It can add more default fields to the message.

When calling from a program, the first argument if non-nil says
not to erase the existing contents of the `*mail*' buffer.

The second through fifth arguments,
 TO, SUBJECT, IN-REPLY-TO and CC, specify if non-nil
 the initial contents of those header fields.
 These arguments should not have final newlines.
The sixth argument REPLYBUFFER is a buffer which contains an
 original message being replied to, or else an action
 of the form (FUNCTION . ARGS) which says how to insert the original.
 Or it can be nil, if not replying to anything.
The seventh argument ACTIONS is a list of actions to take
 if/when the message is sent.  Each action looks like (FUNCTION . ARGS);
 when the message is sent, we apply FUNCTION to ARGS.
 This is how Rmail arranges to mark messages `answered'."
  (interactive "P")
  ;; XEmacs: major changes here
  (if mail-use-multiple-buffers-p
;;; This is commented out because I found it was confusing in practice.
;;; It is easy enough to rename *mail* by hand with rename-buffer
;;; if you want to have multiple mail buffers.
;;; And then you can control which messages to save. --rms.
;;; Put it back in, conditional on mail-use-multiple-buffers-p --jas
      (let ((index 1)
	    buffer)
	;; If requested, look for a mail buffer that is modified and go to it.
	(if noerase
	    (progn
	      (while (and (setq buffer
				(get-buffer (if (= 1 index) "*mail*"
					      (format "*mail*<%d>" index))))
			  (not (buffer-modified-p buffer)))
		(setq index (1+ index)))
	      (if buffer (switch-to-buffer buffer)
		;; If none exists, start a new message.
		;; This will never re-use an existing unmodified mail buffer
		;; (since index is not 1 anymore).  Perhaps it should.
		(setq noerase nil))))
	;; Unless we found a modified message and are happy, start a
	;; new message.
	(if (not noerase)
	    (progn
	      ;; Look for existing unmodified mail buffer.
	      (while (and (setq buffer
				(get-buffer (if (= 1 index) "*mail*"
					      (format "*mail*<%d>" index))))
			  (buffer-modified-p buffer))
		(setq index (1+ index)))
	      ;; If none, make a new one.
	      (or buffer
		  (setq buffer (generate-new-buffer "*mail*")))
	      ;; Go there and initialize it.
	      (switch-to-buffer buffer)
	      (erase-buffer)
	      (setq default-directory (expand-file-name "~/"))
	      (auto-save-mode auto-save-default)
	      (mail-mode)
	      (mail-setup to subject in-reply-to cc replybuffer actions)
	      (if (and buffer-auto-save-file-name
		       (file-exists-p buffer-auto-save-file-name))
		  (message "Auto save file for draft message exists; consider M-x mail-recover"))
	      t)))

    (pop-to-buffer "*mail*")
    ;; Avoid danger that the auto-save file can't be written.
    (let ((dir (expand-file-name
		(file-name-as-directory mail-default-directory))))
      (if (file-exists-p dir)
	  (setq default-directory dir)))
    ;; Only call auto-save-mode if necessary, to avoid changing auto-save file.
    (if (or (and auto-save-default (not buffer-auto-save-file-name))
	    (and (not auto-save-default) buffer-auto-save-file-name))
	(auto-save-mode auto-save-default))
    (mail-mode)
    ;; Disconnect the buffer from its visited file
    ;; (in case the user has actually visited a file *mail*).
;  (set-visited-file-name nil)
    (let (initialized)
      (and (not noerase)
	 (if buffer-file-name
	     (if (buffer-modified-p)
		 (when (y-or-n-p "Buffer has unsaved changes; reinitialize it and discard them? ")
		   (if (y-or-n-p "Disconnect buffer from visited file? ")
		       (set-visited-file-name nil))
		   t)
	       (when (y-or-n-p "Reinitialize buffer, and disconnect it from the visited file? ")
		 (set-visited-file-name nil)
		 t))
	   ;; A non-file-visiting buffer.
	   (if (buffer-modified-p)
	       (y-or-n-p "Unsent message being composed; erase it? ")
	     t))
	 (let ((inhibit-read-only t))
	   (erase-buffer)
	   (mail-setup to subject in-reply-to cc replybuffer actions)
	   (setq initialized t)))
      (if (and buffer-auto-save-file-name
	       (file-exists-p buffer-auto-save-file-name))
	  (message "Auto save file for draft message exists; consider M-x mail-recover"))
      initialized)))

(defun mail-recover-1 ()
  "Pop up a list of auto-saved draft messages so you can recover one of them."
  (interactive)
  (let ((file-name (make-auto-save-file-name))
	(ls-lisp-support-shell-wildcards t)
	non-random-len wildcard)
    ;; Remove the random part from the auto-save-file-name, and
    ;; create a wildcard which matches possible candidates.
    ;; Note: this knows that make-auto-save-file-name appends
    ;; "#<RANDOM-STUFF>#" to the buffer name, where RANDOM-STUFF
    ;; is the result of (make-temp-name "").
    (setq non-random-len
	  (- (length file-name) (length (make-temp-name "")) 1))
    (setq wildcard (concat (substring file-name 0 non-random-len) "*"))
    (if (null (file-expand-wildcards wildcard))
	(message "There are no auto-saved drafts to recover")
      ;; Bind dired-trivial-filenames to t because all auto-save file
      ;; names are normally ``trivial'', so Dired will set point after
      ;; all the files, at buffer bottom.  We want it on the first
      ;; file instead.
      (let ((dired-trivial-filenames t))
	(dired-other-window wildcard (concat dired-listing-switches "t")))
      (rename-buffer "*Auto-saved Drafts*" t)
      (save-excursion
	(goto-char (point-min))
	(or (looking-at " Move to the draft file you want to recover,")
	    (let ((inhibit-read-only t))
	      ;; Each line starts with a space so that Font Lock mode
	      ;; won't highlight the first character.
	      (insert "\
 Move to the draft file you want to recover, then type C-c C-c
 to recover text of message whose composition was interrupted.
 To browse text of a draft, type v on the draft file's line.

 You can also delete some of these files;
 type d on a line to mark that file for deletion.

 List of possible auto-save files for recovery:

"))))
      (use-local-map
       (let ((map (make-sparse-keymap)))
	 (set-keymap-parent map (current-local-map))
	 map))
      (define-key (current-local-map) "v"
	(lambda ()
	  (interactive)
	  ;; XEmacs change; emacs-mule is not available, escape-quoted
	  ;; serves the same purpose.
	  (let ((coding-system-for-read 'escape-quoted))
	    (dired-view-file))))
      (define-key (current-local-map) "\C-c\C-c"
	(lambda ()
	  (interactive)
	  (let ((fname (dired-get-filename))
		;; Auto-saved files are written in the internal
		;; representation, so they should be read accordingly.
		;; XEmacs change; emacs-mule is not available, escape-quoted
		;; serves the same purpose.
		(coding-system-for-read 'escape-quoted))
	    (switch-to-buffer-other-window "*mail*")
	    (let ((buffer-read-only nil))
	      (erase-buffer)
	      (insert-file-contents fname nil)
	      ;; insert-file-contents will set buffer-file-coding-system to
	      ;; escape-quoted on XEmacs, which is not what they want to use
	      ;; for sending the message.  But we don't know what was its
	      ;; value before the buffer was killed or Emacs crashed.  We
	      ;; therefore reset buffer-file-coding-system to the default
	      ;; value, so that either the default does TRT, or the user
	      ;; will get prompted for the right encoding when they send the
	      ;; message.
	      (setq buffer-file-coding-system
		    default-buffer-file-coding-system))))))))

(defun mail-recover ()
  "Recover interrupted mail composition from auto-save files.

If the mail buffer has a current valid auto-save file,
the command recovers that file.  Otherwise, it displays a
buffer showing the existing auto-saved draft messages;
you can move to one of them and type C-c C-c to recover that one."
  (interactive)
  ;; In case they invoke us from some random buffer...
  (switch-to-buffer "*mail*")
  ;; If *mail* didn't exist, set its directory, so that auto-saved
  ;; drafts will be found.
  (let ((dir (expand-file-name
	      (file-name-as-directory mail-default-directory))))
    (if (file-exists-p dir)
	(setq default-directory dir)))
  (or (eq major-mode 'mail-mode)
      (mail-mode))
  (let ((file-name buffer-auto-save-file-name))
    (cond ((and file-name (file-exists-p file-name))
	   (let ((dispbuf
		  ;; This used to invoke `ls' via call-process, but
		  ;; dired-noselect is more portable to systems where
		  ;; `ls' is not a standard program (it will use
		  ;; ls-lisp instead).
		  (dired-noselect file-name
				  (concat dired-listing-switches "t"))))
	     (save-selected-window
	       (select-window (display-buffer dispbuf t))
	       (goto-char (point-min))
	       (forward-line 2)
	       (dired-move-to-filename)
	       (setq dispbuf (rename-buffer "*Directory*" t)))
	     (if (not (yes-or-no-p
		       (format "Recover mail draft from auto save file %s? "
			       file-name)))
		 (error "mail-recover cancelled")
	       (let ((buffer-read-only nil)
		     (buffer-coding buffer-file-coding-system)
		     ;; Auto-save files are written in internal
		     ;; representation of non-ASCII characters.
		     ;; XEmacs change; emacs-mule is not available,
		     ;; escape-quoted serves the same purpose. 
		     (coding-system-for-read 'escape-quoted))
		 (erase-buffer)
		 (insert-file-contents file-name nil)
		 (setq buffer-file-coding-system buffer-coding)))))
	  (t (mail-recover-1)))))

;;;###autoload
(defun mail-other-window (&optional noerase to subject in-reply-to cc replybuffer sendactions)
  "Like `mail' command, but display mail buffer in another window."
  (interactive "P")
  (let ((pop-up-windows t)
	(special-display-buffer-names nil)
	(special-display-regexps nil)
	(same-window-buffer-names nil)
	(same-window-regexps nil))
    (pop-to-buffer "*mail*"))
  (mail noerase to subject in-reply-to cc replybuffer sendactions))

;;;###autoload
(defun mail-other-frame (&optional noerase to subject in-reply-to cc replybuffer sendactions)
  "Like `mail' command, but display mail buffer in another frame."
  (interactive "P")
  (let ((pop-up-frames t)
	(special-display-buffer-names nil)
	(special-display-regexps nil)
	(same-window-buffer-names nil)
	(same-window-regexps nil))
    (pop-to-buffer "*mail*"))
  (mail noerase to subject in-reply-to cc replybuffer sendactions))

;;; Do not add anything but external entries on this page.

(provide 'sendmail)

;;; sendmail.el ends here