1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208
|
$ save_verify='f$verify(0)
$! set ver
$!
$! Compile and link for xcubes
$!
$! USAGE:
$! @make [debug clobber clean]
$! debug : compile with degugger switch
$! clean : clean all except executable
$! clobber : clean all
$!
$! If you have
$! XVMSUTILS library (VMS6.2 or lower) <NOT TESTED>
$! insert the correct directory instead of X11:
$ xvmsutilsf="X11:XVMSUTILS.OLB"
$!
$! Already assumes DEC C on Alpha.
$! Assume VAX C on VAX.
$ decc=0
$! Assume DEC C on VAX.
$! decc=1
$!
$ QUOTE = """""""""
$ QUOTE = QUOTE + QUOTE + QUOTE
$ score = "SCOREFILE=" + QUOTE + "[]cubes.scores" + QUOTE
$ data = "DATAFILE=" + QUOTE + "[]cubes.data" + QUOTE
$ defscore==''score'
$ defdata==''data'
$!
$! NOTHING SHOULD BE MODIFIED BELOW
$!
$ if p1 .eqs. "CLEAN" then goto Clean
$ if p1 .eqs. "CLOBBER" then goto Clobber
$!
$ axp=f$getsyi("HW_MODEL") .ge. 1024
$ sys_ver=f$edit(f$getsyi("version"),"compress")
$ if f$extract(0,1,sys_ver) .nes. "V"
$ then
$ type sys$input
This script will assume that the operating system version is at least V7.0.
$!
$ sys_ver="V7.0"
$ endif
$ sys_maj=0+f$extract(1,1,sys_ver)
$ if sys_maj .lt. 7
$ then
$ xvmsutils=f$search("''xvmsutilsf'") .nes. ""
$ endif
$!
$!
$! Create .opt file
$ close/nolog optf
$ open/write optf xcubes.opt
$!
$ defs=="VMS"
$ if sys_maj .lt. 7
$ then
$ if xvmsutils then defs=="''defs',USE_XVMSUTILS"
$ else
$ defs=="''defs',SRAND=srand48,LRAND=lrand48,MAXRAND=2147483648.0"
$ endif
$ defs=="''defscore',''defdata',''defs'"
$!
$!
$! Establish the Compiling Environment
$!
$! Set compiler command
$ if axp
$ then
$ cc=="cc/standar=vaxc/define=(''defs')"
$ else
$ if decc
$ then
$ cc=="cc/decc/standard=vaxc/define=(''defs')"
$ else ! VAX C
$ cc=="cc/define=(''defs')"
$ endif
$ endif
$ if p1 .eqs. "DEBUG" .or. p2 .eqs. "DEBUG" .or. p3 .eqs. "DEBUG"
$ then
$ if axp
$ then
$ cc=="cc/deb/noopt/standar=vaxc/define=(''defs')/list"
$ else
$ if decc
$ then
$ cc=="cc/deb/noopt/decc/standar=vaxc/define=(''defs')/list"
$ else ! VAX C
$ cc=="cc/deb/noopt/define=(''defs')/list"
$ endif
$ endif
$ link=="link/deb"
$ endif
$!
$ if axp .or. .not. decc
$ then
$ define/nolog sys sys$library
$ endif
$!
$ write sys$output "Compiling XCubes with ''defs'"
$ call make Cubes.obj "cc Cubes.c" Cubes.c CubesP.h Cubes.h
$ call make CubesU.obj "cc CubesU.c" CubesU.c CubesP.h Cubes.h
$ call make rngs.obj "cc rngs.c" rngs.c
$ call make xcubes.obj "cc xcubes.c" xcubes.c Cubes.h
$!
$! Get libraries
$ if sys_maj .lt. 7
$ then
$ if xvmsutils then write optf "''xvmsutilsf'/lib"
$ endif
$! if .not. axp then write optf "sys$library:vaxcrtl/lib"
$ write optf "sys$library:vaxcrtl/lib"
$ if axp then write optf "sys$library:ucx$ipc_shr/share"
$ if axp then write optf "sys$share:decw$xextlibshr/share"
$ if axp then write optf "sys$share:decw$xtlibshrr5/share"
$ if .not. axp then write optf "sys$library:ucx$ipc/lib"
$! write optf "sys$share:decw$dxmlibshr/share"
$ write optf "sys$share:decw$xmlibshr12/share"
$ write optf "sys$share:decw$xlibshr/share"
$ close optf
$!
$! LINK
$ write sys$output "Linking XCubes"
$ link/map xcubes/opt
$!
$! Create .opt file
$ open/write optf xmcubes.opt
$ write sys$output "Compiling XmCubes with ''defs'"
$ call make Cubes.obj "cc Cubes.c" Cubes.c CubesP.h Cubes.h
$ call make CubesU.obj "cc CubesU.c" CubesU.c CubesP.h Cubes.h
$ call make rngs.obj "cc rngs.c" rngs.c
$ call make xmcubes.obj "cc xmcubes.c" xmcubes.c Cubes.h
$! Get libraries
$! if .not. axp then write optf "sys$library:vaxcrtl/lib"
$ write optf "sys$library:vaxcrtl/lib"
$ if axp then write optf "sys$library:ucx$ipc_shr/share"
$ if axp then write optf "sys$share:decw$xextlibshr/share"
$ if axp then write optf "sys$share:decw$xtlibshrr5/share"
$ if .not. axp then write optf "sys$library:ucx$ipc/lib"
$! write optf "sys$share:decw$dxmlibshr/share"
$ write optf "sys$share:decw$xmlibshr12/share"
$ write optf "sys$share:decw$xlibshr/share"
$ close optf
$!
$! LINK
$ write sys$output "Linking XmCubes"
$ link/map xmcubes/opt
$!
$ set noverify
$ exit
$!
$Clobber: ! Delete executables, Purge directory and clean up object files
$! and listings
$ delete/noconfirm/log xcubes.exe;*
$ delete/noconfirm/log xmcubes.exe;*
$!
$Clean: ! Purge directory, clean up object files and listings
$ close/nolog optf
$ purge
$ delete/noconfirm/log *.lis;*
$ delete/noconfirm/log *.obj;*
$ delete/noconfirm/log *.opt;*
$ delete/noconfirm/log *.map;*
$!
$ exit
$!
! SUBROUTINE TO CHECK DEPENDENCIES
$ make: subroutine
$ v='f$verify(0)
$! p1 What we are trying to make
$! p2 Command to make it
$! p3 - p8 What it depends on
$
$ if (f$extract(0,3,p2) .eqs. "cc ") then write optf "''p1'"
$ if (f$extract(0,3,p2) .eqs. "CC ") then write optf "''p1'"
$
$ if f$search(p1) .eqs. "" then goto MakeIt
$ time=f$cvtime(f$file(p1,"RDT"))
$ arg=3
$Loop:
$ argument=p'arg
$ if argument .eqs. "" then goto Exit
$ el=0
$Loop2:
$ file=f$element(el," ",argument)
$ if file .eqs. " " then goto Endl
$ afile=""
$Loop3:
$ ofile=afile
$ afile=f$search(file)
$ if afile .eqs. "" .or. afile .eqs. ofile then goto NextEl
$ if f$cvtime(f$file(afile,"RDT")) .gts. time then goto MakeIt
$ goto Loop3
$NextEL:
$ el=el+1
$ goto Loop2
$EndL:
$ arg=arg+1
$ if arg .le. 8 then goto Loop
$ goto Exit
$
$MakeIt:
$ set verify
$ 'p2
$ vv='f$verify(0)
$Exit:
$ if v then set verify
$ endsubroutine
|