1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
|
# --
# Copyright (C) 2021 Znuny GmbH, https://znuny.org/
# --
# This software comes with ABSOLUTELY NO WARRANTY. For details, see
# the enclosed file COPYING for license information (AGPL). If you
# did not receive this file, see http://www.gnu.org/licenses/agpl.txt.
# --
package Kernel::GenericInterface::Mapping::OutOfOffice;
use strict;
use warnings;
use Kernel::System::VariableCheck qw(:all);
our $ObjectManagerDisabled = 1;
=head1 NAME
Kernel::GenericInterface::Mapping::OutOfOffice
=head1 SYNOPSIS
=head1 PUBLIC INTERFACE
=head2 new()
usually, you want to create an instance of this
by using Kernel::GenericInterface::Mapping->new();
=cut
sub new {
my ( $Type, %Param ) = @_;
my $Self = {};
bless( $Self, $Type );
for my $Needed (qw(DebuggerObject MappingConfig)) {
if ( !$Param{$Needed} ) {
return {
Success => 0,
ErrorMessage => "Got no $Needed!"
};
}
$Self->{$Needed} = $Param{$Needed};
}
return $Self;
}
=head2 Map()
perform data mapping
my $Result = $MappingObject->Map(
Data => { # data payload before mapping
SessionID => 'AValidSessionIDValue', # the ID of the user session
UserLogin => 'Agent', # if no SessionID is given UserLogin is required
Password => 'some password', # user password
OutOfOfficeEntriesCSVString => 'CSV string with out-of-office entries to set',
},
);
$Result = {
Success => 1, # 0 or 1
ErrorMessage => '', # in case of error
Data => { # data payload of after mapping
SessionID => 'AValidSessionIDValue', # the ID of the user session
UserLogin => 'Agent', # if no SessionID is given UserLogin is required
Password => 'some password', # user password
OutOfOfficeEntriesCSVString => 'CSV string with out-of-office entries to set',
OutOfOfficeEntries => [
{
UserLogin => '...',
UserSearch => '...',
UserEmail => '...',
StartDate => '...',
EndDate => '...',
OutOfOffice => 1,
},
# ...
],
},
};
=cut
sub Map {
my ( $Self, %Param ) = @_;
my $CSVObject = $Kernel::OM->Get('Kernel::System::CSV');
my $OutOfOfficeEntriesCSVString = $Param{Data}->{OutOfOfficeEntriesCSVString};
if ( !defined $OutOfOfficeEntriesCSVString || !length $OutOfOfficeEntriesCSVString ) {
return $Self->{DebuggerObject}->Error(
Summary => 'Parameter OutOfOfficeEntriesCSVString is missing.',
);
}
#
# Parse CSV
#
# change line ending format to UNIX
$OutOfOfficeEntriesCSVString =~ s{\r\n?}{\n}msg;
# Add one new line to the end
if ( $OutOfOfficeEntriesCSVString !~ m{\n\z}ms ) {
$OutOfOfficeEntriesCSVString .= "\n";
}
else {
# Remove multiple new lines at the end
$OutOfOfficeEntriesCSVString =~ s{\n+\z}{\n}ms;
}
# Remove comments
$OutOfOfficeEntriesCSVString =~ s{^#.*\n}{}gm;
my $OutOfOfficeEntriesCSV = $CSVObject->CSV2Array(
String => $OutOfOfficeEntriesCSVString,
Separator => ',',
);
if ( !IsArrayRefWithData($OutOfOfficeEntriesCSV) ) {
return $Self->{DebuggerObject}->Error(
Summary => 'Error while parsing CSV string of parameter OutOfOfficeEntriesCSVString.',
);
}
my $HeaderColumns = shift @{$OutOfOfficeEntriesCSV};
my @OutOfOfficeEntriesCSV;
OUTOFOFFICEENTRYCSV:
for my $OutOfOfficeEntryCSV ( @{$OutOfOfficeEntriesCSV} ) {
next OUTOFOFFICEENTRYCSV if !IsArrayRefWithData($OutOfOfficeEntryCSV);
my %OutOfOfficeEntryCSV;
for my $ColumnIndex ( 0 .. $#{$HeaderColumns} ) {
$OutOfOfficeEntryCSV{ $HeaderColumns->[$ColumnIndex] } = $OutOfOfficeEntryCSV->[$ColumnIndex];
}
push @OutOfOfficeEntriesCSV, \%OutOfOfficeEntryCSV;
}
if ( !@OutOfOfficeEntriesCSV ) {
return $Self->{DebuggerObject}->Error(
Summary => 'CSV in parameter OutOfOfficeEntriesCSVString does not contain any entries.',
);
}
#
# Assemble out-of-office entries
#
my @OutOfOfficeEntries;
OUTOFOFFICEENTRYCSV:
for my $OutOfOfficeEntryCSV (@OutOfOfficeEntriesCSV) {
if ( !IsHashRefWithData($OutOfOfficeEntryCSV) ) {
$Self->{DebuggerObject}->Notice(
Summary => 'Out-of-office entry is not a hash with data!'
);
next OUTOFOFFICEENTRYCSV;
}
my %OutOfOfficeEntry = %{$OutOfOfficeEntryCSV};
$OutOfOfficeEntry{UserEmail} //= $OutOfOfficeEntry{EMail};
$OutOfOfficeEntry{EndDate} //= $OutOfOfficeEntry{EndTime};
$OutOfOfficeEntry{StartDate} //= $OutOfOfficeEntry{StartTime};
$OutOfOfficeEntry{OutOfOffice} //= $OutOfOfficeEntry{Enabled};
DATEPART:
for my $DatePart (qw(EndDate StartDate)) {
next DATEPART if !$OutOfOfficeEntry{$DatePart};
next DATEPART if $OutOfOfficeEntry{$DatePart} !~ m{(\d{2}).(\d{2}).(\d{4}) \s \d{2}:\d{2}:\d{2}}x;
$OutOfOfficeEntry{$DatePart} = "$3-$2-$1";
}
my %OutOfOfficeMapping = (
yes => 1,
no => 0,
);
if (
defined $OutOfOfficeEntry{OutOfOffice}
&& defined $OutOfOfficeMapping{ $OutOfOfficeEntry{OutOfOffice} }
)
{
$OutOfOfficeEntry{OutOfOffice} = $OutOfOfficeMapping{ $OutOfOfficeEntry{OutOfOffice} };
}
push @OutOfOfficeEntries, {
UserLogin => $OutOfOfficeEntry{UserLogin},
UserSearch => $OutOfOfficeEntry{UserSearch},
UserEmail => $OutOfOfficeEntry{UserEmail},
StartDate => $OutOfOfficeEntry{StartDate},
EndDate => $OutOfOfficeEntry{EndDate},
OutOfOffice => $OutOfOfficeEntry{OutOfOffice},
};
}
my $Result = {
Success => 1,
Data => {
%{ $Param{Data} }, # preserve original data because it also contains login credentials
OutOfOfficeEntries => \@OutOfOfficeEntries,
},
};
return $Result;
}
1;
|
