File: ac_check_icu.m4

package info (click to toggle)
yaz 5.27.1-2
  • links: PTS, VCS
  • area: main
  • in suites: buster
  • size: 16,184 kB
  • sloc: xml: 123,414; ansic: 72,530; sh: 5,007; tcl: 2,169; makefile: 1,321; yacc: 382
file content (97 lines) | stat: -rw-r--r-- 2,872 bytes parent folder | download | duplicates (3)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
# SYNOPSIS
#
#   AC_CHECK_ICU(version, action-if, action-if-not)
#
# DESCRIPTION
#
#   Defines ICU_LIBS, ICU_CFLAGS, ICU_CPPFLAGS
#
# COPYLEFT
#
#   Copyright (c) 2005 Akos Maroy <darkeye@tyrell.hu>
#
#   Copying and distribution of this file, with or without
#   modification, are permitted in any medium without royalty provided
#   the copyright notice and this notice are preserved.
AC_DEFUN([AC_CHECK_ICU],
	 [icudir=default
	  AC_ARG_WITH(icu,[  --with-icu[=PREFIX]       use ICU libs in PREFIX], icudir=$withval)
	  if test "$icudir" != "no"; then
	      if test "$icudir" = "yes" -o "$icudir" = "default"; then
		  AC_PATH_PROG(pkgconfigpath, pkg-config, NONE)
		  if test -x $pkgconfigpath; then
		      AC_MSG_CHECKING([for icu-i18n via pkg-config])
		      if $pkgconfigpath --exists icu-i18n; then
			  AC_MSG_RESULT([found])
			  ICU_VERSION=`$pkgconfigpath --modversion icu-i18n`
			  ICU_CPPFLAGS=""
			  ICU_CFLAGS=`$pkgconfigpath --cflags icu-i18n`
			  ICU_LIBS=`$pkgconfigpath --libs icu-i18n`
		      else
			  AC_MSG_RESULT([not found])
		      fi
		  fi
	      fi
	      if test -z "$ICU_VERSION"; then
		  if test "$icudir" = "yes" -o "$icudir" = "default"; then
		      AC_PATH_PROG(ICU_CONFIG, icu-config, NONE)
		  else
		      ICU_CONFIG=${icudir}/bin/icu-config
		  fi
		  AC_MSG_CHECKING([$ICU_CONFIG])
		  if test -x "$ICU_CONFIG"; then
		      AC_MSG_RESULT([found])
		      ICU_VERSION=`$ICU_CONFIG --version`
		      ICU_PREFIX=`$ICU_CONFIG --prefix`
		      ICU_CPPFLAGS=`$ICU_CONFIG --cppflags-searchpath`""
		      if test "$ICU_PREFIX" = "/usr"; then
			  ICU_CPPFLAGS=`echo $ICU_CPPFLAGS|sed 's@-I/usr/include@@'`
		      fi
		      ICU_CFLAGS=`$ICU_CONFIG --cflags`
		      if test "$ICU_PREFIX" = "/usr"; then
			  ICU_LIBS=`$ICU_CONFIG --ldflags-libsonly`
		      else
			  ICU_LIBS=`$ICU_CONFIG --ldflags`
		      fi
		      case $host_os in
			  solaris*)
			      AC_CHECK_LIB([Crun],[_fini],[ICU_LIBS="$ICU_LIBS -lCrun"])
			      ;;
		      esac
		  else
		      AC_MSG_RESULT([not found])
		  fi
	      fi
	      if test -n "$ICU_VERSION"; then
		  AC_MSG_CHECKING([for ICU >= $1])
		  VERSION_CHECK=`expr $ICU_VERSION \>\= $1`
		  if test "$VERSION_CHECK" = "1" ; then
		      AC_MSG_RESULT([$ICU_VERSION])
		  else
		      AC_MSG_RESULT([can not find ICU >= $1])
		      ICU_CPPFLAGS=""
		      ICU_CFLAGS=""
		      ICU_LIBS=""
		      ICU_VERSION=""
		  fi
		  AC_SUBST(ICU_CPPFLAGS)
		  AC_SUBST(ICU_CFLAGS)
		  AC_SUBST(ICU_LIBS)
	      fi
	      if test -z "$ICU_VERSION"; then
		  if test "$icudir" != "default"; then
		      AC_MSG_ERROR([libicu development libraries not found.])
		  fi
	      fi
	  fi
	  if test -n "$ICU_VERSION"; then
	      ifelse([$2], , :, [$2])
	  else
	      ifelse([$3], , :, [$3])
	  fi
	 ])
dnl Local Variables:
dnl mode:shell-script
dnl sh-indentation:4
dnl sh-basic-offset: 4
dnl End: