File: checkmail

package info (click to toggle)
zsh 3.1.2-8
  • links: PTS
  • area: main
  • in suites: hamm
  • size: 3,628 kB
  • ctags: 3,582
  • sloc: ansic: 39,480; sh: 2,393; makefile: 1,189; perl: 329; awk: 257; sed: 25
file content (28 lines) | stat: -rw-r--r-- 838 bytes parent folder | download | duplicates (2)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
#! /usr/local/bin/zsh
#
# This autoloadable function checks the folders specified as arguments
# for new mails.  The arguments are interpeted in exactly the same way
# as the mailpath special zsh parameter (see zshparam(1)).
#
# If no arguments are given mailpath is used.  If mailpath is empty, $MAIL
# is used and if that is also empty, /var/spool/mail/$LOGNAME is used.
# This function requires zsh-3.0.1 or newer.
#
# Zolt�n Hidv�gi <hzoli@cs.elte.hu>
#

local file message

for file in "${@:-${mailpath[@]:-${MAIL:-/var/spool/mail/$LOGNAME}}}"
do
	message="${${(M)file%%\?*}#\?}"
	file="${file%%\?*}"
	if [[ -d "$file" ]] then
		file=( "$file"/**/*(.ND) )
		if (($#file)) then
			checkmail "${^file}\?$message"
		fi
	elif test -N "$file"; then  # this also sets $_ to $file
		print -r -- "${(e)message:-You have new mail.}"
	fi
done