1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
QT += core gui widgets opengl xml concurrent network
TARGET = YUView
TEMPLATE = app
CONFIG += c++11
CONFIG -= debug_and_release
SOURCES += $$files(src/*.cpp, false)
HEADERS += $$files(src/*.h, false)
INCLUDEPATH += $$top_srcdir/YUViewLib/src
LIBS += -L$$top_builddir/YUViewLib -lYUViewLib
win32-msvc* {
PRE_TARGETDEPS += $$top_builddir/YUViewLib/YUViewLib.lib
} else {
PRE_TARGETDEPS += $$top_builddir/YUViewLib/libYUViewLib.a
}
unix:!mac {
isEmpty(PREFIX) {
PREFIX = /usr/local
}
isEmpty(BINDIR) {
BINDIR = bin
}
target.path = $$PREFIX/$$BINDIR/
metainfo.files = $$top_srcdir/packaging/linux/de.rwth_aachen.ient.YUView.appdata.xml
metainfo.path = $$PREFIX/share/metainfo
desktop.files = $$top_srcdir/packaging/linux/de.rwth_aachen.ient.YUView.desktop
desktop.path = $$PREFIX/share/applications
mime.files = $$top_srcdir/packaging/linux/de.rwth_aachen.ient.YUView.xml
mime.path = $$PREFIX/share/mime/packages
icon32.files = $$top_srcdir/packaging/linux/icons/32x32/de.rwth_aachen.ient.YUView.png
icon64.files = $$top_srcdir/packaging/linux/icons/64x64/de.rwth_aachen.ient.YUView.png
icon128.files = $$top_srcdir/packaging/linux/icons/128x128/de.rwth_aachen.ient.YUView.png
icon256.files = $$top_srcdir/packaging/linux/icons/256x256/de.rwth_aachen.ient.YUView.png
icon512.files = $$top_srcdir/packaging/linux/icons/512x512/de.rwth_aachen.ient.YUView.png
icon32.path = $$PREFIX/share/icons/hicolor/32x32/apps
icon64.path = $$PREFIX/share/icons/hicolor/64x64/apps
icon128.path = $$PREFIX/share/icons/hicolor/128x128/apps
icon256.path = $$PREFIX/share/icons/hicolor/256x256/apps
icon512.path = $$PREFIX/share/icons/hicolor/512x512/apps
icon1024.path = $$PREFIX/share/icons/hicolor/1024x1024/apps
INSTALLS += target metainfo desktop mime icon32 icon64 icon128 icon256 icon512 icon1024
}
contains(QT_ARCH, x86_32|i386) {
warning("You are building for a 32 bit system. This is untested and not supported.")
}
macx {
ICON = images/YUView.icns
SVNN = $$system("git describe --tags")
}
linux {
SVNN = $$(DEB_VERSION_UPSTREAM)
}
win32-msvc* {
message("MSVC Compiler detected.")
}
win32 {
RC_FILE += images/WindowsAppIcon.rc
SVNN = $$system("git describe --tags")
DEFINES += NOMINMAX
}
isEmpty(LASTHASH) {
LASTHASH = 0
}
isEmpty(SVNN) {
SVNN = 0
}
VERSTR = '\\"$${SVNN}\\"'
DEFINES += YUVIEW_VERSION=$${VERSTR}
|
