File: backward-kill-word-match

package info (click to toggle)
zsh-beta 4.3.0-dev-1%2B20050424-1
  • links: PTS
  • area: main
  • in suites: sarge
  • size: 18,240 kB
  • ctags: 6,564
  • sloc: ansic: 79,241; sh: 4,874; perl: 748; makefile: 676; awk: 341; sed: 16
file content (36 lines) | stat: -rw-r--r-- 627 bytes parent folder | download | duplicates (4) 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
 
emulate -L zsh
setopt extendedglob

autoload match-words-by-style

local curcontext=":zle:$WIDGET" word done
local -a matched_words
integer count=${NUMERIC:-1}

if (( count < 0 )); then
    (( NUMERIC = -count ))
    zle ${WIDGET##backward-}
    return
fi

while (( count-- )); do

    match-words-by-style

    word="$matched_words[2]$matched_words[3]"

    if [[ -n $word ]]; then
	if [[ -n $done || $LASTWIDGET = *kill* ]]; then
	    CUTBUFFER="$word$CUTBUFFER"
	else
	    killring=("$CUTBUFFER" "${(@)killring[1,-2]}")
	    CUTBUFFER=$word
	fi
	LBUFFER=$matched_words[1]
    else
	return 1
    fi
    done=1
done

return 0