File: configure.ac

package info (click to toggle)
yaz 3.0.34-2
  • links: PTS, VCS
  • area: main
  • in suites: lenny
  • size: 13,404 kB
  • ctags: 12,108
  • sloc: xml: 116,075; ansic: 52,205; sh: 9,746; tcl: 2,043; makefile: 1,141; yacc: 347
file content (446 lines) | stat: -rw-r--r-- 12,284 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
dnl This file is part of the YAZ toolkit.
dnl Copyright (C) 1995-2008 Index Data
AC_PREREQ([2.60])
AC_INIT([yaz],[3.0.34],[yaz-help@indexdata.dk])
AC_CONFIG_SRCDIR([configure.ac])
AC_CONFIG_AUX_DIR([config])
AM_INIT_AUTOMAKE([1.9])
dnl
AC_SUBST([READLINE_LIBS])
AC_SUBST([YAZ_CONF_CFLAGS])
dnl ------ Checking programs
AC_PROG_CC
AC_PROG_CPP
AC_CHECK_PROGS([YACC], 'bison -y')
test -z "$YACC" && AC_MSG_WARN([GNU bison not found])
AC_CHECK_PROGS([TCLSH], [tclsh tclsh8.5 tclsh8.4 tclsh8.3 tclsh8.2], [tclsh])
AC_PROG_INSTALL
AM_PROG_LIBTOOL
AC_PATH_PROG([pkgconfigpath],[pkg-config],[NONE])
dnl
YAZ_DOC
dnl 
dnl
AC_CHECK_HEADERS([dirent.h fnmatch.h wchar.h locale.h langinfo.h pwd.h unistd.h sys/select.h sys/socket.h sys/stat.h sys/time.h sys/times.h sys/types.h sys/un.h sys/wait.h netdb.h arpa/inet.h netinet/tcp.h netinet/in_systm.h])
AC_CHECK_HEADERS([net/if.h netinet/in.h netinet/if_ether.h],[],[],[
 #if HAVE_SYS_TYPES_H
 #include <sys/types.h>
 #endif
 #if HAVE_SYS_SOCKET_H
 #include <sys/socket.h>
 #endif
 #if HAVE_NET_IF_H
 #include <net/if.h>
 #endif
 #if HAVE_NETINET_IN_H
 #include <netinet/in.h>
 #endif
])
AC_HEADER_STDC
if test "$ac_cv_header_stdc" = "no"; then
    AC_MSG_WARN([Your system doesn not seem to support ANSI C])
fi
dnl ----- Types
AC_CHECK_TYPES([long long])
dnl
dnl ----- Sockets
checkBoth=0
AC_CHECK_FUNC([connect])
if test "$ac_cv_func_connect" = "no"; then
    AC_CHECK_LIB([socket],[main], LIBS="$LIBS -lsocket", checkBoth=1)
fi
if test "$checkBoth" = "1"; then
    oldLibs=$LIBS
    LIBS="$LIBS -lsocket -lnsl"
    AC_CHECK_FUNC([accept], , [LIBS=$oldLibs])
fi
AC_CHECK_FUNC([gethostbyname], ,[AC_CHECK_LIB(nsl, main, [LIBS="$LIBS -lnsl"])])
dnl

dnl ------ OpenSSL
AC_SUBST([SSL_CFLAGS])
AC_SUBST([SSL_LIBS])
openssl=no
sslver=no
AC_ARG_WITH([openssl], [  --with-openssl[=PREFIX]   OpenSSL library in PREFIX], [openssl=$withval])
SSL_CFLAGS=""
SSL_LIBPATH=""
if test "$openssl" != "no"; then
    if test "$openssl" != "yes" -a "$openssl" != "default"; then
	if test -x $openssl/bin/pkg-config; then
	    if $openssl/bin/pkg-config --exists openssl; then
		SSL_CFLAGS=`$openssl/bin/pkg-config --cflags openssl`
		SSL_LIBS="`$openssl/bin/pkg-config --libs openssl`"
		sslver=`$openssl/bin/pkg-config --modversion openssl`
	    fi
	fi
	if test "$sslver" = "no"; then
	    SSL_CFLAGS="-I$openssl/include -I$openssl/include/openssl"
	    SSL_LIBPATH="-L$openssl/lib"
	fi
    else
	if test "$pkgconfigpath" != "NONE"; then
	    if $pkgconfigpath --exists openssl; then
		SSL_CFLAGS=`$pkgconfigpath --cflags openssl`
		SSL_LIBS="`$pkgconfigpath --libs openssl`"
		sslver=`$pkgconfigpath --modversion openssl`
	    fi
	fi
	if test "$sslver" = "no"; then
	    SSL_CFLAGS="-I/usr/include/openssl"
	fi
    fi
    if test "$sslver" = "no"; then
	xLIBS="$LIBS";
	xCPPFLAGS="$CPPFLAGS";
	CPPFLAGS="$CPPFLAGS ${SSL_CFLAGS} ${SSL_LIBPATH}"
	SSL_LIBS="${SSL_LIBPATH}"
	AC_CHECK_LIB([crypto],[main])
	if test "$ac_cv_lib_crypto_main" = "yes"; then
	    SSL_LIBS="${SSL_LIBS} -lcrypto"
	fi
	AC_CHECK_LIB([ssl],[SSL_new])
	if test "$ac_cv_lib_ssl_SSL_new" = "yes"; then
	    AC_CHECK_HEADER([openssl/ssl.h],[sslver=yes])
	    SSL_LIBS="${SSL_LIBS} -lssl"
	fi
	if test "$sslver" != "yes"; then
	    SSL_LIBS=""
	fi
        LIBS="$xLIBS"
	CPPFLAGS="$xCPPFLAGS"
    fi
    AC_MSG_CHECKING([for SSL])
    if test "$sslver" != "no"; then
	SSL_CFLAGS="-DHAVE_OPENSSL_SSL_H=1 $SSL_CFLAGS"
	AC_MSG_RESULT([$sslver])
    else
	SSL_CFLAGS=""
	AC_MSG_RESULT([None])
	if test "$openssl" != "default"; then
	    AC_MSG_ERROR([OpenSSL development libraries missing])
	fi
    fi
fi
dnl ------ GNU TLS
gnutls=default
AC_ARG_WITH([gnutls], [  --with-gnutls[=PREFIX]    GNU TLS library in PREFIX], [gnutls=$withval])
if test "$gnutls" != "no" -a "$sslver" = "no"; then
    gnutlsver=no
    if test "$gnutls" != "yes" -a "$gnutls" != "default"; then
	if test -x $gnutls/bin/pkg-config; then
	    if $gnutls/bin/pkg-config --exists gnutls; then
		SSL_CFLAGS=`$gnutls/bin/pkg-config --cflags gnutls`
		SSL_LIBS="`$gnutls/bin/pkg-config --libs gnutls`"
		gnutlsver=`$gnutls/bin/pkg-config --modversion gnutls`
	    fi
	fi
    else
	if test "$pkgconfigpath" != "NONE"; then
	    if $pkgconfigpath --exists gnutls; then
		SSL_CFLAGS=`$pkgconfigpath --cflags gnutls`
		SSL_LIBS="`$pkgconfigpath --libs gnutls`"
		gnutlsver=`$pkgconfigpath --modversion gnutls`
	    fi
	fi
    fi
    AC_MSG_CHECKING([for GNU TLS])
    if test "$gnutlsver" != "no"; then
	SSL_CFLAGS="-DHAVE_GNUTLS_H=1 $SSL_CFLAGS"
	AC_MSG_RESULT([$gnutlsver])
    else
	SSL_CFLAGS=""
	AC_MSG_RESULT([None])
	if test "$gnutls" != "default"; then
	    AC_MSG_ERROR([GNU TLS development libraries missing])
	fi
    fi
fi
dnl
dnl ------ GNU Readline
READLINE_SHARED_LIBADD=""
AC_CHECK_LIB([ncurses],[tgetent],[READLINE_SHARED_LIBADD="-lncurses"],
    AC_CHECK_LIB([termcap],[tgetent],[READLINE_SHARED_LIBADD="-ltermcap"])
)
READLINE_LIBS=""
AC_CHECK_LIB([readline],[readline],[READLINE_LIBS="$READLINE_LIBS -lreadline $READLINE_SHARED_LIBADD"],,$READLINE_SHARED_LIBADD)
AC_CHECK_LIB([history],[add_history],[READLINE_LIBS="$READLINE_LIBS -lhistory"])
if test "$ac_cv_lib_readline_readline" = "yes"; then
    AC_CHECK_HEADERS([readline/readline.h readline/history.h])
    xLIBS=$LIBS
    LIBS="$LIBS $READLINE_LIBS"
    AC_TRY_LINK([
	#include <stdio.h>
	#include <readline/readline.h>
	    ],[
	    rl_attempted_completion_over = 0;
	    ],AC_DEFINE([HAVE_READLINE_COMPLETION_OVER]))
    AC_TRY_LINK([
	#include <stdio.h>
	#include <readline/readline.h>
	    ],[
	    rl_completion_matches (0, 0);
	    ],[AC_DEFINE([HAVE_READLINE_RL_COMPLETION_MATCHES])])
    LIBS=$xLIBS
fi
dnl ------ iconv
AC_ARG_WITH([iconv],[  --with-iconv[=PREFIX]     iconv library in PREFIX])
if test "$with_iconv" != "no"; then
    AC_MSG_CHECKING([for iconv])
    oldLIBS="$LIBS"
    oldCPPFLAGS="${CPPFLAGS}"
    if test "$with_iconv" != "yes" -a "$with_iconv" != ""; then
	LIBS="$LIBS -L${with_iconv}/lib"
	CPPFLAGS="${CPPFLAGS} -I${with_iconv}/include"
    fi
    AC_TRY_LINK([
		#include <iconv.h>
	    ],[
	    iconv_t t = iconv_open("", "");
	    ],[
	    AC_DEFINE([HAVE_ICONV_H])
	    AC_MSG_RESULT([yes])
	    ],[
	    LIBS="$LIBS -liconv"
	    AC_TRY_LINK([
			#include <iconv.h>
		    ],[
	    iconv_t t = iconv_open("", "");
		    ],[
	    AC_DEFINE([HAVE_ICONV_H])
	    AC_MSG_RESULT([yes])
		    ],[
	    LIBS="$oldLIBS"
	    CPPFLAGS="$oldCPPFLAGS"
	    AC_MSG_RESULT([no])
	    ])
    ])
fi
dnl ------ various functions
AC_CHECK_FUNCS([getaddrinfo vsnprintf gettimeofday poll strerror_r localtime_r usleep fopen64])
case $host in
    *-*-darwin*)
	trypoll="no";
	;;
    *)
	trypoll="yes";
	;;
esac

if test "$ac_cv_func_poll" = "yes" -a "$trypoll" = "yes"; then
    AC_CHECK_HEADERS([sys/poll.h])
fi
dnl ------ socklen_t
dnl We check for socklen_t by making prototypes with the
dnl various types. First socklen_t, then size_t, finally int.
dnl If the prototype succeeds, we are probably safe.
dnl That works if accept is not preprocessor defined (such sa AIX)
AC_MSG_CHECKING([for socklen_t])
AC_CACHE_VAL(ac_cv_check_socklen_t,[ac_cv_check_socklen_t=''
	AC_TRY_COMPILE([
#include <sys/types.h>
#include <sys/socket.h>
#ifdef __cplusplus
extern "C" {
#endif
#define try 1
#ifdef AIX
#if AIX >= 51
#define try 0
#endif
#endif
#if try
extern int accept(int, struct sockaddr *, socklen_t *);
#endif
#ifdef __cplusplus
}
#endif
	],,[ac_cv_check_socklen_t=socklen_t],[
		AC_TRY_COMPILE([
#include <sys/types.h>
#include <sys/socket.h>
#ifdef __cplusplus
extern "C" {
#endif
#define try 1
#ifdef AIX
#if AIX >= 42
#define try 0
#endif
#endif
#if try
extern int accept(int, struct sockaddr *, size_t t *);
#endif
#ifdef __cplusplus
}
#endif
],,[ac_cv_check_socklen_t=size_t],[ac_cv_check_socklen_t=int])
		])
	])
AC_MSG_RESULT([$ac_cv_check_socklen_t])
AC_DEFINE_UNQUOTED([YAZ_SOCKLEN_T],[$ac_cv_check_socklen_t])
AC_DEFINE([YAZ_USE_NEW_LOG])
dnl
dnl ------ tcpd
AC_ARG_ENABLE([tcpd],[  --enable-tcpd[=PREFIX]  enable TCP wrapper for server if available])
if test "$enable_tcpd" -a "$enable_tcpd" != "no"; then
    oldLibs=$LIBS
    oldCPPFLAGS=$CPPFLAGS
    if test "$enable_tcpd" != "yes"; then
	LIBS="$LIBS -L$enable_tcpd/lib"
	CPPFLAGS="$CPPFLAGS -I$enable_tcpd/include"
    fi
    AC_MSG_CHECKING([for working tcpd.h])
    LIBS="$LIBS -lwrap"
    AC_TRY_LINK([#include <syslog.h>
#include <tcpd.h>
	    int allow_severity = LOG_INFO;
	    int deny_severity = LOG_WARNING;],
	[struct request_info request_info; int i;
	    i = hosts_access(&request_info);],
	tcpd_ok=1, tcpd_ok=0)
    if test "$tcpd_ok" = "0"; then
	AC_MSG_RESULT([no])
	AC_MSG_ERROR([tcpd development libraries missing])
		LIBS=$oldLibs
		CPPFLAGS=$oldCPPFLAGS
    else
	AC_MSG_RESULT([yes])
	AC_DEFINE([HAVE_TCPD_H])
    fi
fi
dnl
AC_SUBST([YAZ_CONFIG_CFLAGS])
dnl
dnl ------ POSIX Threads
HAVETHREADS=0
AC_ARG_ENABLE([threads],[  --disable-threads       disable POSIX threads],[enable_threads=$enableval],[enable_threads=yes])
if test "$enable_threads" = "yes" -a "$HAVETHREADS" = "0"; then
    ACX_PTHREAD([
	    OCFLAGS=$CFLAGS
	    CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
	    dnl unfortunately empty thread lib spec is problematic because 
            dnl 'yaz-config --cflags' is not always passed to linker in 
            dnl applications using YAZ (such as Zebra).
	    if test "x$PTHREAD_LIBS" = "x"; then
		OLIBS=$LIBS
	        for lib in -lpthread -lpthreads -lc_r; do
		    LIBS="$lib $OLIBS"
		    AC_TRY_LINK([ #include <pthread.h> ],
			    [ pthread_t id; pthread_join(id, 0); ],
			    [ PTHREAD_LIBS=$lib; break ]
			)
		done
		LIBS=$OLIBS
	    fi
	    CFLAGS=$OCFLAGS
	    PTHREAD_CFLAGS="$PTHREAD_CFLAGS -DYAZ_POSIX_THREADS=1"
	    ])
fi

dnl ----- libXSLT/libEXLT/libXML2
AC_SUBST([XML2_CFLAGS])

xml_enabled=false
YAZ_LIBXML2([
	AC_DEFINE(YAZ_HAVE_XML2) 
	YAZ_CONFIG_CFLAGS="$YAZ_CONFIG_CFLAGS -DYAZ_HAVE_XML2=1"
	xml_enabled=true
    ])

YAZ_LIBXSLT([
	AC_DEFINE(YAZ_HAVE_XSLT)
	YAZ_CONFIG_CFLAGS="$YAZ_CONFIG_CFLAGS -DYAZ_HAVE_XSLT=1"
    ])
YAZ_LIBEXSLT([
	AC_DEFINE(YAZ_HAVE_EXSLT)
	YAZ_CONFIG_CFLAGS="$YAZ_CONFIG_CFLAGS -DYAZ_HAVE_EXSLT=1"
    ])
	
YAZ_CONFIG_CFLAGS="$YAZ_CONFIG_CFLAGS $XML2_CFLAGS"

if test "$XML2_LIBS"; then
    LIBS="$XML2_LIBS $LIBS"
fi

dnl
dnl 
AC_CHECK_ICU([3.6],[
	if test "$xml_enabled" = "true"; then
	    ICU_CPPFLAGS="$ICU_CPPFLAGS -D YAZ_HAVE_ICU=1"
	else
	    ICU_CPPFLAGS=""
	    AC_MSG_WARN([ICU support disabled because XML support is unavailable])
	fi
])
dnl
dnl ------ Memory debugging
AC_ARG_ENABLE([memdebug],[  --enable-memdebug       enable memory debugging],[enable_memdebug=$enableval],[enable_memdebug=none])
if test "$enable_memdebug" = "yes"; then
    AC_DEFINE([TRACE_XMALLOC],[2])
elif test "$enable_memdebug" = "no"; then
    AC_DEFINE([TRACE_XMALLOC],[0])
fi
dnl
dnl ------ Using this for "in-source" yaz-config
AC_SUBST([YAZ_SRC_ROOT])
AC_SUBST([YAZ_BUILD_ROOT])
YAZ_SRC_ROOT=`cd ${srcdir}; pwd`
YAZ_BUILD_ROOT=`pwd`

dnl ------ windows version files
WIN_FILEVERSION=`echo $PACKAGE_VERSION|tr . ,`.1
dnl
dnl ------ Makefiles
dnl
AC_OUTPUT([
Makefile
yaz.spec
src/Makefile
test/Makefile
util/Makefile
include/Makefile
include/yaz/Makefile
client/Makefile
ztest/Makefile
zoom/Makefile
doc/Makefile
doc/local.ent
doc/common/Makefile
doc/common/print.dsl
etc/Makefile
yaz-config
yaz.pc
Doxyfile
],[
	sed s%yaz_echo_source=yes%yaz_echo_source=no%g < yaz-config > util/yaz-config && chmod +x yaz-config util/yaz-config
    ]
)


echo \
"------------------------------------------------------------------------
Configuration:

  YAZ Package:                ${PACKAGE}
  YAZ Version:                ${VERSION}
  Bugreport:                  ${PACKAGE_BUGREPORT}
  Source code location:       ${srcdir}
  C Preprocessor:             ${CPP}
  C Preprocessor flags:       ${CPPFLAGS}
  C Compiler:                 ${CC}
  C Compiler flags:           ${CFLAGS}
  Linker flags:               ${LDFLAGS}
  Linked libs:                ${LIBS}
  Host System Type:           ${host}
  Install path:               ${prefix}
  Automake:                   ${AUTOMAKE}
  Archiver:                   ${AR}
  Ranlib:                     ${RANLIB}

------------------------------------------------------------------------"
dnl Local Variables:
dnl mode:shell-script
dnl sh-indentation: 2
dnl sh-basic-offset: 4
dnl End: